sys-apps/portage/portage-2.1.11.20.ebuild

# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-apps/portage/portage-2.1.11.20.ebuild,v 1.2 2012/09/22 01:35:24 zmedico Exp $

# Require EAPI 2 since we now require at least python-2.6 (for python 3
# syntax support) which also requires EAPI 2.
EAPI=2
inherit eutils python

DESCRIPTION="Portage is the package management and distribution system for Gentoo"
HOMEPAGE="http://www.gentoo.org/proj/en/portage/index.xml"
LICENSE="GPL-2"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~sparc-fbsd ~x86-fbsd"
SLOT="0"
IUSE="build doc epydoc +ipc linguas_pl pypy1_9 python2 python3 selinux xattr"

# Import of the io module in python-2.6 raises ImportError for the
# thread module if threading is disabled.
python_dep_ssl="python3? ( =dev-lang/python-3*[ssl] )
        !pypy1_9? ( !python2? ( !python3? (
                || ( >=dev-lang/python-2.7[ssl] dev-lang/python:2.6[threads,ssl] )
        ) ) )
        pypy1_9? ( !python2? ( !python3? ( dev-python/pypy:1.9[bzip2,ssl] ) ) )
        python2? ( !python3? ( || ( dev-lang/python:2.7[ssl] dev-lang/python:2.6[ssl,threads] ) ) )"
python_dep="${python_dep_ssl//\[ssl\]}"
python_dep="${python_dep//,ssl}"
python_dep="${python_dep//ssl,}"

# The pysqlite blocker is for bug #282760.
DEPEND="${python_dep}
        >=sys-apps/sed-4.0.5 sys-devel/patch
        doc? ( app-text/xmlto ~app-text/docbook-xml-dtd-4.4 )
        epydoc? ( >=dev-python/epydoc-2.0 !<=dev-python/pysqlite-2.4.1 )"
# Require sandbox-2.2 for bug #288863.
# For xattr, we can spawn getfattr and setfattr from sys-apps/attr, but that's
# quite slow, so it's not considered in the dependencies as an alternative to
# to python-3.3 / pyxattr. Also, xattr support is only tested with Linux, so
# for now, don't pull in xattr deps for other kernels.
# For whirlpool hash, require python[ssl] or python-mhash (bug #425046).
RDEPEND="${python_dep}
        !build? ( >=sys-apps/sed-4.0.5
                >=app-shells/bash-3.2_p17
                >=app-admin/eselect-1.2
                || ( ${python_dep_ssl} dev-python/python-mhash )
        )
        elibc_FreeBSD? ( sys-freebsd/freebsd-bin )
        elibc_glibc? ( >=sys-apps/sandbox-2.2 )
        elibc_uclibc? ( >=sys-apps/sandbox-2.2 )
        >=app-misc/pax-utils-0.1.17
        xattr? ( kernel_linux? ( || ( >=dev-lang/python-3.3_pre20110902 dev-python/pyxattr ) ) )
        selinux? ( || ( >=sys-libs/libselinux-2.0.94[python] <sys-libs/libselinux-2.0.94 ) )
        !<app-shells/bash-3.2_p17
        !<app-admin/logrotate-3.8.0"
PDEPEND="
        !build? (
                >=net-misc/rsync-2.6.4
                userland_GNU? ( >=sys-apps/coreutils-6.4 )
        )"
# coreutils-6.4 rdep is for date format in emerge-webrsync #164532
# NOTE: FEATURES=install-sources requires debugedit and rsync

SRC_ARCHIVES="http://dev.gentoo.org/~zmedico/portage/archives"

prefix_src_archives() {
        local x y
        for x in ${@}; do
                for y in ${SRC_ARCHIVES}; do
                        echo ${y}/${x}
                done
        done
}

PV_PL="2.1.2"
PATCHVER_PL=""
TARBALL_PV=$PV
SRC_URI="mirror://gentoo/${PN}-${TARBALL_PV}.tar.bz2
        $(prefix_src_archives ${PN}-${TARBALL_PV}.tar.bz2)
        linguas_pl? ( mirror://gentoo/${PN}-man-pl-${PV_PL}.tar.bz2
                $(prefix_src_archives ${PN}-man-pl-${PV_PL}.tar.bz2) )"

