www-client/chromium/chromium-22.0.1207.1.ebuild

# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/www-client/chromium/chromium-22.0.1207.1.ebuild,v 1.2 2012/07/22 16:52:26 floppym Exp $

EAPI="4"
PYTHON_DEPEND="2:2.6"

CHROMIUM_LANGS="am ar bg bn ca cs da de el en_GB es es_LA et fa fi fil fr gu he
        hi hr hu id it ja kn ko lt lv ml mr ms nb nl pl pt_BR pt_PT ro ru sk sl sr
        sv sw ta te th tr uk vi zh_CN zh_TW"

inherit chromium eutils flag-o-matic multilib \
        pax-utils portability python toolchain-funcs versionator virtualx

DESCRIPTION="Open-source version of Google Chrome web browser"
HOMEPAGE="http://chromium.org/"
SRC_URI="http://commondatastorage.googleapis.com/chromium-browser-official/${P}.tar.bz2"

LICENSE="BSD"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="bindist cups gnome gnome-keyring kerberos pulseaudio selinux"

RDEPEND="app-arch/bzip2
        cups? (
                dev-libs/libgcrypt
                >=net-print/cups-1.3.11
        )
        >=dev-lang/v8-3.11.10.6
        dev-libs/dbus-glib
        dev-libs/elfutils
        dev-libs/expat
        >=dev-libs/icu-49.1.1-r1
        >=dev-libs/libevent-1.4.13
        dev-libs/libxml2[icu]
        dev-libs/libxslt
        >=dev-libs/nss-3.12.3
        gnome? ( >=gnome-base/gconf-2.24.0 )
        gnome-keyring? ( >=gnome-base/gnome-keyring-2.28.2 )
        >=media-libs/alsa-lib-1.0.19
        media-libs/flac
        >=media-libs/libjpeg-turbo-1.2.0-r1
        media-libs/libpng
        media-libs/speex
        pulseaudio? ( media-sound/pulseaudio )
        sys-fs/udev
        sys-libs/zlib
        virtual/libusb:1
        x11-libs/gtk+:2
        x11-libs/libXinerama
        x11-libs/libXScrnSaver
        x11-libs/libXtst
        kerberos? ( virtual/krb5 )
        selinux? ( sys-libs/libselinux )"
DEPEND="${RDEPEND}
        >=dev-lang/nacl-toolchain-newlib-0_p9093
        dev-lang/perl
        dev-lang/yasm
        dev-python/ply
        dev-python/simplejson
        >=dev-util/gperf-3.0.3
        >=sys-devel/bison-2.4.3
        <sys-devel/bison-2.6
        sys-devel/flex
        >=sys-devel/make-3.81-r2
        virtual/pkgconfig
        test? (
                dev-python/pyftpdlib
        )"
RDEPEND+="
        !=www-client/chromium-9999
        x11-misc/xdg-utils
        virtual/ttf-fonts"

if ! has chromium_pkg_die ${EBUILD_DEATH_HOOKS}; then
        EBUILD_DEATH_HOOKS+=" chromium_pkg_die";
fi

pkg_setup() {
        if [[ "${SLOT}" == "0" ]]; then
                CHROMIUM_SUFFIX=""
        else
                CHROMIUM_SUFFIX="-${SLOT}"
        fi
        CHROMIUM_HOME="/usr/$(get_libdir)/chromium-browser${CHROMIUM_SUFFIX}"

        # Make sure the build system will use the right tools, bug #340795.
        tc-export AR CC CXX RANLIB

        # Make sure the build system will use the right python, bug #344367.
        python_set_active_version 2
        python_pkg_setup

        if ! use selinux; then
                chromium_suid_sandbox_check_kernel_config
        fi

        if use bindist; then
                elog "bindist enabled: H.264 video support will be disabled."
        else
                elog "bindist disabled: Resulting binaries may not be legal to re-distribute."
        fi
}

