/[gentoo-x86]/skel.ebuild
Gentoo

Contents of /skel.ebuild

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.45 - (show annotations) (download)
Wed Mar 12 22:39:13 2008 UTC (6 years, 5 months ago) by solar
Branch: MAIN
Changes since 1.44: +0 -7 lines
- do not encourage the use of EAPI=1 in the skel..

1 # Copyright 1999-2008 Gentoo Foundation
2 # Distributed under the terms of the GNU General Public License v2
3 # $Header: $
4
5 # NOTE: The comments in this file are for instruction and documentation.
6 # They're not meant to appear with your final, production ebuild. Please
7 # remember to remove them before submitting or committing your ebuild. That
8 # doesn't mean you can't add your own comments though.
9
10 # The 'Header' on the third line should just be left alone. When your ebuild
11 # will be committed to cvs, the details on that line will be automatically
12 # generated to contain the correct data.
13
14 # inherit lists eclasses to inherit functions from. Almost all ebuilds should
15 # inherit eutils, as a large amount of important functionality has been
16 # moved there. For example, the $(get_libdir) mentioned below wont work
17 # without the following line:
18 inherit eutils
19 # A well-used example of an eclass function that needs eutils is epatch. If
20 # your source needs patches applied, it's suggested to put your patch in the
21 # 'files' directory and use:
22 #
23 # epatch ${FILESDIR}/patch-name-here
24 #
25 # eclasses tend to list descriptions of how to use their functions properly.
26 # take a look at /usr/portage/eclasses/ for more examples.
27
28 # Short one-line description of this package.
29 DESCRIPTION="This is a sample skeleton ebuild file"
30
31 # Homepage, not used by Portage directly but handy for developer reference
32 HOMEPAGE="http://foo.bar.com/"
33
34 # Point to any required sources; these will be automatically downloaded by
35 # Portage.
36 SRC_URI="ftp://foo.bar.com/${P}.tar.gz"
37
38 # License of the package. This must match the name of file(s) in
39 # /usr/portage/licenses/. For complex license combination see the developer
40 # docs on gentoo.org for details.
41 LICENSE=""
42
43 # The SLOT variable is used to tell Portage if it's OK to keep multiple
44 # versions of the same package installed at the same time. For example,
45 # if we have a libfoo-1.2.2 and libfoo-1.3.2 (which is not compatible
46 # with 1.2.2), it would be optimal to instruct Portage to not remove
47 # libfoo-1.2.2 if we decide to upgrade to libfoo-1.3.2. To do this,
48 # we specify SLOT="1.2" in libfoo-1.2.2 and SLOT="1.3" in libfoo-1.3.2.
49 # emerge clean understands SLOTs, and will keep the most recent version
50 # of each SLOT and remove everything else.
51 # Note that normal applications should use SLOT="0" if possible, since
52 # there should only be exactly one version installed at a time.
53 # DO NOT USE SLOT=""! This tells Portage to disable SLOTs for this package.
54 SLOT="0"
55
56 # Using KEYWORDS, we can record masking information *inside* an ebuild
57 # instead of relying on an external package.mask file. Right now, you should
58 # set the KEYWORDS variable for every ebuild so that it contains the names of
59 # all the architectures with which the ebuild works. All of the official
60 # architectures can be found in the keywords.desc file which is in
61 # /usr/portage/profiles/. Usually you should just set this to "~x86". The ~
62 # in front of the architecture indicates that the package is new and should be
63 # considered unstable until testing proves its stability. So, if you've
64 # confirmed that your ebuild works on x86 and ppc, you'd specify:
65 # KEYWORDS="~x86 ~ppc"
66 # Once packages go stable, the ~ prefix is removed.
67 # For binary packages, use -* and then list the archs the bin package
68 # exists for. If the package was for an x86 binary package, then
69 # KEYWORDS would be set like this: KEYWORDS="-* x86"
70 # DO NOT USE KEYWORDS="*". This is deprecated and only for backward
71 # compatibility reasons.
72 KEYWORDS="~x86"
73
74 # Comprehensive list of any and all USE flags leveraged in the ebuild,
75 # with the exception of any ARCH specific flags, i.e. "ppc", "sparc",
76 # "x86" and "alpha". This is a required variable. If the ebuild doesn't
77 # use any USE flags, set to "".
78 IUSE="gnome X"
79
80 # A space delimited list of portage features to restrict. man 5 ebuild
81 # for details. Usually not needed.
82 #RESTRICT="strip"
83
84 # Build-time dependencies, such as
85 # ssl? ( >=dev-libs/openssl-0.9.6b )
86 # >=dev-lang/perl-5.6.1-r1
87 # It is advisable to use the >= syntax show above, to reflect what you
88 # had installed on your system when you tested the package. Then
89 # other users hopefully won't be caught without the right version of
90 # a dependency.
91 DEPEND=""
92
93 # Run-time dependencies. Must be defined to whatever this depends on to run.
94 # The below is valid if the same run-time depends are required to compile.
95 RDEPEND="${DEPEND}"
96
97 # Source directory; the dir where the sources can be found (automatically
98 # unpacked) inside ${WORKDIR}. The default value for S is ${WORKDIR}/${P}
99 # If you don't need to change it, leave the S= line out of the ebuild
100 # to keep it tidy.
101 #S="${WORKDIR}/${P}"
102
103 src_compile() {
104 # Most open-source packages use GNU autoconf for configuration.
105 # The quickest (and preferred) way of running configure is:
106 econf || die "econf failed"
107 #
108 # You could use something similar to the following lines to
109 # configure your package before compilation. The "|| die" portion
110 # at the end will stop the build process if the command fails.
111 # You should use this at the end of critical commands in the build
112 # process. (Hint: Most commands are critical, that is, the build
113 # process should abort if they aren't successful.)
114 #./configure \
115 # --host=${CHOST} \
116 # --prefix=/usr \
117 # --infodir=/usr/share/info \
118 # --mandir=/usr/share/man || die "./configure failed"
119 # Note the use of --infodir and --mandir, above. This is to make
120 # this package FHS 2.2-compliant. For more information, see
121 # http://www.pathname.com/fhs/
122
123 # emake (previously known as pmake) is a script that calls the
124 # standard GNU make with parallel building options for speedier
125 # builds (especially on SMP systems). Try emake first. It might
126 # not work for some packages, because some makefiles have bugs
127 # related to parallelism, in these cases, use emake -j1 to limit
128 # make to a single process. The -j1 is a visual clue to others
129 # that the makefiles have bugs that have been worked around.
130 emake || die "emake failed"
131 }
132
133 src_install() {
134 # You must *personally verify* that this trick doesn't install
135 # anything outside of DESTDIR; do this by reading and
136 # understanding the install part of the Makefiles.
137 # This is the preferred way to install.
138 emake DESTDIR="${D}" install || die "emake install failed"
139
140 # When you hit a failure with emake, do not just use make. It is
141 # better to fix the Makefiles to allow proper parallelization.
142 # If you fail with that, use "emake -j1", it's still better than make.
143
144 # For Makefiles that don't make proper use of DESTDIR, setting
145 # prefix is often an alternative. However if you do this, then
146 # you also need to specify mandir and infodir, since they were
147 # passed to ./configure as absolute paths (overriding the prefix
148 # setting).
149 #emake \
150 # prefix="${D}"/usr \
151 # mandir="${D}"/usr/share/man \
152 # infodir="${D}"/usr/share/info \
153 # libdir="${D}"/usr/$(get_libdir) \
154 # install || die "emake install failed"
155 # Again, verify the Makefiles! We don't want anything falling
156 # outside of ${D}.
157
158 # The portage shortcut to the above command is simply:
159 #
160 #einstall || die "einstall failed"
161 }

  ViewVC Help
Powered by ViewVC 1.1.20