www-client/chromium/chromium-22.0.1215.0.ebuild

# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/www-client/chromium/chromium-22.0.1215.0.ebuild,v 1.1 2012/07/24 03:27:28 floppym Exp $

EAPI="4"
PYTHON_DEPEND="2:2.6"

CHROMIUM_LANGS="am ar bg bn ca cs da de el en_GB es es_LA et fa fi fil fr gu he
        hi hr hu id it ja kn ko lt lv ml mr ms nb nl pl pt_BR pt_PT ro ru sk sl sr
        sv sw ta te th tr uk vi zh_CN zh_TW"

inherit chromium eutils flag-o-matic multilib \
        pax-utils portability python toolchain-funcs versionator virtualx

DESCRIPTION="Open-source version of Google Chrome web browser"
HOMEPAGE="http://chromium.org/"
SRC_URI="http://commondatastorage.googleapis.com/chromium-browser-official/${P}.tar.bz2"

LICENSE="BSD"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="bindist cups gnome gnome-keyring kerberos pulseaudio selinux"

RDEPEND="app-arch/bzip2
        cups? (
                dev-libs/libgcrypt
                >=net-print/cups-1.3.11
        )
        >=dev-lang/v8-3.11.10.6
        dev-libs/dbus-glib
        dev-libs/elfutils
        dev-libs/expat
        >=dev-libs/icu-49.1.1-r1
        >=dev-libs/libevent-1.4.13
        dev-libs/libxml2[icu]
        dev-libs/libxslt
        >=dev-libs/nss-3.12.3
        gnome? ( >=gnome-base/gconf-2.24.0 )
        gnome-keyring? ( >=gnome-base/gnome-keyring-2.28.2 )
        >=media-libs/alsa-lib-1.0.19
        media-libs/flac
        >=media-libs/libjpeg-turbo-1.2.0-r1
        media-libs/libpng
        media-libs/speex
        pulseaudio? ( media-sound/pulseaudio )
        sys-fs/udev
        sys-libs/zlib
        virtual/libusb:1
        x11-libs/gtk+:2
        x11-libs/libXinerama
        x11-libs/libXScrnSaver
        x11-libs/libXtst
        kerberos? ( virtual/krb5 )
        selinux? ( sys-libs/libselinux )"
DEPEND="${RDEPEND}
        >=dev-lang/nacl-toolchain-newlib-0_p9093
        dev-lang/perl
        dev-lang/yasm
        dev-python/ply
        dev-python/simplejson
        >=dev-util/gperf-3.0.3
        >=sys-devel/bison-2.4.3
        sys-devel/flex
        >=sys-devel/make-3.81-r2
        virtual/pkgconfig
        test? (
                dev-python/pyftpdlib
        )"
RDEPEND+="
        !=www-client/chromium-9999
        x11-misc/xdg-utils
        virtual/ttf-fonts"

if ! has chromium_pkg_die ${EBUILD_DEATH_HOOKS}; then
        EBUILD_DEATH_HOOKS+=" chromium_pkg_die";
fi

pkg_setup() {
        if [[ "${SLOT}" == "0" ]]; then
                CHROMIUM_SUFFIX=""
        else
                CHROMIUM_SUFFIX="-${SLOT}"
        fi
        CHROMIUM_HOME="/usr/$(get_libdir)/chromium-browser${CHROMIUM_SUFFIX}"

        # Make sure the build system will use the right tools, bug #340795.
        tc-export AR CC CXX RANLIB

        # Make sure the build system will use the right python, bug #344367.
        python_set_active_version 2
        python_pkg_setup

        if ! use selinux; then
                chromium_suid_sandbox_check_kernel_config
        fi

        if use bindist; then
                elog "bindist enabled: H.264 video support will be disabled."
        else
                elog "bindist disabled: Resulting binaries may not be legal to re-distribute."
        fi
}

