/[gentoo-x86]/sys-apps/hal/hal-0.5.11-r8.ebuild
Gentoo

Contents of /sys-apps/hal/hal-0.5.11-r8.ebuild

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.1 - (show annotations) (download)
Wed Feb 4 22:58:27 2009 UTC (5 years, 8 months ago) by chainsaw
Branch: MAIN
Revive a patch by Cardoe to fix test failures, closes bug #176535. Enable support for MacBook/MacBook Pro if USE="laptop", closes bug #200643. Patch from Ambroz Bizjak <ambro@b4ever.net> removes ill-conceived UID checks so NTFS volumes can be automounted, closes bug #205901. Upstream commits scavenged by Ricardo Salveti <ricardo.salveti@openbossa.org> allow mac80211-based wireless devices to be detected properly, closes bug #246026. Reverted partition unhiding from bug #247025, it was already controversial but has been proven to automount recovery partitions.
(Portage version: 2.1.6.7/cvs/Linux x86_64)

1 # Copyright 1999-2009 Gentoo Foundation
2 # Distributed under the terms of the GNU General Public License v2
3 # $Header: /var/cvsroot/gentoo-x86/sys-apps/hal/hal-0.5.11-r7.ebuild,v 1.2 2009/02/04 14:27:53 chainsaw Exp $
4
5 inherit eutils linux-info autotools flag-o-matic
6
7 PATCH_VERSION="5"
8
9 DESCRIPTION="Hardware Abstraction Layer"
10 HOMEPAGE="http://www.freedesktop.org/Software/hal"
11 SRC_URI="http://hal.freedesktop.org/releases/${P/_/}.tar.bz2
12 http://dev.gentoo.org/~chainsaw/files/${P}-gentoo-patches-${PATCH_VERSION}.tar.bz2"
13
14 LICENSE="|| ( GPL-2 AFL-2.0 )"
15 SLOT="0"
16 KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sh ~sparc ~x86 ~x86-fbsd"
17
18 KERNEL_IUSE="kernel_linux kernel_FreeBSD"
19 IUSE="X acpi apm crypt debug dell disk-partition doc laptop selinux ${KERNEL_IUSE}"
20
21 RDEPEND=">=dev-libs/dbus-glib-0.61
22 >=dev-libs/glib-2.14
23 >=dev-libs/expat-1.95.8
24 >=dev-libs/libusb-0.1.10a
25 >=sys-apps/pciutils-2.2.7-r1
26 >=dev-util/gperf-3.0.3
27 sys-apps/usbutils
28 virtual/eject
29 amd64? ( >=sys-apps/dmidecode-2.7 )
30 dell? ( >=sys-libs/libsmbios-0.13.4 )
31 disk-partition? ( >=sys-apps/parted-1.8.0 )
32 ia64? ( >=sys-apps/dmidecode-2.7 )
33 kernel_linux? (
34 >=sys-fs/udev-117
35 >=sys-apps/util-linux-2.13
36 >=sys-kernel/linux-headers-2.6.19
37 crypt? ( >=sys-fs/cryptsetup-1.0.5 )
38 )
39 kernel_FreeBSD? ( >=dev-libs/libvolume_id-0.77 )
40 x86? ( >=sys-apps/dmidecode-2.7 )
41 selinux? ( sys-libs/libselinux sec-policy/selinux-hal )"
42 DEPEND="${RDEPEND}
43 dev-util/pkgconfig
44 >=dev-util/intltool-0.35
45 doc? (
46 app-text/xmlto
47 dev-libs/libxml2
48 dev-util/gtk-doc
49 app-text/docbook-sgml-utils
50 )"
51 PDEPEND="|| (
52 >=app-misc/hal-info-20081219 )
53 !gnome-extra/hal-device-manager
54 laptop? ( >=sys-power/pm-utils-0.99.3 )"
55
56 ## HAL Daemon drops privledges so we need group access to read disks
57 HALDAEMON_GROUPS_LINUX="haldaemon,plugdev,disk,cdrom,cdrw,floppy,usb"
58 HALDAEMON_GROUPS_FREEBSD="haldaemon,plugdev,operator"
59
60 function check_hotplug_net() {
61 local CONFIG_CHECK="~HOTPLUG ~NET"
62 local WARNING_HOTPLUG="CONFIG_HOTPLUG:\tis not set (required for HAL)\n"
63 local WARNING_NET="CONFIG_NET:\tis not set (required for HAL)\n"
64 check_extra_config
65 }
66
67 function check_inotify() {
68 local CONFIG_CHECK="~INOTIFY_USER"
69 local WARNING_INOTIFY_USER="CONFIG_INOTIFY_USER:\tis not set (required for HAL)\n"
70 check_extra_config
71 }
72
73 function check_acpi_proc() {
74 local CONFIG_CHECK="~ACPI_PROCFS ~ACPI_PROC_EVENT"
75 local WARNING_ACPI_PROCFS="CONFIG_ACPI_PROCFS:\tis not set (required for HAL)\n"
76 local WARNING_ACPI_PROC_EVENT="CONFIG_ACPI_PROC_EVENT:\tis not set (required for HAL)\n"
77 check_extra_config
78 }
79
80 pkg_setup() {
81 if use kernel_linux ; then
82 if [[ -e "${ROOT}/usr/src/linux/.config" ]] ; then
83 kernel_is ge 2 6 19 || ewarn "HAL requires a kernel version 2.6.19 or newer"
84
85 if kernel_is lt 2 6 23 && use acpi ; then
86 check_acpi_proc
87 fi
88 fi
89
90 check_hotplug_net
91 check_inotify
92 fi
93
94 # http://devmanual.gentoo.org/ebuild-writing/functions/
95 # http://bugs.gentoo.org/show_bug.cgi?id=191605
96
97 # Create groups for hotplugging and HAL
98 enewgroup haldaemon
99 enewgroup plugdev
100
101 # HAL drops priviledges by default now ...
102 # ... so we must make sure it can read disk/cdrom info (ie. be in ${HALDAEMON_GROUPS} groups)
103 if use kernel_linux; then
104 enewuser haldaemon -1 "-1" /dev/null ${HALDAEMON_GROUPS_LINUX}
105 elif use kernel_FreeBSD; then
106 enewuser haldaemon -1 "-1" /dev/null ${HALDAEMON_GROUPS_FREEBSD}
107 fi
108
109 # Make sure that the haldaemon user is in the ${HALDAEMON_GROUPS}
110 # If users have a problem with this, let them file a bug
111 if [[ ${ROOT} == / ]] ; then
112 if use kernel_linux; then
113 usermod -G ${HALDAEMON_GROUPS_LINUX} haldaemon
114 elif use kernel_FreeBSD; then
115 pw usermod haldaemon -G ${HALDAEMON_GROUPS_FREEBSD}
116 fi
117 fi
118 }
119
120 S="${WORKDIR}/${PF/-r*/}"
121
122 src_unpack() {
123 unpack ${A}
124 cd "${S}"
125
126 EPATCH_MULTI_MSG="Applying Gentoo Patchset ..." \
127 EPATCH_SUFFIX="patch" \
128 EPATCH_SOURCE="${WORKDIR}/${P}-patches/" \
129 EPATCH_FORCE="yes" \
130 epatch
131
132 eautoreconf
133 }
134
135 src_compile() {
136 local acpi="$(use_enable acpi)"
137 local backend=
138 local hardware=
139
140 append-flags -rdynamic
141
142 if use kernel_linux ; then
143 backend="linux"
144 elif use kernel_FreeBSD ; then
145 backend="freebsd"
146 else
147 eerror "Invalid backend"
148 fi
149
150 if use kernel_linux ; then
151 if use acpi ; then
152 # Using IBM ACPI and Toshiba ACPI results in double notification as this
153 # was merged into the Linux Kernel 2.6.22
154 if kernel_is lt 2 6 22 ; then
155 acpi="$acpi --enable-acpi-ibm --enable-acpi-toshiba"
156 else
157 acpi="$acpi --disable-acpi-ibm --disable-acpi-toshiba"
158 fi
159
160 acpi="$acpi --enable-acpi-proc --enable-acpi-acpid"
161 else
162 acpi="$acpi --disable-acpi-ibm --disable-acpi-toshiba"
163 acpi="$acpi --disable-acpi-proc --disable-acpi-acpid"
164 fi
165
166 hardware="--with-cpufreq --with-usb-csr --with-keymaps"
167 use arm && hardware="$hardware --with-omap --enable-pmu"
168 use ppc && hardware="$hardware --enable-pmu"
169 use laptop && hardware="--with-macbook --with-macbookpro"
170
171 if use dell ; then
172 hardware="$hardware --with-dell-backlight"
173 else
174 hardware="$hardware --without-dell-backlight"
175 fi
176
177 hardware="$hardware --enable-sonypic"
178 else
179 hardware="--without-cpufreq --without-usb-csr --without-keymaps"
180 hardware="$hardware --without-omap"
181 hardware="$hardware --without-dell-backlight"
182 hardware="$hardware --enable-acpi-ibm --enable-acpi-toshiba"
183 hardware="$hardware --disable-sonypic"
184 fi
185
186 econf --with-backend=${backend} \
187 --with-os-type=gentoo \
188 --with-pid-file=/var/run/hald.pid \
189 --with-hwdata=/usr/share/misc \
190 --with-socket-dir=/var/run/hald \
191 --enable-umount-helper \
192 --enable-man-pages \
193 --disable-policy-kit \
194 --disable-console-kit \
195 --disable-acl-management \
196 --enable-pci \
197 $(use_enable apm) \
198 $(use_enable debug verbose-mode) \
199 $(use_enable disk-partition parted) \
200 $(use_enable doc docbook-docs) \
201 $(use_enable doc gtk-doc) \
202 --docdir=/usr/share/doc/${PF} \
203 --localstatedir=/var \
204 ${acpi} ${hardware} \
205 || die "configure failed"
206
207 emake || die "make failed"
208 }
209
210 src_install() {
211 emake DESTDIR="${D}" install || die
212 dodoc AUTHORS ChangeLog NEWS README || die "docs failed"
213
214 # hal umount for unclean unmounts
215 exeinto /lib/udev/
216 newexe "${FILESDIR}/hal-unmount.dev" hal_unmount || die "udev helper failed"
217
218 # initscript
219 newinitd "${FILESDIR}/0.5.10-hald.rc" hald || die "init script failed"
220
221 # configuration
222 cp "${FILESDIR}/0.5.10-hald.conf" "${WORKDIR}/" || \
223 die "failed to copy hald.conf"
224
225 if use debug; then
226 sed -e 's:HALD_VERBOSE="no":HALD_VERBOSE="yes":' \
227 -i "${WORKDIR}/0.5.10-hald.conf" || die "failed to change verbose"
228 fi
229 newconfd "${WORKDIR}/0.5.10-hald.conf" hald || \
230 die "failed to install hald.conf"
231
232 if use X ; then
233 # New Configuration Snippets
234 dodoc "${WORKDIR}/${PN}-config-examples/"*.fdi || \
235 die "dodoc X examples failed"
236 fi
237
238 # We now create and keep /media here as both gnome-mount and pmount
239 # use these directories, to avoid collision.
240 keepdir /media
241
242 # We also need to create and keep /etc/fdi/{information,policy,preprobe}
243 # or else hal bombs.
244 keepdir /etc/hal/fdi/{information,policy,preprobe}
245
246 # HAL stores it's fdi cache in /var/lib/cache/hald
247 keepdir /var/lib/cache/hald
248
249 # HAL keeps its unix socket here
250 keepdir /var/run/hald
251 keepdir /var/lib/hal
252 }
253
254 pkg_postinst() {
255 # Despite what people keep changing this location. Either one works.. it doesn't matter
256 # http://dev.gentoo.org/~plasmaroo/devmanual/ebuild-writing/functions/
257
258 elog "The HAL daemon needs to be running for certain applications to"
259 elog "work. Suggested is to add the init script to your start-up"
260 elog "scripts, this should be done like this :"
261 elog "\`rc-update add hald default\`"
262 echo
263 elog "Looking for automounting support? Add yourself to the plugdev group"
264 echo
265 elog "IF you have additional applications which consume ACPI events, you"
266 elog "should consider installing acpid to allow applications to share ACPI"
267 elog "events."
268 if use X ; then
269 echo
270 elog "If you wish to use a non US layout, you may do so by executing:"
271 elog "setxkbmap <layout> or by utilizing your Desktop Environment's"
272 elog "Keyboard Layout Settings mechanism."
273 elog "Under GNOME, this is gnome-keyboard-properties, and under KDE"
274 elog "it is kxkb."
275 fi
276 echo
277 elog "In order have suspend/hibernate function with HAL or apps that use HAL"
278 elog "(such as gnome-power-manager), you should build HAL with the laptop"
279 elog "useflag which will install pm-utils."
280 if use X ; then
281 echo
282 elog "X Input Hotplugging (if you build xorg-server with the HAL useflag)"
283 elog "reads user specific configuration from /etc/hal/fdi/policy/."
284 echo
285 elog "You should remove the Input sections from your xorg.conf once you have"
286 elog "migrated the rules to a HAL fdi file."
287 fi
288
289 ebeep 5
290 epause 5
291 }

  ViewVC Help
Powered by ViewVC 1.1.20