viewvc.cgi/gentoo-x86/skel.ebuild

# Copyright 1999-2005 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

# NOTE: The comments in this file are for instruction and documentation.  
# They're not meant to appear with your final, production ebuild.  Please
# remember to remove them before submitting or committing your ebuild.  That
# doesn't mean you can't add your own comments though.

# The 'Header' on the third line should just be left alone.  When your ebuild
# will be committed to cvs, the details on that line will be automatically
# generated to contain the correct data.

# inherit lists eclasses to inherit functions from. Almost all ebuilds should
# inherit eutils, as a large amount of important functionality has been
# moved there. For example, the $(get_libdir) mentioned below wont work
# without the following line:
inherit eutils
# A well-used example of an eclass function that needs eutils is epatch. If
# your source needs patches applied, it's suggested to put your patch in the
# 'files' directory and use:
#
#   epatch ${FILESDIR}/patch-name-here
#
# eclasses tend to list descriptions of how to use their functions properly.
# take a look at /usr/portage/eclasses/ for more examples.

# Short one-line description of this package.
DESCRIPTION="This is a sample skeleton ebuild file"

# Homepage, not used by Portage directly but handy for developer reference
HOMEPAGE="http://foo.bar.com/"

# Point to any required sources; these will be automatically downloaded by
# Portage.
SRC_URI="ftp://foo.bar.com/${P}.tar.gz"

# License of the package.  This must match the name of file(s) in
# /usr/portage/licenses/.  For complex license combination see the developer
# docs on gentoo.org for details.
LICENSE=""

# The SLOT variable is used to tell Portage if it's OK to keep multiple
# versions of the same package installed at the same time.  For example,
# if we have a libfoo-1.2.2 and libfoo-1.3.2 (which is not compatible
# with 1.2.2), it would be optimal to instruct Portage to not remove
# libfoo-1.2.2 if we decide to upgrade to libfoo-1.3.2.  To do this,
# we specify SLOT="1.2" in libfoo-1.2.2 and SLOT="1.3" in libfoo-1.3.2.
# emerge clean understands SLOTs, and will keep the most recent version
# of each SLOT and remove everything else.
# Note that normal applications should use SLOT="0" if possible, since
# there should only be exactly one version installed at a time.
# DO NOT USE SLOT=""! This tells Portage to disable SLOTs for this package.
SLOT="0"

# Using KEYWORDS, we can record masking information *inside* an ebuild
# instead of relying on an external package.mask file.  Right now, you
# should set the KEYWORDS variable for every ebuild so that it contains
# the names of all the architectures with which the ebuild works.  All of
# the official architectures can be found in the keywords.desc file which 
# is in /usr/portage/profiles/.  Usually you should just set this to "~x86".  
# The ~ in front of the architecture indicates that the package is new and 
# should be considered unstable until testing proves its stability.  Once 
# packages go stable the ~ prefix is removed.  So, if you've confirmed that 
# your ebuild works on x86 and ppc, you'd specify: KEYWORDS="~x86 ~ppc"
# For binary packages, use -* and then list the archs the bin package
# exists for.  If the package was for an x86 binary package, then
# KEYWORDS would be set like this: KEYWORDS="-* x86"
# DO NOT USE KEYWORDS="*".  This is deprecated and only for backward
# compatibility reasons.
KEYWORDS="~x86"

# Comprehensive list of any and all USE flags leveraged in the ebuild,
# with the exception of any ARCH specific flags, i.e. "ppc", "sparc",
# "x86" and "alpha".  This is a required variable.  If the ebuild doesn't 
# use any USE flags, set to "".
IUSE="X gnome"

# A space delimited list of portage features to restrict. man 5 ebuild
# for details.  Usually not needed.
#RESTRICT="nostrip"

# Build-time dependencies, such as
#    ssl? ( >=dev-libs/openssl-0.9.6b )
#    >=dev-lang/perl-5.6.1-r1
# It is advisable to use the >= syntax show above, to reflect what you
# had installed on your system when you tested the package.  Then
# other users hopefully won't be caught without the right version of
# a dependency.
DEPEND=""

# Run-time dependencies, same as DEPEND if RDEPEND isn't defined:
#RDEPEND=""

# Source directory; the dir where the sources can be found (automatically
# unpacked) inside ${WORKDIR}.  The default value for S is ${WORKDIR}/${P}
# If you don't need to change it, leave the S= line out of the ebuild
# to keep it tidy.
S=${WORKDIR}/${P}

