sys-devel/bison/bison-2.6.2.ebuild

# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-devel/bison/bison-2.6.2.ebuild,v 1.2 2012/08/24 15:57:21 vapier Exp $

EAPI=4

inherit flag-o-matic

DESCRIPTION="A general-purpose (yacc-compatible) parser generator"
HOMEPAGE="http://www.gnu.org/software/bison/"
SRC_URI="mirror://gnu/${PN}/${P}.tar.xz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~ppc-aix ~amd64-fbsd ~sparc-fbsd ~x86-fbsd ~x64-freebsd ~x86-freebsd ~hppa-hpux ~ia64-hpux ~x86-interix ~amd64-linux ~ia64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~m68k-mint ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
IUSE="nls static"

RDEPEND=">=sys-devel/m4-1.4.16"
DEPEND="${RDEPEND}
        sys-devel/flex
        nls? ( sys-devel/gettext )"

DOCS="AUTHORS ChangeLog-2012 NEWS README THANKS TODO" # ChangeLog-1998 PACKAGING README-alpha README-release

src_configure() {
        use static && append-ldflags -static

        econf \
                --disable-silent-rules \
                $(use_enable nls)
}

src_install() {
        default

        # This one is installed by dev-util/yacc
        mv "${ED}"/usr/bin/yacc{,.bison} || die
        mv "${ED}"/usr/share/man/man1/yacc{,.bison}.1 || die

        # We do not need liby.a
        rm -r "${ED}"/usr/lib* || die

        # Move to documentation directory and leave compressing for EAPI>=4
        mv "${ED}"/usr/share/${PN}/README "${ED}"/usr/share/doc/${PF}/README.data
}

pkg_postinst() {
        local f="${EROOT}/usr/bin/yacc"
        if [[ ! -e ${f} ]] ; then
                ln -s yacc.bison "${f}"
        fi
}

pkg_postrm() {
        # clean up the dead symlink when we get unmerged #377469
        local f="${EROOT}/usr/bin/yacc"
        if [[ -L ${f} && ! -e ${f} ]] ; then
                rm -f "${f}"
        fi
}
1	# Copyright 1999-2012 Gentoo Foundation
2	# Distributed under the terms of the GNU General Public License v2
3	# $Header: /var/cvsroot/gentoo-x86/sys-devel/bison/bison-2.6.2.ebuild,v 1.2 2012/08/24 15:57:21 vapier Exp $
4
5	EAPI=4
6
7	inherit flag-o-matic
8
9	DESCRIPTION="A general-purpose (yacc-compatible) parser generator"
10	HOMEPAGE="http://www.gnu.org/software/bison/"
11	SRC_URI="mirror://gnu/${PN}/${P}.tar.xz"
12
13	LICENSE="GPL-2"
14	SLOT="0"
15	KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~ppc-aix ~amd64-fbsd ~sparc-fbsd ~x86-fbsd ~x64-freebsd ~x86-freebsd ~hppa-hpux ~ia64-hpux ~x86-interix ~amd64-linux ~ia64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~m68k-mint ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
16	IUSE="nls static"
17
18	RDEPEND=">=sys-devel/m4-1.4.16"
19	DEPEND="${RDEPEND}
20	sys-devel/flex
21	nls? ( sys-devel/gettext )"
22
23	DOCS="AUTHORS ChangeLog-2012 NEWS README THANKS TODO" # ChangeLog-1998 PACKAGING README-alpha README-release
24
25	src_configure() {
26	use static && append-ldflags -static
27
28	econf \
29	--disable-silent-rules \
30	$(use_enable nls)
31	}
32
33	src_install() {
34	default
35
36	# This one is installed by dev-util/yacc
37	mv "${ED}"/usr/bin/yacc{,.bison} \|\| die
38	mv "${ED}"/usr/share/man/man1/yacc{,.bison}.1 \|\| die
39
40	# We do not need liby.a
41	rm -r "${ED}"/usr/lib* \|\| die
42
43	# Move to documentation directory and leave compressing for EAPI>=4
44	mv "${ED}"/usr/share/${PN}/README "${ED}"/usr/share/doc/${PF}/README.data
45	}
46
47	pkg_postinst() {
48	local f="${EROOT}/usr/bin/yacc"
49	if [[ ! -e ${f} ]] ; then
50	ln -s yacc.bison "${f}"
51	fi
52	}
53
54	pkg_postrm() {
55	# clean up the dead symlink when we get unmerged #377469
56	local f="${EROOT}/usr/bin/yacc"
57	if [[ -L ${f} && ! -e ${f} ]] ; then
58	rm -f "${f}"
59	fi
60	}