/[gentoo-x86]/sys-apps/acl/acl-2.2.49-r1.ebuild
Gentoo

Contents of /sys-apps/acl/acl-2.2.49-r1.ebuild

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.1 - (show annotations) (download)
Fri Apr 15 17:08:47 2011 UTC (3 years ago) by flameeyes
Branch: MAIN
CVS Tags: HEAD
Revision bump: port to EAPI=4, drop prepalldocs, add static-libs USE flag, drop .la files if static-libs are disabled.

(Portage version: 2.2.0_alpha30/cvs/Linux x86_64)

1 # Copyright 1999-2011 Gentoo Foundation
2 # Distributed under the terms of the GNU General Public License v2
3 # $Header: /var/cvsroot/gentoo-x86/sys-apps/acl/acl-2.2.49.ebuild,v 1.7 2010/04/02 12:15:58 armin76 Exp $
4
5 EAPI=4
6
7 inherit eutils toolchain-funcs
8
9 DESCRIPTION="access control list utilities, libraries and headers"
10 HOMEPAGE="http://savannah.nongnu.org/projects/acl"
11 SRC_URI="http://download.savannah.gnu.org/releases/${PN}/${P}.src.tar.gz
12 nfs? ( http://www.citi.umich.edu/projects/nfsv4/linux/acl-patches/2.2.42-2/acl-2.2.42-CITI_NFS4_ALL-2.dif )"
13
14 LICENSE="LGPL-2.1"
15 SLOT="0"
16 KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-linux ~ia64-linux ~x86-linux"
17 IUSE="nfs nls static-libs"
18
19 RDEPEND=">=sys-apps/attr-2.4
20 nfs? ( net-libs/libnfsidmap )"
21 DEPEND="${RDEPEND}
22 nls? ( sys-devel/gettext )"
23
24 src_prepare() {
25 if use nfs ; then
26 cp "${DISTDIR}"/acl-2.2.42-CITI_NFS4_ALL-2.dif . || die
27 sed -i \
28 -e '/^diff --git a.debian.changelog b.debian.changelog/,/^diff --git/d' \
29 acl-2.2.42-CITI_NFS4_ALL-2.dif || die
30 epatch acl-2.2.42-CITI_NFS4_ALL-2.dif
31 fi
32 epatch "${FILESDIR}"/${P}-quote-strchr.patch
33 sed -i \
34 -e '/^as_dummy=/s:=":="$PATH$PATH_SEPARATOR:' \
35 configure # hack PATH with AC_PATH_PROG
36 sed -i \
37 -e "/^PKG_DOC_DIR/s:@pkg_name@:${PF}:" \
38 -e '/HAVE_ZIPPED_MANPAGES/s:=.*:=false:' \
39 include/builddefs.in \
40 || die "failed to update builddefs"
41 strip-linguas po
42 }
43
44 src_configure() {
45 unset PLATFORM #184564
46 export OPTIMIZER=${CFLAGS}
47 export DEBUG=-DNDEBUG
48
49 econf \
50 $(use_enable nls gettext) \
51 --enable-shared $(use_enable static-libs static) \
52 --libexecdir="${EPREFIX}"/usr/$(get_libdir) \
53 --bindir="${EPREFIX}"/bin
54 }
55
56 src_install() {
57 emake DIST_ROOT="${D}" install install-dev install-lib || die
58 use static-libs || find "${D}" -name '*.la' -delete
59
60 # move shared libs to /
61 gen_usr_ldscript -a acl
62 }

  ViewVC Help
Powered by ViewVC 1.1.20