/[gentoo-x86]/net-misc/tor/tor-0.2.3.7_alpha.ebuild
Gentoo

Contents of /net-misc/tor/tor-0.2.3.7_alpha.ebuild

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.2 - (show annotations) (download)
Fri Dec 9 22:24:20 2011 UTC (2 years, 4 months ago) by blueness
Branch: MAIN
CVS Tags: HEAD
Changes since 1.1: +1 -1 lines
FILE REMOVED
Removed old alpha

(Portage version: 2.1.10.11/cvs/Linux x86_64)

1 # Copyright 1999-2011 Gentoo Foundation
2 # Distributed under the terms of the GNU General Public License v2
3 # $Header: /var/cvsroot/gentoo-x86/net-misc/tor/tor-0.2.3.7_alpha.ebuild,v 1.1 2011/10/31 10:16:33 blueness Exp $
4
5 EAPI=4
6
7 inherit autotools eutils flag-o-matic versionator
8
9 MY_PV="$(replace_version_separator 4 -)"
10 MY_PF="${PN}-${MY_PV}"
11 DESCRIPTION="Anonymizing overlay network for TCP"
12 HOMEPAGE="http://www.torproject.org/"
13 SRC_URI="http://www.torproject.org/dist/${MY_PF}.tar.gz"
14 S="${WORKDIR}/${MY_PF}"
15
16 LICENSE="BSD"
17 SLOT="0"
18 KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
19 IUSE="+bufferevents doc nat-pmp tor-hardening transparent-proxy threads upnp"
20
21 DEPEND="dev-libs/openssl
22 >=dev-libs/libevent-2.0.14
23 nat-pmp? ( net-libs/libnatpmp )
24 upnp? ( <net-libs/miniupnpc-1.6 )"
25 RDEPEND="${DEPEND}"
26
27 pkg_setup() {
28 enewgroup tor
29 enewuser tor -1 -1 /var/lib/tor tor
30 }
31
32 src_prepare() {
33 epatch "${FILESDIR}"/torrc.sample.patch
34
35 einfo "Regenerating autotools files ..."
36 epatch "${FILESDIR}"/${PN}-0.2.2.24_alpha-respect-CFLAGS.patch
37 eautoreconf
38 }
39
40 src_configure() {
41 # Upstream isn't sure of all the user provided CFLAGS that
42 # will break tor, but does recommend against -fstrict-aliasing.
43 # We'll filter-flags them here as we encounter them.
44 filter-flags -fstrict-aliasing
45 econf --docdir=/usr/share/doc/${PF} \
46 $(use_enable bufferevents) \
47 $(use_enable doc asciidoc) \
48 $(use_enable nat-pmp) \
49 $(use_enable tor-hardening gcc-hardening) \
50 $(use_enable tor-hardening linker-hardening) \
51 $(use_enable transparent-proxy transparent) \
52 $(use_enable threads) \
53 $(use_enable upnp)
54 }
55
56 src_install() {
57 newconfd "${FILESDIR}"/tor.confd tor
58 newinitd "${FILESDIR}"/tor.initd-r6 tor
59 emake DESTDIR="${D}" install
60 keepdir /var/lib/tor
61
62 dodoc README ChangeLog ReleaseNotes \
63 doc/{HACKING,TODO} \
64 doc/spec/README
65
66 fperms 750 /var/lib/tor
67 fowners tor:tor /var/lib/tor
68
69 insinto /etc/tor/
70 newins "${FILESDIR}"/torrc-r1 torrc
71 }
72
73 pkg_postinst() {
74 elog
75 elog "We created a configuration file for tor, /etc/tor/torrc, but you can"
76 elog "change it according to your needs. Use the torrc.sample that is in"
77 elog "that directory as a guide. Also, to have privoxy work with tor"
78 elog "just add the following line"
79 elog
80 elog "forward-socks4a / localhost:9050 ."
81 elog
82 elog "to /etc/privoxy/config. Notice the . at the end!"
83 elog
84 }

  ViewVC Help
Powered by ViewVC 1.1.20