src_prepare() {
        ln -s /usr/$(get_libdir)/nacl-toolchain-newlib \
                native_client/toolchain/linux_x86_newlib || die

        # zlib-1.2.5.1-r1 renames the OF macro in zconf.h, bug 383371.
        sed -i '1i#define OF(x) x' \
                third_party/zlib/contrib/minizip/{ioapi,{,un}zip}.h || die

        # Fix build without NaCl glibc toolchain.
        epatch "${FILESDIR}/${PN}-ppapi-r0.patch"

        epatch "${FILESDIR}/${PN}-libyuv-system-libjpeg-r0.patch"

        # Bug 427438.
        epatch "${FILESDIR}/${PN}-bison-2.6-r0.patch"

        epatch_user

        # Remove most bundled libraries. Some are still needed.
        find third_party -type f \! -iname '*.gyp*' \
                \! -path 'third_party/WebKit/*' \
                \! -path 'third_party/angle/*' \
                \! -path 'third_party/cacheinvalidation/*' \
                \! -path 'third_party/cld/*' \
                \! -path 'third_party/ffmpeg/*' \
                \! -path 'third_party/flac/flac.h' \
                \! -path 'third_party/gpsd/*' \
                \! -path 'third_party/harfbuzz/*' \
                \! -path 'third_party/hunspell/*' \
                \! -path 'third_party/hyphen/*' \
                \! -path 'third_party/iccjpeg/*' \
                \! -path 'third_party/jsoncpp/*' \
                \! -path 'third_party/khronos/*' \
                \! -path 'third_party/launchpad_translations/*' \
                \! -path 'third_party/leveldatabase/*' \
                \! -path 'third_party/libjingle/*' \
                \! -path 'third_party/libphonenumber/*' \
                \! -path 'third_party/libsrtp/*' \
                \! -path 'third_party/libusb/libusb.h' \
                \! -path 'third_party/libva/*' \
                \! -path 'third_party/libvpx/*' \
                \! -path 'third_party/libwebp/*' \
                \! -path 'third_party/libxml/chromium/*' \
                \! -path 'third_party/libXNVCtrl/*' \
                \! -path 'third_party/libyuv/*' \
                \! -path 'third_party/lss/*' \
                \! -path 'third_party/mesa/*' \
                \! -path 'third_party/modp_b64/*' \
                \! -path 'third_party/mongoose/*' \
                \! -path 'third_party/npapi/*' \
                \! -path 'third_party/openmax/*' \
                \! -path 'third_party/ots/*' \
                \! -path 'third_party/protobuf/*' \
                \! -path 'third_party/qcms/*' \
                \! -path 'third_party/scons-2.0.1/*' \
                \! -path 'third_party/sfntly/*' \
                \! -path 'third_party/skia/*' \
                \! -path 'third_party/smhasher/*' \
                \! -path 'third_party/speex/speex.h' \
                \! -path 'third_party/sqlite/*' \
                \! -path 'third_party/tlslite/*' \
                \! -path 'third_party/trace-viewer/*' \
                \! -path 'third_party/undoview/*' \
                \! -path 'third_party/v8-i18n/*' \
                \! -path 'third_party/webdriver/*' \
                \! -path 'third_party/webgl_conformance/*' \
                \! -path 'third_party/webrtc/*' \
                \! -path 'third_party/zlib/contrib/minizip/*' \
                -delete || die

        local v8_bundled="$(chromium_bundled_v8_version)"
        local v8_installed="$(chromium_installed_v8_version)"
        einfo "V8 version: bundled - ${v8_bundled}; installed - ${v8_installed}"

        # Remove bundled v8.
        find v8 -type f \! -iname '*.gyp*' -delete || die

        # The implementation files include v8 headers with full path,
        # like #include "v8/include/v8.h". Make sure the system headers
        # will be used.
        # TODO: find a solution that can be upstreamed.
        rmdir v8/include || die
        ln -s /usr/include v8/include || die

        # Make sure the build system will use the right python, bug #344367.
        # Only convert directories that need it, to save time.
        python_convert_shebangs -q -r 2 build tools
}

src_configure() {
        local myconf=""

        # Never tell the build system to "enable" SSE2, it has a few unexpected
        # additions, bug #336871.
        myconf+=" -Ddisable_sse2=1"

        # Disable tcmalloc, it causes problems with e.g. NVIDIA
        # drivers, bug #413637.
        myconf+=" -Dlinux_use_tcmalloc=0"

        # Disable glibc Native Client toolchain, we don't need it (bug #417019).
        myconf+=" -Ddisable_glibc=1"

        # Make it possible to remove third_party/adobe.
        echo > "${T}/flapper_version.h" || die
        myconf+=" -Dflapper_version_h_file=${T}/flapper_version.h"

        # Use system-provided libraries.
        # TODO: use_system_ffmpeg
        # TODO: use_system_hunspell (upstream changes needed).
        # TODO: use_system_ssl (http://crbug.com/58087).
        # TODO: use_system_sqlite (http://crbug.com/22208).
        # TODO: use_system_vpx
        # TODO: use_system_webp (https://chromiumcodereview.appspot.com/10496016
        #       needs to become part of webp release)
        myconf+="
                -Duse_system_bzip2=1
                -Duse_system_flac=1
                -Duse_system_icu=1
                -Duse_system_libevent=1
                -Duse_system_libjpeg=1
                -Duse_system_libpng=1
                -Duse_system_libusb=1
                -Duse_system_libxml=1
                -Duse_system_speex=1
                -Duse_system_v8=1
                -Duse_system_xdg_utils=1
                -Duse_system_yasm=1
                -Duse_system_zlib=1"

        # Optional dependencies.
        # TODO: linux_link_kerberos, bug #381289.
        myconf+="
                $(gyp_use cups)
                $(gyp_use gnome use_gconf)
                $(gyp_use gnome-keyring use_gnome_keyring)
                $(gyp_use gnome-keyring linux_link_gnome_keyring)
                $(gyp_use kerberos)
                $(gyp_use pulseaudio)
                $(gyp_use selinux selinux)"

        if ! use selinux; then
                # Enable SUID sandbox.
                myconf+="
                        -Dlinux_sandbox_path=${CHROMIUM_HOME}/chrome_sandbox
                        -Dlinux_sandbox_chrome_path=${CHROMIUM_HOME}/chrome"
        fi

        # Never use bundled gold binary. Disable gold linker flags for now.
        myconf+="
                -Dlinux_use_gold_binary=0
                -Dlinux_use_gold_flags=0"

        if ! use bindist; then
                # Enable H.624 support in bundled ffmpeg.
                myconf+=" -Dproprietary_codecs=1 -Dffmpeg_branding=Chrome"
        fi

        local myarch="$(tc-arch)"
        if [[ $myarch = amd64 ]] ; then
                myconf+=" -Dtarget_arch=x64"
        elif [[ $myarch = x86 ]] ; then
                myconf+=" -Dtarget_arch=ia32"
        else
                die "Failed to determine target arch, got '$myarch'."
        fi

        # Make sure that -Werror doesn't get added to CFLAGS by the build system.
        # Depending on GCC version the warnings are different and we don't want
        # the build to fail because of that.
        myconf+=" -Dwerror="

        # Avoid CFLAGS problems, bug #352457, bug #390147.
        if ! use custom-cflags; then
                replace-flags "-Os" "-O2"
                strip-flags
        fi

        egyp_chromium ${myconf} || die
}