src_compile() {
        # Most open-source packages use GNU autoconf for configuration.
        # The quickest (and preferred) way of running configure is:
        econf || die "econf failed"
        #
        # You could use something similar to the following lines to
        # configure your package before compilation.  The "|| die" portion
        # at the end will stop the build process if the command fails.
        # You should use this at the end of critical commands in the build
        # process.  (Hint: Most commands are critical, that is, the build
        # process should abort if they aren't successful.)
        #./configure \
        #       --host=${CHOST} \
        #       --prefix=/usr \
        #       --infodir=/usr/share/info \
        #       --mandir=/usr/share/man || die "./configure failed"
        # Note the use of --infodir and --mandir, above. This is to make
        # this package FHS 2.2-compliant.  For more information, see
        #   http://www.pathname.com/fhs/

        # emake (previously known as pmake) is a script that calls the
        # standard GNU make with parallel building options for speedier
        # builds (especially on SMP systems).  Try emake first.  It might
        # not work for some packages, because some makefiles have bugs
        # related to parallelism, in these cases, use emake -j1 to limit
        # make to a single process.  The -j1 is a visual clue to others
        # that the makefiles have bugs that have been worked around.
        emake || die "emake failed"
}

src_install() {
        # You must *personally verify* that this trick doesn't install
        # anything outside of DESTDIR; do this by reading and
        # understanding the install part of the Makefiles.
        # This is the preferred way to install.
        make DESTDIR=${D} install || die

        # For Makefiles that don't make proper use of DESTDIR, setting
        # prefix is often an alternative.  However if you do this, then
        # you also need to specify mandir and infodir, since they were
        # passed to ./configure as absolute paths (overriding the prefix
        # setting).
        #make \
        #       prefix=${D}/usr \
        #       mandir=${D}/usr/share/man \
        #       infodir=${D}/usr/share/info \
        #       libdir=${D}/usr/$(get_libdir) \
        #       install || die
        # Again, verify the Makefiles!  We don't want anything falling
        # outside of ${D}.

        # The portage shortcut to the above command is simply:
        #
        #einstall || die
}
1	dragonheart	1.34	# Copyright 1999-2005 Gentoo Foundation
2	drobbins	1.6	# Distributed under the terms of the GNU General Public License v2
3	sandymac	1.8	# $Header: $
4	drobbins	1.6
5	vapier	1.27	# NOTE: The comments in this file are for instruction and documentation.
6	drobbins	1.6	# They're not meant to appear with your final, production ebuild. Please
7			# remember to remove them before submitting or committing your ebuild. That
8			# doesn't mean you can't add your own comments though.
9
10			# The 'Header' on the third line should just be left alone. When your ebuild
11	msterret	1.21	# will be committed to cvs, the details on that line will be automatically
12	drobbins	1.6	# generated to contain the correct data.
13
14	lv	1.30	# inherit lists eclasses to inherit functions from. Almost all ebuilds should
15			# inherit eutils, as a large amount of important functionality has been
16			# moved there. For example, the $(get_libdir) mentioned below wont work
17			# without the following line:
18			inherit eutils
19			# A well-used example of an eclass function that needs eutils is epatch. If
20			# your source needs patches applied, it's suggested to put your patch in the
21			# 'files' directory and use:
22			#
23			# epatch ${FILESDIR}/patch-name-here
24			#
25			# eclasses tend to list descriptions of how to use their functions properly.
26			# take a look at /usr/portage/eclasses/ for more examples.
27
28	gbevin	1.3	# Short one-line description of this package.
29			DESCRIPTION="This is a sample skeleton ebuild file"
30
31			# Homepage, not used by Portage directly but handy for developer reference
32	vapier	1.16	HOMEPAGE="http://foo.bar.com/"
33	blizzy	1.9
34			# Point to any required sources; these will be automatically downloaded by
35			# Portage.
36			SRC_URI="ftp://foo.bar.com/${P}.tar.gz"
37	sandymac	1.5
38	vapier	1.27	# License of the package. This must match the name of file(s) in
39			# /usr/portage/licenses/. For complex license combination see the developer
40	sandymac	1.5	# docs on gentoo.org for details.
41			LICENSE=""
42	achim	1.1
43	blizzy	1.9	# The SLOT variable is used to tell Portage if it's OK to keep multiple
44	vapier	1.27	# versions of the same package installed at the same time. For example,
45	blizzy	1.9	# if we have a libfoo-1.2.2 and libfoo-1.3.2 (which is not compatible
46			# with 1.2.2), it would be optimal to instruct Portage to not remove
47	vapier	1.27	# libfoo-1.2.2 if we decide to upgrade to libfoo-1.3.2. To do this,
48	blizzy	1.9	# we specify SLOT="1.2" in libfoo-1.2.2 and SLOT="1.3" in libfoo-1.3.2.
49			# emerge clean understands SLOTs, and will keep the most recent version
50			# of each SLOT and remove everything else.
51			# Note that normal applications should use SLOT="0" if possible, since
52			# there should only be exactly one version installed at a time.
53			# DO NOT USE SLOT=""! This tells Portage to disable SLOTs for this package.
54	blizzy	1.12	SLOT="0"
55	blizzy	1.9
56			# Using KEYWORDS, we can record masking information inside an ebuild
57	vapier	1.27	# instead of relying on an external package.mask file. Right now, you
58	blizzy	1.9	# should set the KEYWORDS variable for every ebuild so that it contains
59	vapier	1.27	# the names of all the architectures with which the ebuild works. All of
60			# the official architectures can be found in the keywords.desc file which
61			# is in /usr/portage/profiles/. Usually you should just set this to "~x86".
62			# The ~ in front of the architecture indicates that the package is new and
63			# should be considered unstable until testing proves its stability. Once
64			# packages go stable the ~ prefix is removed. So, if you've confirmed that
65			# your ebuild works on x86 and ppc, you'd specify: KEYWORDS="~x86 ~ppc"
66	vapier	1.22	# For binary packages, use -* and then list the archs the bin package
67			# exists for. If the package was for an x86 binary package, then
68			# KEYWORDS would be set like this: KEYWORDS="-* x86"
69	vapier	1.27	# DO NOT USE KEYWORDS="*". This is deprecated and only for backward
70	blizzy	1.11	# compatibility reasons.
71	seemant	1.18	KEYWORDS="~x86"
72	blizzy	1.15
73			# Comprehensive list of any and all USE flags leveraged in the ebuild,
74			# with the exception of any ARCH specific flags, i.e. "ppc", "sparc",
75	vapier	1.27	# "x86" and "alpha". This is a required variable. If the ebuild doesn't
76			# use any USE flags, set to "".
77	blizzy	1.15	IUSE="X gnome"
78	blizzy	1.9
79	mr_bones_	1.29	# A space delimited list of portage features to restrict. man 5 ebuild
80			# for details. Usually not needed.
81			#RESTRICT="nostrip"
82
83	gbevin	1.3	# Build-time dependencies, such as
84	agriffis	1.24	# ssl? ( >=dev-libs/openssl-0.9.6b )
85			# >=dev-lang/perl-5.6.1-r1
86	gbevin	1.3	# It is advisable to use the >= syntax show above, to reflect what you
87			# had installed on your system when you tested the package. Then
88			# other users hopefully won't be caught without the right version of
89			# a dependency.
90			DEPEND=""
91
92			# Run-time dependencies, same as DEPEND if RDEPEND isn't defined:
93			#RDEPEND=""
94	agenkin	1.7
95			# Source directory; the dir where the sources can be found (automatically
96	mr_bones_	1.26	# unpacked) inside ${WORKDIR}. The default value for S is ${WORKDIR}/${P}
97			# If you don't need to change it, leave the S= line out of the ebuild
98			# to keep it tidy.
99	seemant	1.18	S=${WORKDIR}/${P}
100	achim	1.1
101			src_compile() {
102	gbevin	1.3	# Most open-source packages use GNU autoconf for configuration.
103	vapier	1.33	# The quickest (and preferred) way of running configure is:
104			econf \|\| die "econf failed"
105			#
106			# You could use something similar to the following lines to
107	gbevin	1.3	# configure your package before compilation. The "\|\| die" portion
108			# at the end will stop the build process if the command fails.
109			# You should use this at the end of critical commands in the build
110			# process. (Hint: Most commands are critical, that is, the build
111			# process should abort if they aren't successful.)
112	vapier	1.33	#./configure \
113			# --host=${CHOST} \
114			# --prefix=/usr \
115			# --infodir=/usr/share/info \
116			# --mandir=/usr/share/man \|\| die "./configure failed"
117	gbevin	1.3	# Note the use of --infodir and --mandir, above. This is to make
118			# this package FHS 2.2-compliant. For more information, see
119			# http://www.pathname.com/fhs/
120	blizzy	1.9
121	gbevin	1.3	# emake (previously known as pmake) is a script that calls the
122			# standard GNU make with parallel building options for speedier
123			# builds (especially on SMP systems). Try emake first. It might
124	mr_bones_	1.26	# not work for some packages, because some makefiles have bugs
125			# related to parallelism, in these cases, use emake -j1 to limit
126			# make to a single process. The -j1 is a visual clue to others
127			# that the makefiles have bugs that have been worked around.
128			emake \|\| die "emake failed"
129	achim	1.1	}
130
131	vapier	1.13	src_install() {
132	gbevin	1.3	# You must personally verify that this trick doesn't install
133			# anything outside of DESTDIR; do this by reading and
134	blizzy	1.9	# understanding the install part of the Makefiles.
135	vapier	1.32	# This is the preferred way to install.
136	gbevin	1.3	make DESTDIR=${D} install \|\| die
137	vapier	1.32
138	gbevin	1.3	# For Makefiles that don't make proper use of DESTDIR, setting
139			# prefix is often an alternative. However if you do this, then
140			# you also need to specify mandir and infodir, since they were
141			# passed to ./configure as absolute paths (overriding the prefix
142			# setting).
143			#make \
144			# prefix=${D}/usr \
145			# mandir=${D}/usr/share/man \
146			# infodir=${D}/usr/share/info \
147	lv	1.30	# libdir=${D}/usr/$(get_libdir) \
148	gbevin	1.3	# install \|\| die
149			# Again, verify the Makefiles! We don't want anything falling
150			# outside of ${D}.
151	seemant	1.17
152			# The portage shortcut to the above command is simply:
153			#
154	seemant	1.20	#einstall \|\| die
155	achim	1.1	}