/[gentoo-x86]/sys-apps/pv/pv-1.4.6.ebuild
Gentoo

Contents of /sys-apps/pv/pv-1.4.6.ebuild

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.4 - (show annotations) (download)
Wed Mar 27 17:42:11 2013 UTC (12 months, 3 weeks ago) by jer
Branch: MAIN
Changes since 1.3: +2 -2 lines
Stable for HPPA (bug #463140).

(Portage version: 2.2.0_alpha169/cvs/Linux x86_64, signed Manifest commit with key A792A613)

1 # Copyright 1999-2013 Gentoo Foundation
2 # Distributed under the terms of the GNU General Public License v2
3 # $Header: /var/cvsroot/gentoo-x86/sys-apps/pv/pv-1.4.6.ebuild,v 1.3 2013/03/27 12:52:38 pinkbyte Exp $
4
5 EAPI=4
6 inherit toolchain-funcs
7
8 DESCRIPTION="Pipe Viewer: a tool for monitoring the progress of data through a pipe"
9 HOMEPAGE="http://www.ivarch.com/programs/pv.shtml"
10 SRC_URI="http://www.ivarch.com/programs/sources/${P}.tar.gz"
11
12 LICENSE="Artistic-2"
13 SLOT="0"
14 KEYWORDS="~alpha amd64 arm hppa ~mips ppc ppc64 ~sparc x86 ~amd64-linux ~x86-linux ~ppc-macos ~x86-macos ~sparc64-solaris ~x86-solaris"
15 IUSE="debug nls"
16
17 PV_LINGUAS=( de fr pl pt )
18 IUSE+=" ${PV_LINGUAS[@]/#/linguas_}"
19
20 DOCS=( README doc/NEWS doc/TODO )
21
22 src_prepare() {
23 sed -i configure -e 's|CFLAGS="-g -Wall"|:|g' || die
24 # These should produce the same end result (working `pv`).
25 sed -i \
26 -e 's:$(LD) $(LDFLAGS) -o:$(AR) rc:' \
27 autoconf/make/modules.mk~ || die
28 }
29
30 src_configure() {
31 tc-export AR
32 local lingua
33 for lingua in ${PV_LINGUAS[@]}; do
34 if ! use linguas_${lingua}; then
35 sed -i configure -e "/ALL_LINGUAS=/s:${lingua}::g" || die
36 fi
37 done
38 econf $(use_enable debug debugging) $(use_enable nls)
39 }
40
41 src_test() {
42 if ! has_version sys-apps/usleep; then
43 sed -i -e 's:usleep 200000 || ::g' tests/019-remote-cksum || die
44 fi
45 default
46 }

  ViewVC Help
Powered by ViewVC 1.1.20