src_compile() {
        local test_targets
        for x in base cacheinvalidation crypto \
                googleurl gpu media net printing sql; do
                test_targets+=" ${x}_unittests"
        done

        local make_targets="chrome chromedriver"
        if ! use selinux; then
                make_targets+=" chrome_sandbox"
        fi
        if use test; then
                make_targets+=$test_targets
        fi

        # See bug #410883 for more info about the .host mess.
        emake ${make_targets} BUILDTYPE=Release V=1 \
                CC.host="$(tc-getCC)" CFLAGS.host="${CFLAGS}" \
                CXX.host="$(tc-getCXX)" CXXFLAGS.host="${CXXFLAGS}" \
                LINK.host="$(tc-getCXX)" LDFLAGS.host="${LDFLAGS}" \
                AR.host="$(tc-getAR)" || die

        pax-mark m out/Release/chrome
        if use test; then
                for x in $test_targets; do
                        pax-mark m out/Release/${x}
                done
        fi
}

src_test() {
        # For more info see bug #350349.
        local mylocale='en_US.utf8'
        if ! locale -a | grep -q "$mylocale"; then
                eerror "${PN} requires ${mylocale} locale for tests"
                eerror "Please read the following guides for more information:"
                eerror "  http://www.gentoo.org/doc/en/guide-localization.xml"
                eerror "  http://www.gentoo.org/doc/en/utf-8.xml"
                die "locale ${mylocale} is not supported"
        fi

        # For more info see bug #370957.
        if [[ $UID -eq 0 ]]; then
                die "Tests must be run as non-root. Please use FEATURES=userpriv."
        fi

        runtest() {
                local cmd=$1
                shift
                einfo "${cmd}" "$@"
                LC_ALL="${mylocale}" VIRTUALX_COMMAND="${cmd}" virtualmake "$@"
        }

        # ICUStringConversionsTest: bug #350347.
        # MessagePumpLibeventTest: bug #398501.
        runtest out/Release/base_unittests \
                '--gtest_filter=-ICUStringConversionsTest.*:MessagePumpLibeventTest.*'

        runtest out/Release/cacheinvalidation_unittests
        runtest out/Release/crypto_unittests
        runtest out/Release/googleurl_unittests
        runtest out/Release/gpu_unittests
        runtest out/Release/media_unittests

        # NetUtilTest: bug #361885.
        # DnsConfigServiceTest.GetSystemConfig: bug #394883.
        # CertDatabaseNSSTest.ImportServerCert_SelfSigned: bug #399269.
        runtest out/Release/net_unittests \
                '--gtest_filter=-NetUtilTest.IDNToUnicode*:NetUtilTest.FormatUrl*:DnsConfigServiceTest.GetSystemConfig:CertDatabaseNSSTest.ImportServerCert_SelfSigned:URLFetcher*'

        runtest out/Release/printing_unittests
        runtest out/Release/sql_unittests
}