src_prepare() {
        ln -s /usr/$(get_libdir)/nacl-toolchain-newlib \
                native_client/toolchain/linux_x86_newlib || die

        # zlib-1.2.5.1-r1 renames the OF macro in zconf.h, bug 383371.
        sed -i '1i#define OF(x) x' \
                third_party/zlib/contrib/minizip/{ioapi,{,un}zip}.h || die

        # Fix build without NaCl glibc toolchain.
        epatch "${FILESDIR}/${PN}-ppapi-r0.patch"

        epatch_user

        # Remove most bundled libraries. Some are still needed.
        find third_party -type f \! -iname '*.gyp*' \
                \! -path 'third_party/WebKit/*' \
                \! -path 'third_party/angle/*' \
                \! -path 'third_party/cacheinvalidation/*' \
                \! -path 'third_party/cld/*' \
                \! -path 'third_party/ffmpeg/*' \
                \! -path 'third_party/flac/flac.h' \
                \! -path 'third_party/gpsd/*' \
                \! -path 'third_party/harfbuzz/*' \
                \! -path 'third_party/hunspell/*' \
                \! -path 'third_party/iccjpeg/*' \
                \! -path 'third_party/jsoncpp/*' \
                \! -path 'third_party/khronos/*' \
                \! -path 'third_party/launchpad_translations/*' \
                \! -path 'third_party/leveldatabase/*' \
                \! -path 'third_party/libjingle/*' \
                \! -path 'third_party/libphonenumber/*' \
                \! -path 'third_party/libsrtp/*' \
                \! -path 'third_party/libusb/libusb.h' \
                \! -path 'third_party/libva/*' \
                \! -path 'third_party/libvpx/*' \
                \! -path 'third_party/libwebp/*' \
                \! -path 'third_party/libxml/chromium/*' \
                \! -path 'third_party/libXNVCtrl/*' \
                \! -path 'third_party/libyuv/*' \
                \! -path 'third_party/lss/*' \
                \! -path 'third_party/mesa/*' \
                \! -path 'third_party/modp_b64/*' \
                \! -path 'third_party/mongoose/*' \
                \! -path 'third_party/npapi/*' \
                \! -path 'third_party/openmax/*' \
                \! -path 'third_party/ots/*' \
                \! -path 'third_party/protobuf/*' \
                \! -path 'third_party/qcms/*' \
                \! -path 'third_party/scons-2.0.1/*' \
                \! -path 'third_party/sfntly/*' \
                \! -path 'third_party/skia/*' \
                \! -path 'third_party/smhasher/*' \
                \! -path 'third_party/speex/speex.h' \
                \! -path 'third_party/sqlite/*' \
                \! -path 'third_party/tlslite/*' \
                \! -path 'third_party/trace-viewer/*' \
                \! -path 'third_party/undoview/*' \
                \! -path 'third_party/v8-i18n/*' \
                \! -path 'third_party/webdriver/*' \
                \! -path 'third_party/webgl_conformance/*' \
                \! -path 'third_party/webrtc/*' \
                \! -path 'third_party/zlib/contrib/minizip/*' \
                -delete || die

        local v8_bundled="$(chromium_bundled_v8_version)"
        local v8_installed="$(chromium_installed_v8_version)"
        einfo "V8 version: bundled - ${v8_bundled}; installed - ${v8_installed}"

        # Remove bundled v8.
        find v8 -type f \! -iname '*.gyp*' -delete || die

        # The implementation files include v8 headers with full path,
        # like #include "v8/include/v8.h". Make sure the system headers
        # will be used.
        # TODO: find a solution that can be upstreamed.
        rmdir v8/include || die
        ln -s /usr/include v8/include || die

        # Make sure the build system will use the right python, bug #344367.
        # Only convert directories that need it, to save time.
        python_convert_shebangs -q -r 2 build tools
}

src_configure() {
        local myconf=""

        # Never tell the build system to "enable" SSE2, it has a few unexpected
        # additions, bug #336871.
        myconf+=" -Ddisable_sse2=1"

        # Disable tcmalloc, it causes problems with e.g. NVIDIA
        # drivers, bug #413637.
        myconf+=" -Dlinux_use_tcmalloc=0"

        # Disable glibc Native Client toolchain, we don't need it (bug #417019).
        myconf+=" -Ddisable_glibc=1"

        # Make it possible to remove third_party/adobe.
        echo > "${T}/flapper_version.h" || die
        myconf+=" -Dflapper_version_h_file=${T}/flapper_version.h"

        # Use system-provided libraries.
        # TODO: use_system_ffmpeg
        # TODO: use_system_hunspell (upstream changes needed).
        # TODO: use_system_ssl (http://crbug.com/58087).
        # TODO: use_system_sqlite (http://crbug.com/22208).
        # TODO: use_system_vpx
        # TODO: use_system_webp (https://chromiumcodereview.appspot.com/10496016
        #       needs to become part of webp release)
        myconf+="
                -Duse_system_bzip2=1
                -Duse_system_flac=1
                -Duse_system_icu=1
                -Duse_system_libevent=1
                -Duse_system_libjpeg=1
                -Duse_system_libpng=1
                -Duse_system_libusb=1
                -Duse_system_libxml=1
                -Duse_system_speex=1
                -Duse_system_v8=1
                -Duse_system_xdg_utils=1
                -Duse_system_yasm=1
                -Duse_system_zlib=1"

        # Optional dependencies.
        # TODO: linux_link_kerberos, bug #381289.
        myconf+="
                $(gyp_use cups)
                $(gyp_use gnome use_gconf)
                $(gyp_use gnome-keyring use_gnome_keyring)
                $(gyp_use gnome-keyring linux_link_gnome_keyring)
                $(gyp_use kerberos)
                $(gyp_use pulseaudio)
                $(gyp_use selinux selinux)"

        if ! use selinux; then
                # Enable SUID sandbox.
                myconf+="
                        -Dlinux_sandbox_path=${CHROMIUM_HOME}/chrome_sandbox
                        -Dlinux_sandbox_chrome_path=${CHROMIUM_HOME}/chrome"
        fi

        # Never use bundled gold binary. Disable gold linker flags for now.
        myconf+="
                -Dlinux_use_gold_binary=0
                -Dlinux_use_gold_flags=0"

        if ! use bindist; then
                # Enable H.624 support in bundled ffmpeg.
                myconf+=" -Dproprietary_codecs=1 -Dffmpeg_branding=Chrome"
        fi

        local myarch="$(tc-arch)"
        if [[ $myarch = amd64 ]] ; then
                myconf+=" -Dtarget_arch=x64"
        elif [[ $myarch = x86 ]] ; then
                myconf+=" -Dtarget_arch=ia32"
        else
                die "Failed to determine target arch, got '$myarch'."
        fi

        # Make sure that -Werror doesn't get added to CFLAGS by the build system.
        # Depending on GCC version the warnings are different and we don't want
        # the build to fail because of that.
        myconf+=" -Dwerror="

        # Avoid CFLAGS problems, bug #352457, bug #390147.
        if ! use custom-cflags; then
                replace-flags "-Os" "-O2"
                strip-flags
        fi

        egyp_chromium ${myconf} || die
}

