/[gentoo-x86]/sys-apps/pacman/pacman-4.0.1.ebuild
Gentoo

Contents of /sys-apps/pacman/pacman-4.0.1.ebuild

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.3 - (show annotations) (download)
Sat Jun 16 05:28:26 2012 UTC (2 years, 4 months ago) by binki
Branch: MAIN
CVS Tags: HEAD
Changes since 1.2: +10 -1 lines
Fix inconsistency between m4/gettext.m4 and Makefile.in.in caused by autopoint running. Fixes bug #420469 by Ilya Gordeev.

(Portage version: 2.2.0_alpha110-r1/cvs/Linux x86_64)

1 # Copyright 1999-2012 Gentoo Foundation
2 # Distributed under the terms of the GNU General Public License v2
3 # $Header: /var/cvsroot/gentoo-x86/sys-apps/pacman/pacman-4.0.1.ebuild,v 1.2 2012/05/08 18:47:47 jdhore Exp $
4
5 EAPI=4
6
7 inherit autotools autotools-utils bash-completion-r1 eutils
8
9 DESCRIPTION="Archlinux's binary package manager"
10 HOMEPAGE="http://archlinux.org/pacman/"
11 SRC_URI="ftp://ftp.archlinux.org/other/${PN}/${P}.tar.gz"
12
13 LICENSE="GPL-2"
14 SLOT="0"
15 KEYWORDS="~amd64 ~x86"
16 IUSE="curl debug doc gpg test"
17
18 COMMON_DEPEND="app-arch/libarchive
19 dev-libs/openssl
20 virtual/libiconv
21 virtual/libintl
22 sys-devel/gettext
23 curl? ( net-misc/curl )
24 gpg? ( app-crypt/gpgme )"
25 RDEPEND="${COMMON_DEPEND}
26 app-arch/xz-utils"
27 # autoconf macros from gpgme requied unconditionally
28 DEPEND="${COMMON_DEPEND}
29 app-crypt/gpgme
30 doc? ( app-doc/doxygen
31 app-text/asciidoc )
32 test? ( dev-lang/python )"
33
34 RESTRICT="test"
35
36 src_prepare() {
37 # Adds AM_GPGME_PATH call which requires app-crypt/gpgme to be
38 # DEPENDed on unconditionally:
39 epatch "${FILESDIR}"/${PN}-4.0.0-gpgme.patch
40
41 # Remove a line that adds -Werror in ./configure when --enable-debug
42 # is passed:
43 sed -i -e '/-Werror/d' configure.ac || die "-Werror"
44
45 # autopoint is unwilling to replace m4/gettext.m4 with the correct
46 # version even though it'll gladly replace */po/Makefile.in.in,
47 # creating an inconsistency between gettext m4 macros and
48 # Makefile.in.in. Also, AM_MKINSTALLDIRS apparently doesn't exist
49 # anymore, so we need newer gettext macros. #420469
50 rm m4/gettext.m4 || die
51 sed -i -e '/AM_GNU_GETTEXT_VERSION/s/0\.13\.1/0.18.1/' configure.ac || die
52
53 eautoreconf
54 }
55
56 src_configure() {
57 local myeconfargs=(
58 --localstatedir=/var
59 --disable-git-version
60 --with-openssl
61 # Help protect user from shooting his/her Gentoo installation in
62 # its foot.
63 --with-root-dir="${EPREFIX}"/var/chroot/archlinux
64 $(use_enable debug)
65 $(use_enable doc)
66 $(use_enable doc doxygen)
67 $(use_with curl libcurl)
68 $(use_with gpg gpgme)
69 )
70 autotools-utils_src_configure
71 }
72
73 src_install() {
74 autotools-utils_src_install
75
76 dodir /etc/pacman.d
77 newbashcomp "${AUTOTOOLS_BUILD_DIR}"/contrib/bash_completion pacman
78 }
79
80 pkg_postinst() {
81 einfo "Please see http://ohnopub.net/~ohnobinki/gentoo/arch/ for information"
82 einfo "about setting up an archlinux chroot."
83 }

  ViewVC Help
Powered by ViewVC 1.1.20