src_install() {
        exeinto "${CHROMIUM_HOME}"
        doexe out/Release/chrome || die

        if ! use selinux; then
                doexe out/Release/chrome_sandbox || die
                fperms 4755 "${CHROMIUM_HOME}/chrome_sandbox"
        fi

        doexe out/Release/chromedriver || die

        doexe out/Release/nacl_helper{,_bootstrap} || die
        insinto "${CHROMIUM_HOME}"
        doins out/Release/nacl_irt_*.nexe || die
        doins out/Release/libppGoogleNaClPluginChrome.so || die

        newexe "${FILESDIR}"/chromium-launcher-r2.sh chromium-launcher.sh || die
        if [[ "${CHROMIUM_SUFFIX}" != "" ]]; then
                sed "s:chromium-browser:chromium-browser${CHROMIUM_SUFFIX}:g" \
                        -i "${ED}"/"${CHROMIUM_HOME}"/chromium-launcher.sh || die
                sed "s:chromium.desktop:chromium${CHROMIUM_SUFFIX}.desktop:g" \
                        -i "${ED}"/"${CHROMIUM_HOME}"/chromium-launcher.sh || die
                sed "s:plugins:plugins --user-data-dir=\${HOME}/.config/chromium${CHROMIUM_SUFFIX}:" \
                        -i "${ED}"/"${CHROMIUM_HOME}"/chromium-launcher.sh || die
        fi

        # It is important that we name the target "chromium-browser",
        # xdg-utils expect it; bug #355517.
        dosym "${CHROMIUM_HOME}/chromium-launcher.sh" /usr/bin/chromium-browser${CHROMIUM_SUFFIX} || die
        # keep the old symlink around for consistency
        dosym "${CHROMIUM_HOME}/chromium-launcher.sh" /usr/bin/chromium${CHROMIUM_SUFFIX} || die

        # Allow users to override command-line options, bug #357629.
        dodir /etc/chromium || die
        insinto /etc/chromium
        newins "${FILESDIR}/chromium.default" "default" || die

        pushd out/Release/locales > /dev/null || die
        chromium_remove_language_paks
        popd

        insinto "${CHROMIUM_HOME}"
        doins out/Release/*.pak || die

        doins -r out/Release/locales || die
        doins -r out/Release/resources || die

        newman out/Release/chrome.1 chromium${CHROMIUM_SUFFIX}.1 || die
        newman out/Release/chrome.1 chromium-browser${CHROMIUM_SUFFIX}.1 || die

        doexe out/Release/libffmpegsumo.so || die

        # Install icons and desktop entry.
        local branding size
        for size in 16 22 24 32 48 64 128 256 ; do
                case ${size} in
                        16|32) branding="chrome/app/theme/default_100_percent/chromium" ;;
                                *) branding="chrome/app/theme/chromium" ;;
                esac
                newicon -s ${size} "${branding}/product_logo_${size}.png" \
                        chromium-browser${CHROMIUM_SUFFIX}.png
        done

        local mime_types="text/html;text/xml;application/xhtml+xml;"
        mime_types+="x-scheme-handler/http;x-scheme-handler/https;" # bug #360797
        mime_types+="x-scheme-handler/ftp;" # bug #412185
        mime_types+="x-scheme-handler/mailto;x-scheme-handler/webcal;" # bug #416393
        make_desktop_entry \
                chromium-browser${CHROMIUM_SUFFIX} \
                "Chromium${CHROMIUM_SUFFIX}" \
                chromium-browser${CHROMIUM_SUFFIX} \
                "Network;WebBrowser" \
                "MimeType=${mime_types}\nStartupWMClass=chromium-browser"
        sed -e "/^Exec/s/$/ %U/" -i "${ED}"/usr/share/applications/*.desktop || die

        # Install GNOME default application entry (bug #303100).
        if use gnome; then
                dodir /usr/share/gnome-control-center/default-apps || die
                insinto /usr/share/gnome-control-center/default-apps
                newins "${FILESDIR}"/chromium-browser.xml chromium-browser${CHROMIUM_SUFFIX}.xml || die
                if [[ "${CHROMIUM_SUFFIX}" != "" ]]; then
                        sed "s:chromium-browser:chromium-browser${CHROMIUM_SUFFIX}:g" -i \
                                "${ED}"/usr/share/gnome-control-center/default-apps/chromium-browser${CHROMIUM_SUFFIX}.xml
                fi
        fi
}
1	# Copyright 1999-2012 Gentoo Foundation
2	# Distributed under the terms of the GNU General Public License v2
3	# $Header: /var/cvsroot/gentoo-x86/www-client/chromium/chromium-22.0.1215.0.ebuild,v 1.1 2012/07/24 03:27:28 floppym Exp $
4
5	EAPI="4"
6	PYTHON_DEPEND="2:2.6"
7
8	CHROMIUM_LANGS="am ar bg bn ca cs da de el en_GB es es_LA et fa fi fil fr gu he
9	hi hr hu id it ja kn ko lt lv ml mr ms nb nl pl pt_BR pt_PT ro ru sk sl sr
10	sv sw ta te th tr uk vi zh_CN zh_TW"
11
12	inherit chromium eutils flag-o-matic multilib \
13	pax-utils portability python toolchain-funcs versionator virtualx
14
15	DESCRIPTION="Open-source version of Google Chrome web browser"
16	HOMEPAGE="http://chromium.org/"
17	SRC_URI="http://commondatastorage.googleapis.com/chromium-browser-official/${P}.tar.bz2"
18
19	LICENSE="BSD"
20	SLOT="0"
21	KEYWORDS="~amd64 ~x86"
22	IUSE="bindist cups gnome gnome-keyring kerberos pulseaudio selinux"
23
24	RDEPEND="app-arch/bzip2
25	cups? (
26	dev-libs/libgcrypt
27	>=net-print/cups-1.3.11
28	)
29	>=dev-lang/v8-3.11.10.6
30	dev-libs/dbus-glib
31	dev-libs/elfutils
32	dev-libs/expat
33	>=dev-libs/icu-49.1.1-r1
34	>=dev-libs/libevent-1.4.13
35	dev-libs/libxml2[icu]
36	dev-libs/libxslt
37	>=dev-libs/nss-3.12.3
38	gnome? ( >=gnome-base/gconf-2.24.0 )
39	gnome-keyring? ( >=gnome-base/gnome-keyring-2.28.2 )
40	>=media-libs/alsa-lib-1.0.19
41	media-libs/flac
42	>=media-libs/libjpeg-turbo-1.2.0-r1
43	media-libs/libpng
44	media-libs/speex
45	pulseaudio? ( media-sound/pulseaudio )
46	sys-fs/udev
47	sys-libs/zlib
48	virtual/libusb:1
49	x11-libs/gtk+:2
50	x11-libs/libXinerama
51	x11-libs/libXScrnSaver
52	x11-libs/libXtst
53	kerberos? ( virtual/krb5 )
54	selinux? ( sys-libs/libselinux )"
55	DEPEND="${RDEPEND}
56	>=dev-lang/nacl-toolchain-newlib-0_p9093
57	dev-lang/perl
58	dev-lang/yasm
59	dev-python/ply
60	dev-python/simplejson
61	>=dev-util/gperf-3.0.3
62	>=sys-devel/bison-2.4.3
63	sys-devel/flex
64	>=sys-devel/make-3.81-r2
65	virtual/pkgconfig
66	test? (
67	dev-python/pyftpdlib
68	)"
69	RDEPEND+="
70	!=www-client/chromium-9999
71	x11-misc/xdg-utils
72	virtual/ttf-fonts"
73
74	if ! has chromium_pkg_die ${EBUILD_DEATH_HOOKS}; then
75	EBUILD_DEATH_HOOKS+=" chromium_pkg_die";
76	fi
77
78	pkg_setup() {
79	if [[ "${SLOT}" == "0" ]]; then
80	CHROMIUM_SUFFIX=""
81	else
82	CHROMIUM_SUFFIX="-${SLOT}"
83	fi
84	CHROMIUM_HOME="/usr/$(get_libdir)/chromium-browser${CHROMIUM_SUFFIX}"
85
86	# Make sure the build system will use the right tools, bug #340795.
87	tc-export AR CC CXX RANLIB
88
89	# Make sure the build system will use the right python, bug #344367.
90	python_set_active_version 2
91	python_pkg_setup
92
93	if ! use selinux; then
94	chromium_suid_sandbox_check_kernel_config
95	fi
96
97	if use bindist; then
98	elog "bindist enabled: H.264 video support will be disabled."
99	else
100	elog "bindist disabled: Resulting binaries may not be legal to re-distribute."
101	fi
102	}
103
104	src_prepare() {
105	ln -s /usr/$(get_libdir)/nacl-toolchain-newlib \
106	native_client/toolchain/linux_x86_newlib \|\| die
107
108	# zlib-1.2.5.1-r1 renames the OF macro in zconf.h, bug 383371.
109	sed -i '1i#define OF(x) x' \
110	third_party/zlib/contrib/minizip/{ioapi,{,un}zip}.h \|\| die
111
112	# Fix build without NaCl glibc toolchain.
113	epatch "${FILESDIR}/${PN}-ppapi-r0.patch"
114
115	epatch "${FILESDIR}/${PN}-libyuv-system-libjpeg-r0.patch"
116
117	# Bug 427438.
118	epatch "${FILESDIR}/${PN}-bison-2.6-r0.patch"
119
120	epatch_user
121
122	# Remove most bundled libraries. Some are still needed.
123	find third_party -type f \! -iname '.gyp' \
124	\! -path 'third_party/WebKit/*' \
125	\! -path 'third_party/angle/*' \
126	\! -path 'third_party/cacheinvalidation/*' \
127	\! -path 'third_party/cld/*' \
128	\! -path 'third_party/ffmpeg/*' \
129	\! -path 'third_party/flac/flac.h' \
130	\! -path 'third_party/gpsd/*' \
131	\! -path 'third_party/harfbuzz/*' \
132	\! -path 'third_party/hunspell/*' \
133	\! -path 'third_party/hyphen/*' \
134	\! -path 'third_party/iccjpeg/*' \
135	\! -path 'third_party/jsoncpp/*' \
136	\! -path 'third_party/khronos/*' \
137	\! -path 'third_party/launchpad_translations/*' \
138	\! -path 'third_party/leveldatabase/*' \
139	\! -path 'third_party/libjingle/*' \
140	\! -path 'third_party/libphonenumber/*' \
141	\! -path 'third_party/libsrtp/*' \
142	\! -path 'third_party/libusb/libusb.h' \
143	\! -path 'third_party/libva/*' \
144	\! -path 'third_party/libvpx/*' \
145	\! -path 'third_party/libwebp/*' \
146	\! -path 'third_party/libxml/chromium/*' \
147	\! -path 'third_party/libXNVCtrl/*' \
148	\! -path 'third_party/libyuv/*' \
149	\! -path 'third_party/lss/*' \
150	\! -path 'third_party/mesa/*' \
151	\! -path 'third_party/modp_b64/*' \
152	\! -path 'third_party/mongoose/*' \
153	\! -path 'third_party/npapi/*' \
154	\! -path 'third_party/openmax/*' \
155	\! -path 'third_party/ots/*' \
156	\! -path 'third_party/protobuf/*' \
157	\! -path 'third_party/qcms/*' \
158	\! -path 'third_party/scons-2.0.1/*' \
159	\! -path 'third_party/sfntly/*' \
160	\! -path 'third_party/skia/*' \
161	\! -path 'third_party/smhasher/*' \
162	\! -path 'third_party/speex/speex.h' \
163	\! -path 'third_party/sqlite/*' \
164	\! -path 'third_party/tlslite/*' \
165	\! -path 'third_party/trace-viewer/*' \
166	\! -path 'third_party/undoview/*' \
167	\! -path 'third_party/v8-i18n/*' \
168	\! -path 'third_party/webdriver/*' \
169	\! -path 'third_party/webgl_conformance/*' \
170	\! -path 'third_party/webrtc/*' \
171	\! -path 'third_party/zlib/contrib/minizip/*' \
172	-delete \|\| die
173
174	local v8_bundled="$(chromium_bundled_v8_version)"
175	local v8_installed="$(chromium_installed_v8_version)"
176	einfo "V8 version: bundled - ${v8_bundled}; installed - ${v8_installed}"
177
178	# Remove bundled v8.
179	find v8 -type f \! -iname '.gyp' -delete \|\| die
180
181	# The implementation files include v8 headers with full path,
182	# like #include "v8/include/v8.h". Make sure the system headers
183	# will be used.
184	# TODO: find a solution that can be upstreamed.
185	rmdir v8/include \|\| die
186	ln -s /usr/include v8/include \|\| die
187
188	# Make sure the build system will use the right python, bug #344367.
189	# Only convert directories that need it, to save time.
190	python_convert_shebangs -q -r 2 build tools
191	}
192
193	src_configure() {
194	local myconf=""
195
196	# Never tell the build system to "enable" SSE2, it has a few unexpected
197	# additions, bug #336871.
198	myconf+=" -Ddisable_sse2=1"
199
200	# Disable tcmalloc, it causes problems with e.g. NVIDIA
201	# drivers, bug #413637.
202	myconf+=" -Dlinux_use_tcmalloc=0"
203
204	# Disable glibc Native Client toolchain, we don't need it (bug #417019).
205	myconf+=" -Ddisable_glibc=1"
206
207	# Make it possible to remove third_party/adobe.
208	echo > "${T}/flapper_version.h" \|\| die
209	myconf+=" -Dflapper_version_h_file=${T}/flapper_version.h"
210
211	# Use system-provided libraries.
212	# TODO: use_system_ffmpeg
213	# TODO: use_system_hunspell (upstream changes needed).
214	# TODO: use_system_ssl (http://crbug.com/58087).
215	# TODO: use_system_sqlite (http://crbug.com/22208).
216	# TODO: use_system_vpx
217	# TODO: use_system_webp (https://chromiumcodereview.appspot.com/10496016
218	# needs to become part of webp release)
219	myconf+="
220	-Duse_system_bzip2=1
221	-Duse_system_flac=1
222	-Duse_system_icu=1
223	-Duse_system_libevent=1
224	-Duse_system_libjpeg=1
225	-Duse_system_libpng=1
226	-Duse_system_libusb=1
227	-Duse_system_libxml=1
228	-Duse_system_speex=1
229	-Duse_system_v8=1
230	-Duse_system_xdg_utils=1
231	-Duse_system_yasm=1
232	-Duse_system_zlib=1"
233
234	# Optional dependencies.
235	# TODO: linux_link_kerberos, bug #381289.
236	myconf+="
237	$(gyp_use cups)
238	$(gyp_use gnome use_gconf)
239	$(gyp_use gnome-keyring use_gnome_keyring)
240	$(gyp_use gnome-keyring linux_link_gnome_keyring)
241	$(gyp_use kerberos)
242	$(gyp_use pulseaudio)
243	$(gyp_use selinux selinux)"
244
245	if ! use selinux; then
246	# Enable SUID sandbox.
247	myconf+="
248	-Dlinux_sandbox_path=${CHROMIUM_HOME}/chrome_sandbox
249	-Dlinux_sandbox_chrome_path=${CHROMIUM_HOME}/chrome"
250	fi
251
252	# Never use bundled gold binary. Disable gold linker flags for now.
253	myconf+="
254	-Dlinux_use_gold_binary=0
255	-Dlinux_use_gold_flags=0"
256
257	if ! use bindist; then
258	# Enable H.624 support in bundled ffmpeg.
259	myconf+=" -Dproprietary_codecs=1 -Dffmpeg_branding=Chrome"
260	fi
261
262	local myarch="$(tc-arch)"
263	if [[ $myarch = amd64 ]] ; then
264	myconf+=" -Dtarget_arch=x64"
265	elif [[ $myarch = x86 ]] ; then
266	myconf+=" -Dtarget_arch=ia32"
267	else
268	die "Failed to determine target arch, got '$myarch'."
269	fi
270
271	# Make sure that -Werror doesn't get added to CFLAGS by the build system.
272	# Depending on GCC version the warnings are different and we don't want
273	# the build to fail because of that.
274	myconf+=" -Dwerror="
275
276	# Avoid CFLAGS problems, bug #352457, bug #390147.
277	if ! use custom-cflags; then
278	replace-flags "-Os" "-O2"
279	strip-flags
280	fi
281
282	egyp_chromium ${myconf} \|\| die
283	}
284
285	src_compile() {
286	local test_targets
287	for x in base cacheinvalidation crypto \
288	googleurl gpu media net printing sql; do
289	test_targets+=" ${x}_unittests"
290	done
291
292	local make_targets="chrome chromedriver"
293	if ! use selinux; then
294	make_targets+=" chrome_sandbox"
295	fi
296	if use test; then
297	make_targets+=$test_targets
298	fi
299
300	# See bug #410883 for more info about the .host mess.
301	emake ${make_targets} BUILDTYPE=Release V=1 \
302	CC.host="$(tc-getCC)" CFLAGS.host="${CFLAGS}" \
303	CXX.host="$(tc-getCXX)" CXXFLAGS.host="${CXXFLAGS}" \
304	LINK.host="$(tc-getCXX)" LDFLAGS.host="${LDFLAGS}" \
305	AR.host="$(tc-getAR)" \|\| die
306
307	pax-mark m out/Release/chrome
308	if use test; then
309	for x in $test_targets; do
310	pax-mark m out/Release/${x}
311	done
312	fi
313	}
314
315	src_test() {
316	# For more info see bug #350349.
317	local mylocale='en_US.utf8'
318	if ! locale -a \| grep -q "$mylocale"; then
319	eerror "${PN} requires ${mylocale} locale for tests"
320	eerror "Please read the following guides for more information:"
321	eerror " http://www.gentoo.org/doc/en/guide-localization.xml"
322	eerror " http://www.gentoo.org/doc/en/utf-8.xml"
323	die "locale ${mylocale} is not supported"
324	fi
325
326	# For more info see bug #370957.
327	if [[ $UID -eq 0 ]]; then
328	die "Tests must be run as non-root. Please use FEATURES=userpriv."
329	fi
330
331	runtest() {
332	local cmd=$1
333	shift
334	einfo "${cmd}" "$@"
335	LC_ALL="${mylocale}" VIRTUALX_COMMAND="${cmd}" virtualmake "$@"
336	}
337
338	# ICUStringConversionsTest: bug #350347.
339	# MessagePumpLibeventTest: bug #398501.
340	runtest out/Release/base_unittests \
341	'--gtest_filter=-ICUStringConversionsTest.:MessagePumpLibeventTest.'
342
343	runtest out/Release/cacheinvalidation_unittests
344	runtest out/Release/crypto_unittests
345	runtest out/Release/googleurl_unittests
346	runtest out/Release/gpu_unittests
347	runtest out/Release/media_unittests
348
349	# NetUtilTest: bug #361885.
350	# DnsConfigServiceTest.GetSystemConfig: bug #394883.
351	# CertDatabaseNSSTest.ImportServerCert_SelfSigned: bug #399269.
352	runtest out/Release/net_unittests \
353	'--gtest_filter=-NetUtilTest.IDNToUnicode:NetUtilTest.FormatUrl:DnsConfigServiceTest.GetSystemConfig:CertDatabaseNSSTest.ImportServerCert_SelfSigned:URLFetcher*'
354
355	runtest out/Release/printing_unittests
356	runtest out/Release/sql_unittests
357	}
358
359	src_install() {
360	exeinto "${CHROMIUM_HOME}"
361	doexe out/Release/chrome \|\| die
362
363	if ! use selinux; then
364	doexe out/Release/chrome_sandbox \|\| die
365	fperms 4755 "${CHROMIUM_HOME}/chrome_sandbox"
366	fi
367
368	doexe out/Release/chromedriver \|\| die
369
370	doexe out/Release/nacl_helper{,_bootstrap} \|\| die
371	insinto "${CHROMIUM_HOME}"
372	doins out/Release/nacl_irt_*.nexe \|\| die
373	doins out/Release/libppGoogleNaClPluginChrome.so \|\| die
374
375	newexe "${FILESDIR}"/chromium-launcher-r2.sh chromium-launcher.sh \|\| die
376	if [[ "${CHROMIUM_SUFFIX}" != "" ]]; then
377	sed "s:chromium-browser:chromium-browser${CHROMIUM_SUFFIX}:g" \
378	-i "${ED}"/"${CHROMIUM_HOME}"/chromium-launcher.sh \|\| die
379	sed "s:chromium.desktop:chromium${CHROMIUM_SUFFIX}.desktop:g" \
380	-i "${ED}"/"${CHROMIUM_HOME}"/chromium-launcher.sh \|\| die
381	sed "s:plugins:plugins --user-data-dir=\${HOME}/.config/chromium${CHROMIUM_SUFFIX}:" \
382	-i "${ED}"/"${CHROMIUM_HOME}"/chromium-launcher.sh \|\| die
383	fi
384
385	# It is important that we name the target "chromium-browser",
386	# xdg-utils expect it; bug #355517.
387	dosym "${CHROMIUM_HOME}/chromium-launcher.sh" /usr/bin/chromium-browser${CHROMIUM_SUFFIX} \|\| die
388	# keep the old symlink around for consistency
389	dosym "${CHROMIUM_HOME}/chromium-launcher.sh" /usr/bin/chromium${CHROMIUM_SUFFIX} \|\| die
390
391	# Allow users to override command-line options, bug #357629.
392	dodir /etc/chromium \|\| die
393	insinto /etc/chromium
394	newins "${FILESDIR}/chromium.default" "default" \|\| die
395
396	pushd out/Release/locales > /dev/null \|\| die
397	chromium_remove_language_paks
398	popd
399
400	insinto "${CHROMIUM_HOME}"
401	doins out/Release/*.pak \|\| die
402
403	doins -r out/Release/locales \|\| die
404	doins -r out/Release/resources \|\| die
405
406	newman out/Release/chrome.1 chromium${CHROMIUM_SUFFIX}.1 \|\| die
407	newman out/Release/chrome.1 chromium-browser${CHROMIUM_SUFFIX}.1 \|\| die
408
409	doexe out/Release/libffmpegsumo.so \|\| die
410
411	# Install icons and desktop entry.
412	local branding size
413	for size in 16 22 24 32 48 64 128 256 ; do
414	case ${size} in
415	16\|32) branding="chrome/app/theme/default_100_percent/chromium" ;;
416	*) branding="chrome/app/theme/chromium" ;;
417	esac
418	newicon -s ${size} "${branding}/product_logo_${size}.png" \
419	chromium-browser${CHROMIUM_SUFFIX}.png
420	done
421
422	local mime_types="text/html;text/xml;application/xhtml+xml;"
423	mime_types+="x-scheme-handler/http;x-scheme-handler/https;" # bug #360797
424	mime_types+="x-scheme-handler/ftp;" # bug #412185
425	mime_types+="x-scheme-handler/mailto;x-scheme-handler/webcal;" # bug #416393
426	make_desktop_entry \
427	chromium-browser${CHROMIUM_SUFFIX} \
428	"Chromium${CHROMIUM_SUFFIX}" \
429	chromium-browser${CHROMIUM_SUFFIX} \
430	"Network;WebBrowser" \
431	"MimeType=${mime_types}\nStartupWMClass=chromium-browser"
432	sed -e "/^Exec/s/$/ %U/" -i "${ED}"/usr/share/applications/*.desktop \|\| die
433
434	# Install GNOME default application entry (bug #303100).
435	if use gnome; then
436	dodir /usr/share/gnome-control-center/default-apps \|\| die
437	insinto /usr/share/gnome-control-center/default-apps
438	newins "${FILESDIR}"/chromium-browser.xml chromium-browser${CHROMIUM_SUFFIX}.xml \|\| die
439	if [[ "${CHROMIUM_SUFFIX}" != "" ]]; then
440	sed "s:chromium-browser:chromium-browser${CHROMIUM_SUFFIX}:g" -i \
441	"${ED}"/usr/share/gnome-control-center/default-apps/chromium-browser${CHROMIUM_SUFFIX}.xml
442	fi
443	fi
444	}