src_compile() {
        local test_targets
        for x in base cacheinvalidation crypto \
                googleurl gpu media net printing sql; do
                test_targets+=" ${x}_unittests"
        done

        local make_targets="chrome chromedriver"
        if ! use selinux; then
                make_targets+=" chrome_sandbox"
        fi
        if use test; then
                make_targets+=$test_targets
        fi

        # See bug #410883 for more info about the .host mess.
        emake ${make_targets} BUILDTYPE=Release V=1 \
                CC.host="$(tc-getCC)" CFLAGS.host="${CFLAGS}" \
                CXX.host="$(tc-getCXX)" CXXFLAGS.host="${CXXFLAGS}" \
                LINK.host="$(tc-getCXX)" LDFLAGS.host="${LDFLAGS}" \
                AR.host="$(tc-getAR)" || die

        pax-mark m out/Release/chrome
        if use test; then
                for x in $test_targets; do
                        pax-mark m out/Release/${x}
                done
        fi
}

src_test() {
        # For more info see bug #350349.
        local mylocale='en_US.utf8'
        if ! locale -a | grep -q "$mylocale"; then
                eerror "${PN} requires ${mylocale} locale for tests"
                eerror "Please read the following guides for more information:"
                eerror "  http://www.gentoo.org/doc/en/guide-localization.xml"
                eerror "  http://www.gentoo.org/doc/en/utf-8.xml"
                die "locale ${mylocale} is not supported"
        fi

        # For more info see bug #370957.
        if [[ $UID -eq 0 ]]; then
                die "Tests must be run as non-root. Please use FEATURES=userpriv."
        fi

        runtest() {
                local cmd=$1
                shift
                einfo "${cmd}" "$@"
                LC_ALL="${mylocale}" VIRTUALX_COMMAND="${cmd}" virtualmake "$@"
        }

        # ICUStringConversionsTest: bug #350347.
        # MessagePumpLibeventTest: bug #398501.
        runtest out/Release/base_unittests \
                '--gtest_filter=-ICUStringConversionsTest.*:MessagePumpLibeventTest.*'

        runtest out/Release/cacheinvalidation_unittests
        runtest out/Release/crypto_unittests
        runtest out/Release/googleurl_unittests
        runtest out/Release/gpu_unittests
        runtest out/Release/media_unittests

        # NetUtilTest: bug #361885.
        # DnsConfigServiceTest.GetSystemConfig: bug #394883.
        # CertDatabaseNSSTest.ImportServerCert_SelfSigned: bug #399269.
        runtest out/Release/net_unittests \
                '--gtest_filter=-NetUtilTest.IDNToUnicode*:NetUtilTest.FormatUrl*:DnsConfigServiceTest.GetSystemConfig:CertDatabaseNSSTest.ImportServerCert_SelfSigned:URLFetcher*'

        runtest out/Release/printing_unittests
        runtest out/Release/sql_unittests
}

