/[gentoo-x86]/net-misc/radvd/radvd-1.9.1-r1.ebuild
Gentoo

Contents of /net-misc/radvd/radvd-1.9.1-r1.ebuild

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.6 - (show annotations) (download)
Wed Sep 19 22:44:02 2012 UTC (23 months ago) by jer
Branch: MAIN
Changes since 1.5: +2 -2 lines
Stable for HPPA (bug #433341).

(Portage version: 2.2.0_alpha129/cvs/Linux x86_64)

1 # Copyright 1999-2012 Gentoo Foundation
2 # Distributed under the terms of the GNU General Public License v2
3 # $Header: /var/cvsroot/gentoo-x86/net-misc/radvd/radvd-1.9.1-r1.ebuild,v 1.5 2012/09/11 16:02:13 armin76 Exp $
4
5 EAPI=4
6
7 inherit user
8
9 DESCRIPTION="Linux IPv6 Router Advertisement Daemon"
10 HOMEPAGE="http://v6web.litech.org/radvd/"
11 SRC_URI="http://v6web.litech.org/radvd/dist/${P}.tar.gz"
12
13 LICENSE="BSD"
14 SLOT="0"
15 KEYWORDS="amd64 arm hppa ppc sparc x86 ~x86-fbsd"
16 IUSE="kernel_FreeBSD selinux"
17
18 RDEPEND="dev-libs/libdaemon
19 selinux? ( sec-policy/selinux-radvd )"
20 DEPEND="${RDEPEND}
21 sys-devel/bison
22 sys-devel/flex
23 virtual/pkgconfig"
24
25 DOCS=( CHANGES README TODO radvd.conf.example )
26
27 pkg_setup() {
28 enewgroup radvd
29 enewuser radvd -1 -1 /dev/null radvd
30
31 # force ownership of radvd user and group (bug #19647)
32 [[ -d ${ROOT}/var/run/radvd ]] && chown radvd:radvd "${ROOT}"/var/run/radvd
33 }
34
35 src_configure() {
36 econf --with-pidfile=/var/run/radvd/radvd.pid
37 }
38
39 src_install() {
40 default
41
42 dohtml INTRO.html
43
44 newinitd "${FILESDIR}"/${P}.init ${PN}
45 newconfd "${FILESDIR}"/${PN}.conf ${PN}
46
47 # location of radvd.pid needs to be writeable by the radvd user
48 keepdir /var/run/radvd
49 fowners -R radvd:radvd /var/run/radvd
50 fperms 755 /var/run/radvd
51
52 if use kernel_FreeBSD ; then
53 sed -i -e \
54 's/^SYSCTL_FORWARD=.*$/SYSCTL_FORWARD=net.inet6.ip6.forwarding/g' \
55 "${D}"/etc/init.d/${PN} || die
56 fi
57 }
58
59 pkg_postinst() {
60 elog
61 elog "To use ${PN} you must create the configuration file"
62 elog "${ROOT}etc/radvd.conf"
63 elog
64 elog "An example configuration file has been installed under"
65 elog "${ROOT}usr/share/doc/${PF}"
66 elog
67 elog "grsecurity users should allow a specific group to read /proc"
68 elog "and add the radvd user to that group, otherwise radvd may"
69 elog "segfault on startup."
70 }

  ViewVC Help
Powered by ViewVC 1.1.20