sys-boot/grub/grub-9999.ebuild

# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-boot/grub/grub-9999.ebuild,v 1.37 2011/08/27 11:29:52 scarabeus Exp $

EAPI=4

if [[ ${PV} == "9999" ]] ; then
        EBZR_REPO_URI="http://bzr.savannah.gnu.org/r/grub/trunk/grub/"
        LIVE_ECLASS="autotools bzr"
        SRC_URI=""
else
        MY_P=${P/_/\~}
        SRC_URI="mirror://gnu/${PN}/${MY_P}.tar.xz
                mirror://gentoo/${MY_P}.tar.xz"
        S=${WORKDIR}/${MY_P}
fi

inherit mount-boot eutils flag-o-matic toolchain-funcs ${LIVE_ECLASS}
unset LIVE_ECLASS

DESCRIPTION="GNU GRUB boot loader"
HOMEPAGE="http://www.gnu.org/software/grub/"

LICENSE="GPL-3"
SLOT="2"
[[ ${PV} != "9999" ]] && KEYWORDS="~amd64 ~mips ~x86"
IUSE="custom-cflags debug device-mapper efiemu nls static sdl truetype"

GRUB_PLATFORMS="coreboot efi-32 efi-64 emu ieee1275 multiboot pc qemu qemu-mips loongson"
# everywhere:
#     emu
# mips only:
#     qemu-mips, loongson
# amd64, x86, ppc, ppc64
#     ieee1275
# amd64, x86
#     coreboot, multiboot, efi-32, pc, qemu
# amd64
#     efi-64
for i in ${GRUB_PLATFORMS}; do
        IUSE+=" grub_platforms_${i}"
done
unset i

# os-prober: Used on runtime to detect other OSes
# xorriso (dev-libs/libisoburn): Used on runtime for mkrescue
RDEPEND="
        dev-libs/libisoburn
        dev-libs/lzo
        sys-boot/os-prober
        >=sys-libs/ncurses-5.2-r5
        debug? (
                sdl? ( media-libs/libsdl )
        )
        device-mapper? ( >=sys-fs/lvm2-2.02.45 )
        truetype? ( media-libs/freetype >=media-fonts/unifont-5 )"
DEPEND="${RDEPEND}
        >=dev-lang/python-2.5.2
        sys-devel/flex
        virtual/yacc
"
if [[ ${PV} == "9999" ]]; then
        DEPEND+=" >=sys-devel/autogen-5.10 sys-apps/help2man"
else
        DEPEND+=" app-arch/xz-utils"
fi

export STRIP_MASK="*/grub*/*/*.{mod,img}"
QA_EXECSTACK="
        lib64/grub2/*/setjmp.mod
        lib64/grub2/*/kernel.img
        sbin/grub2-probe
        sbin/grub2-setup
        sbin/grub2-mkdevicemap
        bin/grub2-script-check
        bin/grub2-fstest
        bin/grub2-mklayout
        bin/grub2-menulst2cfg
        bin/grub2-mkrelpath
        bin/grub2-mkpasswd-pbkdf2
        bin/grub2-mkfont
        bin/grub2-editenv
        bin/grub2-mkimage
"

grub_run_phase() {
        local phase=$1
        local platform=$2
        [[ -z ${phase} || -z ${platform} ]] && die "${FUNCNAME} [phase] [platform]"

        [[ -d "${WORKDIR}/build-${platform}" ]] || \
                { mkdir "${WORKDIR}/build-${platform}" || die ; }
        pushd "${WORKDIR}/build-${platform}" > /dev/null || die

        echo ">>> Running ${phase} for platform \"${platform}\""
        echo ">>> Working in: \"${WORKDIR}/build-${platform}\""

        grub_${phase} ${platform}

        popd > /dev/null || die
}