src_install() {
        exeinto "${CHROMIUM_HOME}"
        doexe out/Release/chrome || die

        if ! use selinux; then
                doexe out/Release/chrome_sandbox || die
                fperms 4755 "${CHROMIUM_HOME}/chrome_sandbox"
        fi

        doexe out/Release/chromedriver || die

        doexe out/Release/nacl_helper{,_bootstrap} || die
        insinto "${CHROMIUM_HOME}"
        doins out/Release/nacl_irt_*.nexe || die
        doins out/Release/libppGoogleNaClPluginChrome.so || die

        newexe "${FILESDIR}"/chromium-launcher-r2.sh chromium-launcher.sh || die
        if [[ "${CHROMIUM_SUFFIX}" != "" ]]; then
                sed "s:chromium-browser:chromium-browser${CHROMIUM_SUFFIX}:g" \
                        -i "${ED}"/"${CHROMIUM_HOME}"/chromium-launcher.sh || die
                sed "s:chromium.desktop:chromium${CHROMIUM_SUFFIX}.desktop:g" \
                        -i "${ED}"/"${CHROMIUM_HOME}"/chromium-launcher.sh || die
                sed "s:plugins:plugins --user-data-dir=\${HOME}/.config/chromium${CHROMIUM_SUFFIX}:" \
                        -i "${ED}"/"${CHROMIUM_HOME}"/chromium-launcher.sh || die
        fi

        # It is important that we name the target "chromium-browser",
        # xdg-utils expect it; bug #355517.
        dosym "${CHROMIUM_HOME}/chromium-launcher.sh" /usr/bin/chromium-browser${CHROMIUM_SUFFIX} || die
        # keep the old symlink around for consistency
        dosym "${CHROMIUM_HOME}/chromium-launcher.sh" /usr/bin/chromium${CHROMIUM_SUFFIX} || die

        # Allow users to override command-line options, bug #357629.
        dodir /etc/chromium || die
        insinto /etc/chromium
        newins "${FILESDIR}/chromium.default" "default" || die

        pushd out/Release/locales > /dev/null || die
        chromium_remove_language_paks
        popd

        insinto "${CHROMIUM_HOME}"
        doins out/Release/*.pak || die

        doins -r out/Release/locales || die
        doins -r out/Release/resources || die

        newman out/Release/chrome.1 chromium${CHROMIUM_SUFFIX}.1 || die
        newman out/Release/chrome.1 chromium-browser${CHROMIUM_SUFFIX}.1 || die

        doexe out/Release/libffmpegsumo.so || die

        # Install icons and desktop entry.
        local branding size
        for size in 16 22 24 32 48 64 128 256 ; do
                case ${size} in
                        16|32) branding="chrome/app/theme/default_100_percent/chromium" ;;
                                *) branding="chrome/app/theme/chromium" ;;
                esac
                newicon -s ${size} "${branding}/product_logo_${size}.png" \
                        chromium-browser${CHROMIUM_SUFFIX}.png
        done

        local mime_types="text/html;text/xml;application/xhtml+xml;"
        mime_types+="x-scheme-handler/http;x-scheme-handler/https;" # bug #360797
        mime_types+="x-scheme-handler/ftp;" # bug #412185
        mime_types+="x-scheme-handler/mailto;x-scheme-handler/webcal;" # bug #416393
        make_desktop_entry \
                chromium-browser${CHROMIUM_SUFFIX} \
                "Chromium${CHROMIUM_SUFFIX}" \
                chromium-browser${CHROMIUM_SUFFIX} \
                "Network;WebBrowser" \
                "MimeType=${mime_types}\nStartupWMClass=chromium-browser"
        sed -e "/^Exec/s/$/ %U/" -i "${ED}"/usr/share/applications/*.desktop || die

        # Install GNOME default application entry (bug #303100).
        if use gnome; then
                dodir /usr/share/gnome-control-center/default-apps || die
                insinto /usr/share/gnome-control-center/default-apps
                newins "${FILESDIR}"/chromium-browser.xml chromium-browser${CHROMIUM_SUFFIX}.xml || die
                if [[ "${CHROMIUM_SUFFIX}" != "" ]]; then
                        sed "s:chromium-browser:chromium-browser${CHROMIUM_SUFFIX}:g" -i \
                                "${ED}"/usr/share/gnome-control-center/default-apps/chromium-browser${CHROMIUM_SUFFIX}.xml
                fi
        fi
}
1	# Copyright 1999-2012 Gentoo Foundation
2	# Distributed under the terms of the GNU General Public License v2
3	# $Header: /var/cvsroot/gentoo-x86/www-client/chromium/chromium-22.0.1207.1.ebuild,v 1.2 2012/07/22 16:52:26 floppym Exp $
4
5	EAPI="4"
6	PYTHON_DEPEND="2:2.6"
7
8	CHROMIUM_LANGS="am ar bg bn ca cs da de el en_GB es es_LA et fa fi fil fr gu he
9	hi hr hu id it ja kn ko lt lv ml mr ms nb nl pl pt_BR pt_PT ro ru sk sl sr
10	sv sw ta te th tr uk vi zh_CN zh_TW"
11
12	inherit chromium eutils flag-o-matic multilib \
13	pax-utils portability python toolchain-funcs versionator virtualx
14
15	DESCRIPTION="Open-source version of Google Chrome web browser"
16	HOMEPAGE="http://chromium.org/"
17	SRC_URI="http://commondatastorage.googleapis.com/chromium-browser-official/${P}.tar.bz2"
18
19	LICENSE="BSD"
20	SLOT="0"
21	KEYWORDS="~amd64 ~x86"
22	IUSE="bindist cups gnome gnome-keyring kerberos pulseaudio selinux"
23
24	RDEPEND="app-arch/bzip2
25	cups? (
26	dev-libs/libgcrypt
27	>=net-print/cups-1.3.11
28	)
29	>=dev-lang/v8-3.11.10.6
30	dev-libs/dbus-glib
31	dev-libs/elfutils
32	dev-libs/expat
33	>=dev-libs/icu-49.1.1-r1
34	>=dev-libs/libevent-1.4.13
35	dev-libs/libxml2[icu]
36	dev-libs/libxslt
37	>=dev-libs/nss-3.12.3
38	gnome? ( >=gnome-base/gconf-2.24.0 )
39	gnome-keyring? ( >=gnome-base/gnome-keyring-2.28.2 )
40	>=media-libs/alsa-lib-1.0.19
41	media-libs/flac
42	>=media-libs/libjpeg-turbo-1.2.0-r1
43	media-libs/libpng
44	media-libs/speex
45	pulseaudio? ( media-sound/pulseaudio )
46	sys-fs/udev
47	sys-libs/zlib
48	virtual/libusb:1
49	x11-libs/gtk+:2
50	x11-libs/libXinerama
51	x11-libs/libXScrnSaver
52	x11-libs/libXtst
53	kerberos? ( virtual/krb5 )
54	selinux? ( sys-libs/libselinux )"
55	DEPEND="${RDEPEND}
56	>=dev-lang/nacl-toolchain-newlib-0_p9093
57	dev-lang/perl
58	dev-lang/yasm
59	dev-python/ply
60	dev-python/simplejson
61	>=dev-util/gperf-3.0.3
62	>=sys-devel/bison-2.4.3
63	<sys-devel/bison-2.6
64	sys-devel/flex
65	>=sys-devel/make-3.81-r2
66	virtual/pkgconfig
67	test? (
68	dev-python/pyftpdlib
69	)"
70	RDEPEND+="
71	!=www-client/chromium-9999
72	x11-misc/xdg-utils
73	virtual/ttf-fonts"
74
75	if ! has chromium_pkg_die ${EBUILD_DEATH_HOOKS}; then
76	EBUILD_DEATH_HOOKS+=" chromium_pkg_die";
77	fi
78
79	pkg_setup() {
80	if [[ "${SLOT}" == "0" ]]; then
81	CHROMIUM_SUFFIX=""
82	else
83	CHROMIUM_SUFFIX="-${SLOT}"
84	fi
85	CHROMIUM_HOME="/usr/$(get_libdir)/chromium-browser${CHROMIUM_SUFFIX}"
86
87	# Make sure the build system will use the right tools, bug #340795.
88	tc-export AR CC CXX RANLIB
89
90	# Make sure the build system will use the right python, bug #344367.
91	python_set_active_version 2
92	python_pkg_setup
93
94	if ! use selinux; then
95	chromium_suid_sandbox_check_kernel_config
96	fi
97
98	if use bindist; then
99	elog "bindist enabled: H.264 video support will be disabled."
100	else
101	elog "bindist disabled: Resulting binaries may not be legal to re-distribute."
102	fi
103	}
104
105	src_prepare() {
106	ln -s /usr/$(get_libdir)/nacl-toolchain-newlib \
107	native_client/toolchain/linux_x86_newlib \|\| die
108
109	# zlib-1.2.5.1-r1 renames the OF macro in zconf.h, bug 383371.
110	sed -i '1i#define OF(x) x' \
111	third_party/zlib/contrib/minizip/{ioapi,{,un}zip}.h \|\| die
112
113	# Fix build without NaCl glibc toolchain.
114	epatch "${FILESDIR}/${PN}-ppapi-r0.patch"
115
116	epatch_user
117
118	# Remove most bundled libraries. Some are still needed.
119	find third_party -type f \! -iname '.gyp' \
120	\! -path 'third_party/WebKit/*' \
121	\! -path 'third_party/angle/*' \
122	\! -path 'third_party/cacheinvalidation/*' \
123	\! -path 'third_party/cld/*' \
124	\! -path 'third_party/ffmpeg/*' \
125	\! -path 'third_party/flac/flac.h' \
126	\! -path 'third_party/gpsd/*' \
127	\! -path 'third_party/harfbuzz/*' \
128	\! -path 'third_party/hunspell/*' \
129	\! -path 'third_party/iccjpeg/*' \
130	\! -path 'third_party/jsoncpp/*' \
131	\! -path 'third_party/khronos/*' \
132	\! -path 'third_party/launchpad_translations/*' \
133	\! -path 'third_party/leveldatabase/*' \
134	\! -path 'third_party/libjingle/*' \
135	\! -path 'third_party/libphonenumber/*' \
136	\! -path 'third_party/libsrtp/*' \
137	\! -path 'third_party/libusb/libusb.h' \
138	\! -path 'third_party/libva/*' \
139	\! -path 'third_party/libvpx/*' \
140	\! -path 'third_party/libwebp/*' \
141	\! -path 'third_party/libxml/chromium/*' \
142	\! -path 'third_party/libXNVCtrl/*' \
143	\! -path 'third_party/libyuv/*' \
144	\! -path 'third_party/lss/*' \
145	\! -path 'third_party/mesa/*' \
146	\! -path 'third_party/modp_b64/*' \
147	\! -path 'third_party/mongoose/*' \
148	\! -path 'third_party/npapi/*' \
149	\! -path 'third_party/openmax/*' \
150	\! -path 'third_party/ots/*' \
151	\! -path 'third_party/protobuf/*' \
152	\! -path 'third_party/qcms/*' \
153	\! -path 'third_party/scons-2.0.1/*' \
154	\! -path 'third_party/sfntly/*' \
155	\! -path 'third_party/skia/*' \
156	\! -path 'third_party/smhasher/*' \
157	\! -path 'third_party/speex/speex.h' \
158	\! -path 'third_party/sqlite/*' \
159	\! -path 'third_party/tlslite/*' \
160	\! -path 'third_party/trace-viewer/*' \
161	\! -path 'third_party/undoview/*' \
162	\! -path 'third_party/v8-i18n/*' \
163	\! -path 'third_party/webdriver/*' \
164	\! -path 'third_party/webgl_conformance/*' \
165	\! -path 'third_party/webrtc/*' \
166	\! -path 'third_party/zlib/contrib/minizip/*' \
167	-delete \|\| die
168
169	local v8_bundled="$(chromium_bundled_v8_version)"
170	local v8_installed="$(chromium_installed_v8_version)"
171	einfo "V8 version: bundled - ${v8_bundled}; installed - ${v8_installed}"
172
173	# Remove bundled v8.
174	find v8 -type f \! -iname '.gyp' -delete \|\| die
175
176	# The implementation files include v8 headers with full path,
177	# like #include "v8/include/v8.h". Make sure the system headers
178	# will be used.
179	# TODO: find a solution that can be upstreamed.
180	rmdir v8/include \|\| die
181	ln -s /usr/include v8/include \|\| die
182
183	# Make sure the build system will use the right python, bug #344367.
184	# Only convert directories that need it, to save time.
185	python_convert_shebangs -q -r 2 build tools
186	}
187
188	src_configure() {
189	local myconf=""
190
191	# Never tell the build system to "enable" SSE2, it has a few unexpected
192	# additions, bug #336871.
193	myconf+=" -Ddisable_sse2=1"
194
195	# Disable tcmalloc, it causes problems with e.g. NVIDIA
196	# drivers, bug #413637.
197	myconf+=" -Dlinux_use_tcmalloc=0"
198
199	# Disable glibc Native Client toolchain, we don't need it (bug #417019).
200	myconf+=" -Ddisable_glibc=1"
201
202	# Make it possible to remove third_party/adobe.
203	echo > "${T}/flapper_version.h" \|\| die
204	myconf+=" -Dflapper_version_h_file=${T}/flapper_version.h"
205
206	# Use system-provided libraries.
207	# TODO: use_system_ffmpeg
208	# TODO: use_system_hunspell (upstream changes needed).
209	# TODO: use_system_ssl (http://crbug.com/58087).
210	# TODO: use_system_sqlite (http://crbug.com/22208).
211	# TODO: use_system_vpx
212	# TODO: use_system_webp (https://chromiumcodereview.appspot.com/10496016
213	# needs to become part of webp release)
214	myconf+="
215	-Duse_system_bzip2=1
216	-Duse_system_flac=1
217	-Duse_system_icu=1
218	-Duse_system_libevent=1
219	-Duse_system_libjpeg=1
220	-Duse_system_libpng=1
221	-Duse_system_libusb=1
222	-Duse_system_libxml=1
223	-Duse_system_speex=1
224	-Duse_system_v8=1
225	-Duse_system_xdg_utils=1
226	-Duse_system_yasm=1
227	-Duse_system_zlib=1"
228
229	# Optional dependencies.
230	# TODO: linux_link_kerberos, bug #381289.
231	myconf+="
232	$(gyp_use cups)
233	$(gyp_use gnome use_gconf)
234	$(gyp_use gnome-keyring use_gnome_keyring)
235	$(gyp_use gnome-keyring linux_link_gnome_keyring)
236	$(gyp_use kerberos)
237	$(gyp_use pulseaudio)
238	$(gyp_use selinux selinux)"
239
240	if ! use selinux; then
241	# Enable SUID sandbox.
242	myconf+="
243	-Dlinux_sandbox_path=${CHROMIUM_HOME}/chrome_sandbox
244	-Dlinux_sandbox_chrome_path=${CHROMIUM_HOME}/chrome"
245	fi
246
247	# Never use bundled gold binary. Disable gold linker flags for now.
248	myconf+="
249	-Dlinux_use_gold_binary=0
250	-Dlinux_use_gold_flags=0"
251
252	if ! use bindist; then
253	# Enable H.624 support in bundled ffmpeg.
254	myconf+=" -Dproprietary_codecs=1 -Dffmpeg_branding=Chrome"
255	fi
256
257	local myarch="$(tc-arch)"
258	if [[ $myarch = amd64 ]] ; then
259	myconf+=" -Dtarget_arch=x64"
260	elif [[ $myarch = x86 ]] ; then
261	myconf+=" -Dtarget_arch=ia32"
262	else
263	die "Failed to determine target arch, got '$myarch'."
264	fi
265
266	# Make sure that -Werror doesn't get added to CFLAGS by the build system.
267	# Depending on GCC version the warnings are different and we don't want
268	# the build to fail because of that.
269	myconf+=" -Dwerror="
270
271	# Avoid CFLAGS problems, bug #352457, bug #390147.
272	if ! use custom-cflags; then
273	replace-flags "-Os" "-O2"
274	strip-flags
275	fi
276
277	egyp_chromium ${myconf} \|\| die
278	}
279
280	src_compile() {
281	local test_targets
282	for x in base cacheinvalidation crypto \
283	googleurl gpu media net printing sql; do
284	test_targets+=" ${x}_unittests"
285	done
286
287	local make_targets="chrome chromedriver"
288	if ! use selinux; then
289	make_targets+=" chrome_sandbox"
290	fi
291	if use test; then
292	make_targets+=$test_targets
293	fi
294
295	# See bug #410883 for more info about the .host mess.
296	emake ${make_targets} BUILDTYPE=Release V=1 \
297	CC.host="$(tc-getCC)" CFLAGS.host="${CFLAGS}" \
298	CXX.host="$(tc-getCXX)" CXXFLAGS.host="${CXXFLAGS}" \
299	LINK.host="$(tc-getCXX)" LDFLAGS.host="${LDFLAGS}" \
300	AR.host="$(tc-getAR)" \|\| die
301
302	pax-mark m out/Release/chrome
303	if use test; then
304	for x in $test_targets; do
305	pax-mark m out/Release/${x}
306	done
307	fi
308	}
309
310	src_test() {
311	# For more info see bug #350349.
312	local mylocale='en_US.utf8'
313	if ! locale -a \| grep -q "$mylocale"; then
314	eerror "${PN} requires ${mylocale} locale for tests"
315	eerror "Please read the following guides for more information:"
316	eerror " http://www.gentoo.org/doc/en/guide-localization.xml"
317	eerror " http://www.gentoo.org/doc/en/utf-8.xml"
318	die "locale ${mylocale} is not supported"
319	fi
320
321	# For more info see bug #370957.
322	if [[ $UID -eq 0 ]]; then
323	die "Tests must be run as non-root. Please use FEATURES=userpriv."
324	fi
325
326	runtest() {
327	local cmd=$1
328	shift
329	einfo "${cmd}" "$@"
330	LC_ALL="${mylocale}" VIRTUALX_COMMAND="${cmd}" virtualmake "$@"
331	}
332
333	# ICUStringConversionsTest: bug #350347.
334	# MessagePumpLibeventTest: bug #398501.
335	runtest out/Release/base_unittests \
336	'--gtest_filter=-ICUStringConversionsTest.:MessagePumpLibeventTest.'
337
338	runtest out/Release/cacheinvalidation_unittests
339	runtest out/Release/crypto_unittests
340	runtest out/Release/googleurl_unittests
341	runtest out/Release/gpu_unittests
342	runtest out/Release/media_unittests
343
344	# NetUtilTest: bug #361885.
345	# DnsConfigServiceTest.GetSystemConfig: bug #394883.
346	# CertDatabaseNSSTest.ImportServerCert_SelfSigned: bug #399269.
347	runtest out/Release/net_unittests \
348	'--gtest_filter=-NetUtilTest.IDNToUnicode:NetUtilTest.FormatUrl:DnsConfigServiceTest.GetSystemConfig:CertDatabaseNSSTest.ImportServerCert_SelfSigned:URLFetcher*'
349
350	runtest out/Release/printing_unittests
351	runtest out/Release/sql_unittests
352	}
353
354	src_install() {
355	exeinto "${CHROMIUM_HOME}"
356	doexe out/Release/chrome \|\| die
357
358	if ! use selinux; then
359	doexe out/Release/chrome_sandbox \|\| die
360	fperms 4755 "${CHROMIUM_HOME}/chrome_sandbox"
361	fi
362
363	doexe out/Release/chromedriver \|\| die
364
365	doexe out/Release/nacl_helper{,_bootstrap} \|\| die
366	insinto "${CHROMIUM_HOME}"
367	doins out/Release/nacl_irt_*.nexe \|\| die
368	doins out/Release/libppGoogleNaClPluginChrome.so \|\| die
369
370	newexe "${FILESDIR}"/chromium-launcher-r2.sh chromium-launcher.sh \|\| die
371	if [[ "${CHROMIUM_SUFFIX}" != "" ]]; then
372	sed "s:chromium-browser:chromium-browser${CHROMIUM_SUFFIX}:g" \
373	-i "${ED}"/"${CHROMIUM_HOME}"/chromium-launcher.sh \|\| die
374	sed "s:chromium.desktop:chromium${CHROMIUM_SUFFIX}.desktop:g" \
375	-i "${ED}"/"${CHROMIUM_HOME}"/chromium-launcher.sh \|\| die
376	sed "s:plugins:plugins --user-data-dir=\${HOME}/.config/chromium${CHROMIUM_SUFFIX}:" \
377	-i "${ED}"/"${CHROMIUM_HOME}"/chromium-launcher.sh \|\| die
378	fi
379
380	# It is important that we name the target "chromium-browser",
381	# xdg-utils expect it; bug #355517.
382	dosym "${CHROMIUM_HOME}/chromium-launcher.sh" /usr/bin/chromium-browser${CHROMIUM_SUFFIX} \|\| die
383	# keep the old symlink around for consistency
384	dosym "${CHROMIUM_HOME}/chromium-launcher.sh" /usr/bin/chromium${CHROMIUM_SUFFIX} \|\| die
385
386	# Allow users to override command-line options, bug #357629.
387	dodir /etc/chromium \|\| die
388	insinto /etc/chromium
389	newins "${FILESDIR}/chromium.default" "default" \|\| die
390
391	pushd out/Release/locales > /dev/null \|\| die
392	chromium_remove_language_paks
393	popd
394
395	insinto "${CHROMIUM_HOME}"
396	doins out/Release/*.pak \|\| die
397
398	doins -r out/Release/locales \|\| die
399	doins -r out/Release/resources \|\| die
400
401	newman out/Release/chrome.1 chromium${CHROMIUM_SUFFIX}.1 \|\| die
402	newman out/Release/chrome.1 chromium-browser${CHROMIUM_SUFFIX}.1 \|\| die
403
404	doexe out/Release/libffmpegsumo.so \|\| die
405
406	# Install icons and desktop entry.
407	local branding size
408	for size in 16 22 24 32 48 64 128 256 ; do
409	case ${size} in
410	16\|32) branding="chrome/app/theme/default_100_percent/chromium" ;;
411	*) branding="chrome/app/theme/chromium" ;;
412	esac
413	newicon -s ${size} "${branding}/product_logo_${size}.png" \
414	chromium-browser${CHROMIUM_SUFFIX}.png
415	done
416
417	local mime_types="text/html;text/xml;application/xhtml+xml;"
418	mime_types+="x-scheme-handler/http;x-scheme-handler/https;" # bug #360797
419	mime_types+="x-scheme-handler/ftp;" # bug #412185
420	mime_types+="x-scheme-handler/mailto;x-scheme-handler/webcal;" # bug #416393
421	make_desktop_entry \
422	chromium-browser${CHROMIUM_SUFFIX} \
423	"Chromium${CHROMIUM_SUFFIX}" \
424	chromium-browser${CHROMIUM_SUFFIX} \
425	"Network;WebBrowser" \
426	"MimeType=${mime_types}\nStartupWMClass=chromium-browser"
427	sed -e "/^Exec/s/$/ %U/" -i "${ED}"/usr/share/applications/*.desktop \|\| die
428
429	# Install GNOME default application entry (bug #303100).
430	if use gnome; then
431	dodir /usr/share/gnome-control-center/default-apps \|\| die
432	insinto /usr/share/gnome-control-center/default-apps
433	newins "${FILESDIR}"/chromium-browser.xml chromium-browser${CHROMIUM_SUFFIX}.xml \|\| die
434	if [[ "${CHROMIUM_SUFFIX}" != "" ]]; then
435	sed "s:chromium-browser:chromium-browser${CHROMIUM_SUFFIX}:g" -i \
436	"${ED}"/usr/share/gnome-control-center/default-apps/chromium-browser${CHROMIUM_SUFFIX}.xml
437	fi
438	fi
439	}