PATCHVER=
[[ $TARBALL_PV = $PV ]] || PATCHVER=$PV
if [ -n "${PATCHVER}" ]; then
        SRC_URI="${SRC_URI} mirror://gentoo/${PN}-${PATCHVER}.patch.bz2
        $(prefix_src_archives ${PN}-${PATCHVER}.patch.bz2)"
fi

S="${WORKDIR}"/${PN}-${TARBALL_PV}
S_PL="${WORKDIR}"/${PN}-${PV_PL}

compatible_python_is_selected() {
        [[ $(/usr/bin/python -c 'import sys ; sys.stdout.write(sys.hexversion >= 0x2060000 and "good" or "bad")') = good ]]
}

current_python_has_xattr() {
        [[ $(/usr/bin/python -c 'import sys ; sys.stdout.write(sys.hexversion >= 0x3030000 and "yes" or "no")') = yes ]] || \
        /usr/bin/python -c 'import xattr' 2>/dev/null
}

pkg_setup() {
        if use python2 && use python3 ; then
                ewarn "Both python2 and python3 USE flags are enabled, but only one"
                ewarn "can be in the shebangs. Using python3."
        fi
        if use pypy1_9 && use python3 ; then
                ewarn "Both pypy1_9 and python3 USE flags are enabled, but only one"
                ewarn "can be in the shebangs. Using python3."
        fi
        if use pypy1_9 && use python2 ; then
                ewarn "Both pypy1_9 and python2 USE flags are enabled, but only one"
                ewarn "can be in the shebangs. Using python2"
        fi
        if ! use pypy1_9 && ! use python2 && ! use python3 && \
                ! compatible_python_is_selected ; then
                ewarn "Attempting to select a compatible default python interpreter"
                local x success=0
                for x in /usr/bin/python2.* ; do
                        x=${x#/usr/bin/python2.}
                        if [[ $x -ge 6 ]] 2>/dev/null ; then
                                eselect python set python2.$x
                                if compatible_python_is_selected ; then
                                        elog "Default python interpreter is now set to python-2.$x"
                                        success=1
                                        break
                                fi
                        fi
                done
                if [ $success != 1 ] ; then
                        eerror "Unable to select a compatible default python interpreter!"
                        die "This version of portage requires at least python-2.6 to be selected as the default python interpreter (see \`eselect python --help\`)."
                fi
        fi

        if use python3; then
                python_set_active_version 3
        elif use python2; then
                python_set_active_version 2
        elif use pypy1_9; then
                python_set_active_version 2.7-pypy-1.9
        fi
}

src_prepare() {
        if [ -n "${PATCHVER}" ] ; then
                if [[ -L $S/bin/ebuild-helpers/portageq ]] ; then
                        rm "$S/bin/ebuild-helpers/portageq" \
                                || die "failed to remove portageq helper symlink"
                fi
                epatch "${WORKDIR}/${PN}-${PATCHVER}.patch"
        fi
        einfo "Setting portage.VERSION to ${PVR} ..."
        sed -e "s/^VERSION=.*/VERSION=\"${PVR}\"/" -i pym/portage/__init__.py || \
                die "Failed to patch portage.VERSION"
        sed -e "1s/VERSION/${PVR}/" -i doc/fragment/version || \
                die "Failed to patch VERSION in doc/fragment/version"
        sed -e "1s/VERSION/${PVR}/" -i man/* || \
                die "Failed to patch VERSION in man page headers"

        if ! use ipc ; then
                einfo "Disabling ipc..."
                sed -e "s:_enable_ipc_daemon = True:_enable_ipc_daemon = False:" \
                        -i pym/_emerge/AbstractEbuildProcess.py || \
                        die "failed to patch AbstractEbuildProcess.py"
        fi

        if use xattr && use kernel_linux ; then
                einfo "Adding FEATURES=xattr to make.globals ..."
                echo -e '\nFEATURES="${FEATURES} xattr"' >> cnf/make.globals \
                        || die "failed to append to make.globals"
        fi

        if use python3; then
                einfo "Converting shebangs for python3..."
                python_convert_shebangs -r 3 .
        elif use python2; then
                einfo "Converting shebangs for python2..."
                python_convert_shebangs -r 2 .
        elif use pypy1_9; then
                einfo "Converting shebangs for pypy-c1.9..."
                python_convert_shebangs -r 2.7-pypy-1.9 .
        fi

        cd "${S}/cnf" || die
        if [ -f "make.conf.${ARCH}".diff ]; then
                patch make.conf "make.conf.${ARCH}".diff || \
                        die "Failed to patch make.conf.example"
        else
                eerror ""
                eerror "Portage does not have an arch-specific configuration for this arch."
                eerror "Please notify the arch maintainer about this issue. Using generic."
                eerror ""
        fi

        sed -e "s:^option is enabled by default. In some cases this can$:option is disabled by default. In some cases this can:" \
                -i "${S}/man/emerge.1" || die
}

src_compile() {
        if use doc; then
                emake docbook || die
        fi

        if use epydoc; then
                einfo "Generating api docs"
                emake epydoc || die
        fi
}

src_test() {
        emake test || die
}

src_install() {
        emake DESTDIR="${D}" \
                sysconfdir="/etc" \
                prefix="/usr" \
                install || die

        # Use dodoc for compression, since the Makefile doesn't do that.
        dodoc "${S}"/{ChangeLog,NEWS,RELEASE-NOTES} || die

        if use linguas_pl; then
                doman -i18n=pl "${S_PL}"/man/pl/*.[0-9] || die
                doman -i18n=pl_PL.UTF-8 "${S_PL}"/man/pl_PL.UTF-8/*.[0-9] || die
        fi

        # Set PYTHONPATH for portage API consumers. This way we don't have
        # to rely on patched python having the correct path, since it has
        # been known to incorrectly add /usr/libx32/portage/pym to sys.path.
        echo "PYTHONPATH=/usr/lib/portage/pym" > \
                "${T}/05portage" || die
        doenvd "${T}/05portage" || die
}

pkg_preinst() {
        if [[ $ROOT == / ]] ; then
                # Run some minimal tests as a sanity check.
                local test_runner=$(find "$D" -name runTests)
                if [[ -n $test_runner && -x $test_runner ]] ; then
                        einfo "Running preinst sanity tests..."
                        "$test_runner" || die "preinst sanity tests failed"
                fi
        fi

        if use xattr && ! current_python_has_xattr ; then
                ewarn "For optimal performance in xattr handling, install"
                ewarn "dev-python/pyxattr, or install >=dev-lang/python-3.3 and"
                ewarn "enable USE=python3 for $CATEGORY/$PN."
        fi

        if ! use build && ! has_version dev-python/pycrypto && \
                ! has_version '>=dev-lang/python-2.6[ssl]' ; then
                ewarn "If you are an ebuild developer and you plan to commit ebuilds"
                ewarn "with this system then please install dev-python/pycrypto or"
                ewarn "enable the ssl USE flag for >=dev-lang/python-2.6 in order"
                ewarn "to enable RMD160 hash support."
                ewarn "See bug #198398 for more information."
        fi

        if [[ -d ${ROOT}var/log/portage && \
                $(ls -ld "${ROOT}var/log/portage") != *" portage portage "* ]] && \
                has_version '<sys-apps/portage-2.1.10.11' ; then
                # Initialize permissions for bug #378451 and bug #377177, since older
                # portage does not create /var/log/portage with the desired default
                # permissions.
                einfo "Applying portage group permission to ${ROOT}var/log/portage for bug #378451"
                chown portage:portage "${ROOT}var/log/portage"
                chmod g+ws "${ROOT}var/log/portage"
        fi

        if has_version '<sys-apps/portage-2.1.10.61' ; then
                ewarn "FEATURES=config-protect-if-modified is now enabled by default."
                ewarn "This causes the CONFIG_PROTECT behavior to be skipped for"
                ewarn "files that have not been modified since they were installed."
        fi
}

pkg_postinst() {
        # Compile all source files recursively. Any orphans
        # will be identified and removed in postrm.
        python_mod_optimize /usr/lib/portage/pym
}

pkg_postrm() {
        python_mod_cleanup /usr/lib/portage/pym
}
1	# Copyright 1999-2012 Gentoo Foundation
2	# Distributed under the terms of the GNU General Public License v2
3	# $Header: /var/cvsroot/gentoo-x86/sys-apps/portage/portage-2.1.11.20.ebuild,v 1.2 2012/09/22 01:35:24 zmedico Exp $
4
5	# Require EAPI 2 since we now require at least python-2.6 (for python 3
6	# syntax support) which also requires EAPI 2.
7	EAPI=2
8	inherit eutils python
9
10	DESCRIPTION="Portage is the package management and distribution system for Gentoo"
11	HOMEPAGE="http://www.gentoo.org/proj/en/portage/index.xml"
12	LICENSE="GPL-2"
13	KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~sparc-fbsd ~x86-fbsd"
14	SLOT="0"
15	IUSE="build doc epydoc +ipc linguas_pl pypy1_9 python2 python3 selinux xattr"
16
17	# Import of the io module in python-2.6 raises ImportError for the
18	# thread module if threading is disabled.
19	python_dep_ssl="python3? ( =dev-lang/python-3*[ssl] )
20	!pypy1_9? ( !python2? ( !python3? (
21	\|\| ( >=dev-lang/python-2.7[ssl] dev-lang/python:2.6[threads,ssl] )
22	) ) )
23	pypy1_9? ( !python2? ( !python3? ( dev-python/pypy:1.9[bzip2,ssl] ) ) )
24	python2? ( !python3? ( \|\| ( dev-lang/python:2.7[ssl] dev-lang/python:2.6[ssl,threads] ) ) )"
25	python_dep="${python_dep_ssl//\[ssl\]}"
26	python_dep="${python_dep//,ssl}"
27	python_dep="${python_dep//ssl,}"
28
29	# The pysqlite blocker is for bug #282760.
30	DEPEND="${python_dep}
31	>=sys-apps/sed-4.0.5 sys-devel/patch
32	doc? ( app-text/xmlto ~app-text/docbook-xml-dtd-4.4 )
33	epydoc? ( >=dev-python/epydoc-2.0 !<=dev-python/pysqlite-2.4.1 )"
34	# Require sandbox-2.2 for bug #288863.
35	# For xattr, we can spawn getfattr and setfattr from sys-apps/attr, but that's
36	# quite slow, so it's not considered in the dependencies as an alternative to
37	# to python-3.3 / pyxattr. Also, xattr support is only tested with Linux, so
38	# for now, don't pull in xattr deps for other kernels.
39	# For whirlpool hash, require python[ssl] or python-mhash (bug #425046).
40	RDEPEND="${python_dep}
41	!build? ( >=sys-apps/sed-4.0.5
42	>=app-shells/bash-3.2_p17
43	>=app-admin/eselect-1.2
44	\|\| ( ${python_dep_ssl} dev-python/python-mhash )
45	)
46	elibc_FreeBSD? ( sys-freebsd/freebsd-bin )
47	elibc_glibc? ( >=sys-apps/sandbox-2.2 )
48	elibc_uclibc? ( >=sys-apps/sandbox-2.2 )
49	>=app-misc/pax-utils-0.1.17
50	xattr? ( kernel_linux? ( \|\| ( >=dev-lang/python-3.3_pre20110902 dev-python/pyxattr ) ) )
51	selinux? ( \|\| ( >=sys-libs/libselinux-2.0.94[python] <sys-libs/libselinux-2.0.94 ) )
52	!<app-shells/bash-3.2_p17
53	!<app-admin/logrotate-3.8.0"
54	PDEPEND="
55	!build? (
56	>=net-misc/rsync-2.6.4
57	userland_GNU? ( >=sys-apps/coreutils-6.4 )
58	)"
59	# coreutils-6.4 rdep is for date format in emerge-webrsync #164532
60	# NOTE: FEATURES=install-sources requires debugedit and rsync
61
62	SRC_ARCHIVES="http://dev.gentoo.org/~zmedico/portage/archives"
63
64	prefix_src_archives() {
65	local x y
66	for x in ${@}; do
67	for y in ${SRC_ARCHIVES}; do
68	echo ${y}/${x}
69	done
70	done
71	}
72
73	PV_PL="2.1.2"
74	PATCHVER_PL=""
75	TARBALL_PV=$PV
76	SRC_URI="mirror://gentoo/${PN}-${TARBALL_PV}.tar.bz2
77	$(prefix_src_archives ${PN}-${TARBALL_PV}.tar.bz2)
78	linguas_pl? ( mirror://gentoo/${PN}-man-pl-${PV_PL}.tar.bz2
79	$(prefix_src_archives ${PN}-man-pl-${PV_PL}.tar.bz2) )"
80
81	PATCHVER=
82	[[ $TARBALL_PV = $PV ]] \|\| PATCHVER=$PV
83	if [ -n "${PATCHVER}" ]; then
84	SRC_URI="${SRC_URI} mirror://gentoo/${PN}-${PATCHVER}.patch.bz2
85	$(prefix_src_archives ${PN}-${PATCHVER}.patch.bz2)"
86	fi
87
88	S="${WORKDIR}"/${PN}-${TARBALL_PV}
89	S_PL="${WORKDIR}"/${PN}-${PV_PL}
90
91	compatible_python_is_selected() {
92	[[ $(/usr/bin/python -c 'import sys ; sys.stdout.write(sys.hexversion >= 0x2060000 and "good" or "bad")') = good ]]
93	}
94
95	current_python_has_xattr() {
96	[[ $(/usr/bin/python -c 'import sys ; sys.stdout.write(sys.hexversion >= 0x3030000 and "yes" or "no")') = yes ]] \|\| \
97	/usr/bin/python -c 'import xattr' 2>/dev/null
98	}
99
100	pkg_setup() {
101	if use python2 && use python3 ; then
102	ewarn "Both python2 and python3 USE flags are enabled, but only one"
103	ewarn "can be in the shebangs. Using python3."
104	fi
105	if use pypy1_9 && use python3 ; then
106	ewarn "Both pypy1_9 and python3 USE flags are enabled, but only one"
107	ewarn "can be in the shebangs. Using python3."
108	fi
109	if use pypy1_9 && use python2 ; then
110	ewarn "Both pypy1_9 and python2 USE flags are enabled, but only one"
111	ewarn "can be in the shebangs. Using python2"
112	fi
113	if ! use pypy1_9 && ! use python2 && ! use python3 && \
114	! compatible_python_is_selected ; then
115	ewarn "Attempting to select a compatible default python interpreter"
116	local x success=0
117	for x in /usr/bin/python2.* ; do
118	x=${x#/usr/bin/python2.}
119	if [[ $x -ge 6 ]] 2>/dev/null ; then
120	eselect python set python2.$x
121	if compatible_python_is_selected ; then
122	elog "Default python interpreter is now set to python-2.$x"
123	success=1
124	break
125	fi
126	fi
127	done
128	if [ $success != 1 ] ; then
129	eerror "Unable to select a compatible default python interpreter!"
130	die "This version of portage requires at least python-2.6 to be selected as the default python interpreter (see \`eselect python --help\`)."
131	fi
132	fi
133
134	if use python3; then
135	python_set_active_version 3
136	elif use python2; then
137	python_set_active_version 2
138	elif use pypy1_9; then
139	python_set_active_version 2.7-pypy-1.9
140	fi
141	}
142
143	src_prepare() {
144	if [ -n "${PATCHVER}" ] ; then
145	if [[ -L $S/bin/ebuild-helpers/portageq ]] ; then
146	rm "$S/bin/ebuild-helpers/portageq" \
147	\|\| die "failed to remove portageq helper symlink"
148	fi
149	epatch "${WORKDIR}/${PN}-${PATCHVER}.patch"
150	fi
151	einfo "Setting portage.VERSION to ${PVR} ..."
152	sed -e "s/^VERSION=.*/VERSION=\"${PVR}\"/" -i pym/portage/__init__.py \|\| \
153	die "Failed to patch portage.VERSION"
154	sed -e "1s/VERSION/${PVR}/" -i doc/fragment/version \|\| \
155	die "Failed to patch VERSION in doc/fragment/version"
156	sed -e "1s/VERSION/${PVR}/" -i man/* \|\| \
157	die "Failed to patch VERSION in man page headers"
158
159	if ! use ipc ; then
160	einfo "Disabling ipc..."
161	sed -e "s:_enable_ipc_daemon = True:_enable_ipc_daemon = False:" \
162	-i pym/_emerge/AbstractEbuildProcess.py \|\| \
163	die "failed to patch AbstractEbuildProcess.py"
164	fi
165
166	if use xattr && use kernel_linux ; then
167	einfo "Adding FEATURES=xattr to make.globals ..."
168	echo -e '\nFEATURES="${FEATURES} xattr"' >> cnf/make.globals \
169	\|\| die "failed to append to make.globals"
170	fi
171
172	if use python3; then
173	einfo "Converting shebangs for python3..."
174	python_convert_shebangs -r 3 .
175	elif use python2; then
176	einfo "Converting shebangs for python2..."
177	python_convert_shebangs -r 2 .
178	elif use pypy1_9; then
179	einfo "Converting shebangs for pypy-c1.9..."
180	python_convert_shebangs -r 2.7-pypy-1.9 .
181	fi
182
183	cd "${S}/cnf" \|\| die
184	if [ -f "make.conf.${ARCH}".diff ]; then
185	patch make.conf "make.conf.${ARCH}".diff \|\| \
186	die "Failed to patch make.conf.example"
187	else
188	eerror ""
189	eerror "Portage does not have an arch-specific configuration for this arch."
190	eerror "Please notify the arch maintainer about this issue. Using generic."
191	eerror ""
192	fi
193
194	sed -e "s:^option is enabled by default. In some cases this can$:option is disabled by default. In some cases this can:" \
195	-i "${S}/man/emerge.1" \|\| die
196	}
197
198	src_compile() {
199	if use doc; then
200	emake docbook \|\| die
201	fi
202
203	if use epydoc; then
204	einfo "Generating api docs"
205	emake epydoc \|\| die
206	fi
207	}
208
209	src_test() {
210	emake test \|\| die
211	}
212
213	src_install() {
214	emake DESTDIR="${D}" \
215	sysconfdir="/etc" \
216	prefix="/usr" \
217	install \|\| die
218
219	# Use dodoc for compression, since the Makefile doesn't do that.
220	dodoc "${S}"/{ChangeLog,NEWS,RELEASE-NOTES} \|\| die
221
222	if use linguas_pl; then
223	doman -i18n=pl "${S_PL}"/man/pl/*.[0-9] \|\| die
224	doman -i18n=pl_PL.UTF-8 "${S_PL}"/man/pl_PL.UTF-8/*.[0-9] \|\| die
225	fi
226
227	# Set PYTHONPATH for portage API consumers. This way we don't have
228	# to rely on patched python having the correct path, since it has
229	# been known to incorrectly add /usr/libx32/portage/pym to sys.path.
230	echo "PYTHONPATH=/usr/lib/portage/pym" > \
231	"${T}/05portage" \|\| die
232	doenvd "${T}/05portage" \|\| die
233	}
234
235	pkg_preinst() {
236	if [[ $ROOT == / ]] ; then
237	# Run some minimal tests as a sanity check.
238	local test_runner=$(find "$D" -name runTests)
239	if [[ -n $test_runner && -x $test_runner ]] ; then
240	einfo "Running preinst sanity tests..."
241	"$test_runner" \|\| die "preinst sanity tests failed"
242	fi
243	fi
244
245	if use xattr && ! current_python_has_xattr ; then
246	ewarn "For optimal performance in xattr handling, install"
247	ewarn "dev-python/pyxattr, or install >=dev-lang/python-3.3 and"
248	ewarn "enable USE=python3 for $CATEGORY/$PN."
249	fi
250
251	if ! use build && ! has_version dev-python/pycrypto && \
252	! has_version '>=dev-lang/python-2.6[ssl]' ; then
253	ewarn "If you are an ebuild developer and you plan to commit ebuilds"
254	ewarn "with this system then please install dev-python/pycrypto or"
255	ewarn "enable the ssl USE flag for >=dev-lang/python-2.6 in order"
256	ewarn "to enable RMD160 hash support."
257	ewarn "See bug #198398 for more information."
258	fi
259
260	if [[ -d ${ROOT}var/log/portage && \
261	$(ls -ld "${ROOT}var/log/portage") != " portage portage " ]] && \
262	has_version '<sys-apps/portage-2.1.10.11' ; then
263	# Initialize permissions for bug #378451 and bug #377177, since older
264	# portage does not create /var/log/portage with the desired default
265	# permissions.
266	einfo "Applying portage group permission to ${ROOT}var/log/portage for bug #378451"
267	chown portage:portage "${ROOT}var/log/portage"
268	chmod g+ws "${ROOT}var/log/portage"
269	fi
270
271	if has_version '<sys-apps/portage-2.1.10.61' ; then
272	ewarn "FEATURES=config-protect-if-modified is now enabled by default."
273	ewarn "This causes the CONFIG_PROTECT behavior to be skipped for"
274	ewarn "files that have not been modified since they were installed."
275	fi
276	}
277
278	pkg_postinst() {
279	# Compile all source files recursively. Any orphans
280	# will be identified and removed in postrm.
281	python_mod_optimize /usr/lib/portage/pym
282	}
283
284	pkg_postrm() {
285	python_mod_cleanup /usr/lib/portage/pym
286	}