grub_src_configure() {
        local platform=$1
        local target

        [[ -z ${platform} ]] && die "${FUNCNAME} [platform]"

        # if we have no platform then --with-platform=guessed does not work
        [[ ${platform} == "guessed" ]] && platform=""

        # check if we have to specify the target (EFI)
        # or just append correct --with-platform
        if [[ -n ${platform} ]]; then
                if [[ ${platform} == efi* ]]; then
                        # EFI platform hack
                        [[ ${platform/*-} == 32 ]] && target=i386
                        [[ ${platform/*-} == 64 ]] && target=x86_64
                        # program-prefix is required empty because otherwise it is equal to
                        # target variable, which we do not want at all
                        platform="
                                --with-platform=${platform/-*}
                                --target=${target}
                                --program-prefix=
                        "
                else
                        platform=" --with-platform=${platform}"
                fi
        fi

        ECONF_SOURCE="${WORKDIR}/${P}/" \
        econf \
                --disable-werror \
                --sbindir=/sbin \
                --bindir=/bin \
                --libdir=/$(get_libdir) \
                --program-transform-name=s,grub,grub2, \
                $(use_enable debug mm-debug) \
                $(use_enable debug grub-emu-usb) \
                $(use_enable device-mapper) \
                $(use_enable efiemu) \
                $(use_enable nls) \
                $(use_enable truetype grub-mkfont) \
                $(use sdl && use_enable debug grub-emu-sdl) \
                ${platform}
}

grub_src_compile() {
        default_src_compile
}

grub_src_install() {
        default_src_install
}

src_prepare() {
        local i j archs

        epatch_user

        # autogen.sh does more than just run autotools
        if [[ ${PV} == "9999" ]] ; then
                sed -i -e '/^autoreconf/s:^:set +e; e:' autogen.sh || die
                (. ./autogen.sh) || die
        fi

        # install into the right dir for eselect #372735
        sed -i \
                -e '/^bashcompletiondir =/s:=.*:= $(datarootdir)/bash-completion:' \
                util/bash-completion.d/Makefile.in || die

        # get enabled platforms
        GRUB_ENABLED_PLATFORMS=""
        for i in ${GRUB_PLATFORMS}; do
                use grub_platforms_${i} && GRUB_ENABLED_PLATFORMS+=" ${i}"
        done
        [[ -z ${GRUB_ENABLED_PLATFORMS} ]] && GRUB_ENABLED_PLATFORMS="guessed"
        einfo "Going to build following platforms: ${GRUB_ENABLED_PLATFORMS}"
}

src_configure() {
        local i

        use custom-cflags || unset CFLAGS CPPFLAGS LDFLAGS
        use static && append-ldflags -static

        for i in ${GRUB_ENABLED_PLATFORMS}; do
                grub_run_phase ${FUNCNAME} ${i}
        done
}

src_compile() {
        local i

        for i in ${GRUB_ENABLED_PLATFORMS}; do
                grub_run_phase ${FUNCNAME} ${i}
        done
}

src_install() {
        local i

        for i in ${GRUB_ENABLED_PLATFORMS}; do
                grub_run_phase ${FUNCNAME} ${i}
        done

        # slot all collisions with grub legacy
        mv "${ED}"/usr/share/info/grub.info \
                "${ED}"/usr/share/info/grub2.info || die

        # can't be in docs array as we use defualt_src_install in different builddir
        dodoc AUTHORS ChangeLog NEWS README THANKS TODO
        insinto /etc/default
        newins "${FILESDIR}"/grub.default grub
        cat <<EOF >> "${ED}"/lib*/grub2/grub-mkconfig_lib
        GRUB_DISTRIBUTOR="Gentoo"
EOF
}

setup_boot_dir() {
        local dir=$1

        # display the link to guide if user didn't set up anything yet.
        elog "For informations how to configure grub-2 please reffer to the guide:"
        elog "    http://dev.gentoo.org/~scarabeus/grub-2-guide.xml"

        if [[ ! -e ${dir}/grub.cfg && -e ${dir/2/}/menu.lst ]] ; then
                # This is first grub2 install and we have old configuraton for
                # grub1 around. Lets try to generate grub.cfg from it so user
                # does not loose any stuff when rebooting.
                # NOTE: in long term he still NEEDS to migrate to grub.d stuff.
                einfo "Running: grub2-menulst2cfg '${dir/2/}/menu.lst' '${dir}/grub.cfg'"
                grub2-menulst2cfg "${dir/2/}/menu.lst" "${dir}/grub.cfg" || \
                        ewarn "Running grub2-menulst2cfg failed!"

                einfo "Even if we just created configuration for your grub2 using old"
                einfo "grub-legacy configuration file you should migrate to use new style"
                einfo "configuration in '${ROOT}/etc/grub.d'."
                einfo

        else
                # we need to refresh the grub.cfg everytime just to play it safe
                einfo "Running: grub2-mkconfig -o '${dir}/grub.cfg'"
                grub2-mkconfig -o "${dir}/grub.cfg" || \
                        ewarn "Running grub2-mkconfig failed! Check your configuration files!"
        fi

        elog "Remember to run \"grub2-mkconfig -o '${dir}/grub.cfg'\" every time"
        elog "you update the configuration files!"

        elog "Remember to run grub2-install to install your grub every time"
        elog "you update this package!"
}

pkg_postinst() {
        mount-boot_mount_boot_partition

        setup_boot_dir "${ROOT}"boot/grub2

        # needs to be called after we call setup_boot_dir
        mount-boot_pkg_postinst
}
1	vapier	1.27	# Copyright 1999-2011 Gentoo Foundation
2	vapier	1.1	# Distributed under the terms of the GNU General Public License v2
3	scarabeus	1.38	# $Header: /var/cvsroot/gentoo-x86/sys-boot/grub/grub-9999.ebuild,v 1.37 2011/08/27 11:29:52 scarabeus Exp $
4	vapier	1.21
5	scarabeus	1.37	EAPI=4
6	vapier	1.1
7			if [[ ${PV} == "9999" ]] ; then
8	vapier	1.29	EBZR_REPO_URI="http://bzr.savannah.gnu.org/r/grub/trunk/grub/"
9	scarabeus	1.37	LIVE_ECLASS="autotools bzr"
10	vapier	1.2	SRC_URI=""
11			else
12	scarabeus	1.37	MY_P=${P/_/\~}
13			SRC_URI="mirror://gnu/${PN}/${MY_P}.tar.xz
14			mirror://gentoo/${MY_P}.tar.xz"
15			S=${WORKDIR}/${MY_P}
16	vapier	1.1	fi
17
18	scarabeus	1.37	inherit mount-boot eutils flag-o-matic toolchain-funcs ${LIVE_ECLASS}
19			unset LIVE_ECLASS
20
21	vapier	1.32	DESCRIPTION="GNU GRUB boot loader"
22	vapier	1.1	HOMEPAGE="http://www.gnu.org/software/grub/"
23
24	vapier	1.4	LICENSE="GPL-3"
25	scarabeus	1.37	SLOT="2"
26			[[ ${PV} != "9999" ]] && KEYWORDS="~amd64 ~mips ~x86"
27	scarabeus	1.38	IUSE="custom-cflags debug device-mapper efiemu nls static sdl truetype"
28	scarabeus	1.37
29			GRUB_PLATFORMS="coreboot efi-32 efi-64 emu ieee1275 multiboot pc qemu qemu-mips loongson"
30			# everywhere:
31			# emu
32			# mips only:
33			# qemu-mips, loongson
34			# amd64, x86, ppc, ppc64
35			# ieee1275
36			# amd64, x86
37			# coreboot, multiboot, efi-32, pc, qemu
38			# amd64
39			# efi-64
40			for i in ${GRUB_PLATFORMS}; do
41			IUSE+=" grub_platforms_${i}"
42			done
43			unset i
44
45			# os-prober: Used on runtime to detect other OSes
46			# xorriso (dev-libs/libisoburn): Used on runtime for mkrescue
47			RDEPEND="
48			dev-libs/libisoburn
49	vapier	1.18	dev-libs/lzo
50	scarabeus	1.37	sys-boot/os-prober
51			>=sys-libs/ncurses-5.2-r5
52	vapier	1.32	debug? (
53			sdl? ( media-libs/libsdl )
54			)
55			device-mapper? ( >=sys-fs/lvm2-2.02.45 )
56	vapier	1.24	truetype? ( media-libs/freetype >=media-fonts/unifont-5 )"
57	vapier	1.9	DEPEND="${RDEPEND}
58	mattst88	1.35	>=dev-lang/python-2.5.2
59	scarabeus	1.37	sys-devel/flex
60	vapier	1.36	virtual/yacc
61	scarabeus	1.37	"
62			if [[ ${PV} == "9999" ]]; then
63			DEPEND+=" >=sys-devel/autogen-5.10 sys-apps/help2man"
64			else
65			DEPEND+=" app-arch/xz-utils"
66			fi
67
68			export STRIP_MASK="/grub//.{mod,img}"
69			QA_EXECSTACK="
70			lib64/grub2/*/setjmp.mod
71			lib64/grub2/*/kernel.img
72			sbin/grub2-probe
73			sbin/grub2-setup
74			sbin/grub2-mkdevicemap
75			bin/grub2-script-check
76			bin/grub2-fstest
77			bin/grub2-mklayout
78			bin/grub2-menulst2cfg
79			bin/grub2-mkrelpath
80			bin/grub2-mkpasswd-pbkdf2
81			bin/grub2-mkfont
82			bin/grub2-editenv
83			bin/grub2-mkimage
84			"
85
86			grub_run_phase() {
87			local phase=$1
88			local platform=$2
89			[[ -z ${phase} \|\| -z ${platform} ]] && die "${FUNCNAME} [phase] [platform]"
90
91			[[ -d "${WORKDIR}/build-${platform}" ]] \|\| \
92			{ mkdir "${WORKDIR}/build-${platform}" \|\| die ; }
93			pushd "${WORKDIR}/build-${platform}" > /dev/null \|\| die
94
95			echo ">>> Running ${phase} for platform \"${platform}\""
96			echo ">>> Working in: \"${WORKDIR}/build-${platform}\""
97	vapier	1.1
98	scarabeus	1.37	grub_${phase} ${platform}
99
100			popd > /dev/null \|\| die
101			}
102
103			grub_src_configure() {
104			local platform=$1
105			local target
106
107			[[ -z ${platform} ]] && die "${FUNCNAME} [platform]"
108
109			# if we have no platform then --with-platform=guessed does not work
110			[[ ${platform} == "guessed" ]] && platform=""
111
112			# check if we have to specify the target (EFI)
113			# or just append correct --with-platform
114			if [[ -n ${platform} ]]; then
115			if [[ ${platform} == efi* ]]; then
116			# EFI platform hack
117			[[ ${platform/*-} == 32 ]] && target=i386
118			[[ ${platform/*-} == 64 ]] && target=x86_64
119			# program-prefix is required empty because otherwise it is equal to
120			# target variable, which we do not want at all
121			platform="
122			--with-platform=${platform/-*}
123			--target=${target}
124			--program-prefix=
125			"
126			else
127			platform=" --with-platform=${platform}"
128			fi
129			fi
130
131			ECONF_SOURCE="${WORKDIR}/${P}/" \
132			econf \
133			--disable-werror \
134			--sbindir=/sbin \
135			--bindir=/bin \
136			--libdir=/$(get_libdir) \
137			--program-transform-name=s,grub,grub2, \
138	scarabeus	1.38	$(use_enable debug mm-debug) \
139			$(use_enable debug grub-emu-usb) \
140	scarabeus	1.37	$(use_enable device-mapper) \
141	scarabeus	1.38	$(use_enable efiemu) \
142			$(use_enable nls) \
143	scarabeus	1.37	$(use_enable truetype grub-mkfont) \
144			$(use sdl && use_enable debug grub-emu-sdl) \
145			${platform}
146			}
147
148			grub_src_compile() {
149			default_src_compile
150			}
151
152			grub_src_install() {
153			default_src_install
154			}
155	vapier	1.1
156	vapier	1.33	src_prepare() {
157	scarabeus	1.37	local i j archs
158
159	vapier	1.15	epatch_user
160	vapier	1.7
161			# autogen.sh does more than just run autotools
162	vapier	1.17	if [[ ${PV} == "9999" ]] ; then
163	vapier	1.33	sed -i -e '/^autoreconf/s:^:set +e; e:' autogen.sh \|\| die
164	vapier	1.17	(. ./autogen.sh) \|\| die
165			fi
166	vapier	1.34
167			# install into the right dir for eselect #372735
168			sed -i \
169			-e '/^bashcompletiondir =/s:=.*:= $(datarootdir)/bash-completion:' \
170			util/bash-completion.d/Makefile.in \|\| die
171	scarabeus	1.37
172			# get enabled platforms
173			GRUB_ENABLED_PLATFORMS=""
174			for i in ${GRUB_PLATFORMS}; do
175			use grub_platforms_${i} && GRUB_ENABLED_PLATFORMS+=" ${i}"
176			done
177			[[ -z ${GRUB_ENABLED_PLATFORMS} ]] && GRUB_ENABLED_PLATFORMS="guessed"
178			einfo "Going to build following platforms: ${GRUB_ENABLED_PLATFORMS}"
179	vapier	1.6	}
180
181	vapier	1.33	src_configure() {
182	scarabeus	1.37	local i
183
184	vapier	1.1	use custom-cflags \|\| unset CFLAGS CPPFLAGS LDFLAGS
185			use static && append-ldflags -static
186
187	scarabeus	1.37	for i in ${GRUB_ENABLED_PLATFORMS}; do
188			grub_run_phase ${FUNCNAME} ${i}
189			done
190	vapier	1.33	}
191
192			src_compile() {
193	scarabeus	1.37	local i
194
195			for i in ${GRUB_ENABLED_PLATFORMS}; do
196			grub_run_phase ${FUNCNAME} ${i}
197			done
198	vapier	1.1	}
199
200			src_install() {
201	scarabeus	1.37	local i
202
203			for i in ${GRUB_ENABLED_PLATFORMS}; do
204			grub_run_phase ${FUNCNAME} ${i}
205			done
206
207			# slot all collisions with grub legacy
208			mv "${ED}"/usr/share/info/grub.info \
209			"${ED}"/usr/share/info/grub2.info \|\| die
210
211			# can't be in docs array as we use defualt_src_install in different builddir
212	vapier	1.1	dodoc AUTHORS ChangeLog NEWS README THANKS TODO
213	scarabeus	1.37	insinto /etc/default
214			newins "${FILESDIR}"/grub.default grub
215			cat <<EOF >> "${ED}"/lib*/grub2/grub-mkconfig_lib
216	vapier	1.6	GRUB_DISTRIBUTOR="Gentoo"
217	scarabeus	1.37	EOF
218	vapier	1.3	}
219
220			setup_boot_dir() {
221	scarabeus	1.37	local dir=$1
222	vapier	1.3
223	scarabeus	1.37	# display the link to guide if user didn't set up anything yet.
224			elog "For informations how to configure grub-2 please reffer to the guide:"
225			elog " http://dev.gentoo.org/~scarabeus/grub-2-guide.xml"
226
227			if [[ ! -e ${dir}/grub.cfg && -e ${dir/2/}/menu.lst ]] ; then
228			# This is first grub2 install and we have old configuraton for
229			# grub1 around. Lets try to generate grub.cfg from it so user
230			# does not loose any stuff when rebooting.
231			# NOTE: in long term he still NEEDS to migrate to grub.d stuff.
232			einfo "Running: grub2-menulst2cfg '${dir/2/}/menu.lst' '${dir}/grub.cfg'"
233			grub2-menulst2cfg "${dir/2/}/menu.lst" "${dir}/grub.cfg" \|\| \
234			ewarn "Running grub2-menulst2cfg failed!"
235
236			einfo "Even if we just created configuration for your grub2 using old"
237			einfo "grub-legacy configuration file you should migrate to use new style"
238			einfo "configuration in '${ROOT}/etc/grub.d'."
239			einfo
240
241			else
242			# we need to refresh the grub.cfg everytime just to play it safe
243			einfo "Running: grub2-mkconfig -o '${dir}/grub.cfg'"
244			grub2-mkconfig -o "${dir}/grub.cfg" \|\| \
245			ewarn "Running grub2-mkconfig failed! Check your configuration files!"
246	vapier	1.3	fi
247
248	scarabeus	1.37	elog "Remember to run \"grub2-mkconfig -o '${dir}/grub.cfg'\" every time"
249			elog "you update the configuration files!"
250
251			elog "Remember to run grub2-install to install your grub every time"
252			elog "you update this package!"
253	vapier	1.1	}
254
255			pkg_postinst() {
256	vapier	1.28	mount-boot_mount_boot_partition
257	vapier	1.27
258	scarabeus	1.37	setup_boot_dir "${ROOT}"boot/grub2
259	vapier	1.28
260	scarabeus	1.37	# needs to be called after we call setup_boot_dir
261	vapier	1.28	mount-boot_pkg_postinst
262	vapier	1.1	}