/[gentoo-x86]/skel.ebuild
Gentoo

Contents of /skel.ebuild

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.49 - (show annotations) (download)
Fri Mar 14 01:47:23 2008 UTC (6 years, 10 months ago) by solar
Branch: MAIN
Changes since 1.48: +6 -4 lines
- clarify exactly when EAPI > 0 should and should not be used. solar/Betelgeuse

1 # Copyright 1999-2008 Gentoo Foundation
2 # Distributed under the terms of the GNU General Public License v2
3 # $Header: $
4
5 # NOTE: The comments in this file are for instruction and documentation.
6 # They're not meant to appear with your final, production ebuild. Please
7 # remember to remove them before submitting or committing your ebuild. That
8 # doesn't mean you can't add your own comments though.
9
10 # The 'Header' on the third line should just be left alone. When your ebuild
11 # will be committed to cvs, the details on that line will be automatically
12 # generated to contain the correct data.
13
14 # The EAPI variable tells the ebuild format in use.
15 # Defaults to 0 if not specified. The current PMS draft contains details on
16 # a proposed EAPI=0 definition but is not finalized yet. It is for this
17 # reason that using EAPI > 0 should be avoided.
18 # Eclasses will test for this variable if they need to use EAPI > 0 features.
19 # Ebuilds should not define EAPI > 0 unless they absolutely need to use
20 # features added in that version.
21 #EAPI=0
22
23 # inherit lists eclasses to inherit functions from. Almost all ebuilds should
24 # inherit eutils, as a large amount of important functionality has been
25 # moved there. For example, the $(get_libdir) mentioned below wont work
26 # without the following line:
27 inherit eutils
28 # A well-used example of an eclass function that needs eutils is epatch. If
29 # your source needs patches applied, it's suggested to put your patch in the
30 # 'files' directory and use:
31 #
32 # epatch ${FILESDIR}/patch-name-here
33 #
34 # eclasses tend to list descriptions of how to use their functions properly.
35 # take a look at /usr/portage/eclasses/ for more examples.
36
37 # Short one-line description of this package.
38 DESCRIPTION="This is a sample skeleton ebuild file"
39
40 # Homepage, not used by Portage directly but handy for developer reference
41 HOMEPAGE="http://foo.bar.com/"
42
43 # Point to any required sources; these will be automatically downloaded by
44 # Portage.
45 SRC_URI="ftp://foo.bar.com/${P}.tar.gz"
46
47 # License of the package. This must match the name of file(s) in
48 # /usr/portage/licenses/. For complex license combination see the developer
49 # docs on gentoo.org for details.
50 LICENSE=""
51
52 # The SLOT variable is used to tell Portage if it's OK to keep multiple
53 # versions of the same package installed at the same time. For example,
54 # if we have a libfoo-1.2.2 and libfoo-1.3.2 (which is not compatible
55 # with 1.2.2), it would be optimal to instruct Portage to not remove
56 # libfoo-1.2.2 if we decide to upgrade to libfoo-1.3.2. To do this,
57 # we specify SLOT="1.2" in libfoo-1.2.2 and SLOT="1.3" in libfoo-1.3.2.
58 # emerge clean understands SLOTs, and will keep the most recent version
59 # of each SLOT and remove everything else.
60 # Note that normal applications should use SLOT="0" if possible, since
61 # there should only be exactly one version installed at a time.
62 # DO NOT USE SLOT=""! This tells Portage to disable SLOTs for this package.
63 SLOT="0"
64
65 # Using KEYWORDS, we can record masking information *inside* an ebuild
66 # instead of relying on an external package.mask file. Right now, you should
67 # set the KEYWORDS variable for every ebuild so that it contains the names of
68 # all the architectures with which the ebuild works. All of the official
69 # architectures can be found in the keywords.desc file which is in
70 # /usr/portage/profiles/. Usually you should just set this to "~x86". The ~
71 # in front of the architecture indicates that the package is new and should be
72 # considered unstable until testing proves its stability. So, if you've
73 # confirmed that your ebuild works on x86 and ppc, you'd specify:
74 # KEYWORDS="~x86 ~ppc"
75 # Once packages go stable, the ~ prefix is removed.
76 # For binary packages, use -* and then list the archs the bin package
77 # exists for. If the package was for an x86 binary package, then
78 # KEYWORDS would be set like this: KEYWORDS="-* x86"
79 # DO NOT USE KEYWORDS="*". This is deprecated and only for backward
80 # compatibility reasons.
81 KEYWORDS="~x86"
82
83 # Comprehensive list of any and all USE flags leveraged in the ebuild,
84 # with the exception of any ARCH specific flags, i.e. "ppc", "sparc",
85 # "x86" and "alpha". This is a required variable. If the ebuild doesn't
86 # use any USE flags, set to "".
87 IUSE="gnome X"
88
89 # A space delimited list of portage features to restrict. man 5 ebuild
90 # for details. Usually not needed.
91 #RESTRICT="strip"
92
93 # Build-time dependencies, such as
94 # ssl? ( >=dev-libs/openssl-0.9.6b )
95 # >=dev-lang/perl-5.6.1-r1
96 # It is advisable to use the >= syntax show above, to reflect what you
97 # had installed on your system when you tested the package. Then
98 # other users hopefully won't be caught without the right version of
99 # a dependency.
100 DEPEND=""
101
102 # Run-time dependencies. Must be defined to whatever this depends on to run.
103 # The below is valid if the same run-time depends are required to compile.
104 RDEPEND="${DEPEND}"
105
106 # Source directory; the dir where the sources can be found (automatically
107 # unpacked) inside ${WORKDIR}. The default value for S is ${WORKDIR}/${P}
108 # If you don't need to change it, leave the S= line out of the ebuild
109 # to keep it tidy.
110 #S="${WORKDIR}/${P}"
111
112 src_compile() {
113 # Most open-source packages use GNU autoconf for configuration.
114 # The quickest (and preferred) way of running configure is:
115 econf || die "econf failed"
116 #
117 # You could use something similar to the following lines to
118 # configure your package before compilation. The "|| die" portion
119 # at the end will stop the build process if the command fails.
120 # You should use this at the end of critical commands in the build
121 # process. (Hint: Most commands are critical, that is, the build
122 # process should abort if they aren't successful.)
123 #./configure \
124 # --host=${CHOST} \
125 # --prefix=/usr \
126 # --infodir=/usr/share/info \
127 # --mandir=/usr/share/man || die "./configure failed"
128 # Note the use of --infodir and --mandir, above. This is to make
129 # this package FHS 2.2-compliant. For more information, see
130 # http://www.pathname.com/fhs/
131
132 # emake (previously known as pmake) is a script that calls the
133 # standard GNU make with parallel building options for speedier
134 # builds (especially on SMP systems). Try emake first. It might
135 # not work for some packages, because some makefiles have bugs
136 # related to parallelism, in these cases, use emake -j1 to limit
137 # make to a single process. The -j1 is a visual clue to others
138 # that the makefiles have bugs that have been worked around.
139 emake || die "emake failed"
140 }
141
142 src_install() {
143 # You must *personally verify* that this trick doesn't install
144 # anything outside of DESTDIR; do this by reading and
145 # understanding the install part of the Makefiles.
146 # This is the preferred way to install.
147 emake DESTDIR="${D}" install || die "emake install failed"
148
149 # When you hit a failure with emake, do not just use make. It is
150 # better to fix the Makefiles to allow proper parallelization.
151 # If you fail with that, use "emake -j1", it's still better than make.
152
153 # For Makefiles that don't make proper use of DESTDIR, setting
154 # prefix is often an alternative. However if you do this, then
155 # you also need to specify mandir and infodir, since they were
156 # passed to ./configure as absolute paths (overriding the prefix
157 # setting).
158 #emake \
159 # prefix="${D}"/usr \
160 # mandir="${D}"/usr/share/man \
161 # infodir="${D}"/usr/share/info \
162 # libdir="${D}"/usr/$(get_libdir) \
163 # install || die "emake install failed"
164 # Again, verify the Makefiles! We don't want anything falling
165 # outside of ${D}.
166
167 # The portage shortcut to the above command is simply:
168 #
169 #einstall || die "einstall failed"
170 }

  ViewVC Help
Powered by ViewVC 1.1.20