/[gentoo-x86]/sys-apps/man-db/man-db-2.6.2.ebuild
Gentoo

Contents of /sys-apps/man-db/man-db-2.6.2.ebuild

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.1 - (hide annotations) (download)
Tue Jul 24 15:59:58 2012 UTC (2 years, 1 month ago) by vapier
Branch: MAIN
Version bump.

(Portage version: 2.2.0_alpha116/cvs/Linux x86_64)

1 vapier 1.1 # Copyright 1999-2012 Gentoo Foundation
2     # Distributed under the terms of the GNU General Public License v2
3     # $Header: /var/cvsroot/gentoo-x86/sys-apps/man-db/man-db-2.6.1.ebuild,v 1.3 2012/05/24 03:07:45 vapier Exp $
4    
5     EAPI="4"
6    
7     inherit eutils user
8    
9     DESCRIPTION="a man replacement that utilizes berkdb instead of flat files"
10     HOMEPAGE="http://www.nongnu.org/man-db/"
11     SRC_URI="mirror://nongnu/${PN}/${P}.tar.gz"
12    
13     LICENSE="GPL-3"
14     SLOT="0"
15     KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86"
16     IUSE="berkdb +gdbm nls static-libs zlib"
17    
18     RDEPEND="dev-libs/libpipeline
19     berkdb? ( sys-libs/db )
20     gdbm? ( sys-libs/gdbm )
21     !berkdb? ( !gdbm? ( sys-libs/gdbm ) )
22     sys-apps/groff
23     zlib? ( sys-libs/zlib )
24     !sys-apps/man"
25     DEPEND="${RDEPEND}
26     virtual/pkgconfig
27     nls? ( sys-devel/gettext )"
28    
29     pkg_setup() {
30     # Create user now as Makefile in src_install does setuid/chown
31     enewgroup man 15
32     enewuser man 13 -1 /usr/share/man man
33     }
34    
35     src_prepare() {
36     epatch "${FILESDIR}"/${PN}-2.6.1-no-gets.patch #427252
37     }
38    
39     src_configure() {
40     export ac_cv_lib_z_gzopen=$(usex zlib)
41     econf \
42     --with-sections="1 1p 8 2 3 3p 4 5 6 7 9 0p tcl n l p o 1x 2x 3x 4x 5x 6x 7x 8x" \
43     $(use_enable nls) \
44     $(use_enable static-libs static) \
45     --with-db=$(usex gdbm gdbm $(usex berkdb db gdbm))
46     }
47    
48     src_install() {
49     default
50     dodoc docs/{HACKING,TODO}
51     use static-libs || find "${ED}"/usr/ -name '*.la' -delete
52     }

  ViewVC Help
Powered by ViewVC 1.1.20