www-client/chromium/chromium-22.0.1229.2.ebuild

# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/www-client/chromium/chromium-22.0.1229.2.ebuild,v 1.1 2012/08/10 03:30:56 floppym Exp $

EAPI="4"
PYTHON_DEPEND="2:2.6"

CHROMIUM_LANGS="am ar bg bn ca cs da de el en_GB es es_LA et fa fi fil fr gu he
        hi hr hu id it ja kn ko lt lv ml mr ms nb nl pl pt_BR pt_PT ro ru sk sl sr
        sv sw ta te th tr uk vi zh_CN zh_TW"

inherit chromium eutils flag-o-matic multilib \
        pax-utils portability python toolchain-funcs versionator virtualx

DESCRIPTION="Open-source version of Google Chrome web browser"
HOMEPAGE="http://chromium.org/"
SRC_URI="http://commondatastorage.googleapis.com/chromium-browser-official/${P}.tar.bz2"

LICENSE="BSD"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="bindist cups gnome gnome-keyring kerberos pulseaudio selinux"

RDEPEND="app-arch/bzip2
        cups? (
                dev-libs/libgcrypt
                >=net-print/cups-1.3.11
        )
        >=dev-lang/v8-3.11.10.6
        dev-libs/dbus-glib
        dev-libs/elfutils
        dev-libs/expat
        >=dev-libs/icu-49.1.1-r1
        >=dev-libs/libevent-1.4.13
        dev-libs/libxml2[icu]
        dev-libs/libxslt
        >=dev-libs/nss-3.12.3
        gnome? ( >=gnome-base/gconf-2.24.0 )
        gnome-keyring? ( >=gnome-base/gnome-keyring-2.28.2 )
        >=media-libs/alsa-lib-1.0.19
        media-libs/flac
        >=media-libs/libjpeg-turbo-1.2.0-r1
        media-libs/libpng
        media-libs/speex
        pulseaudio? ( media-sound/pulseaudio )
        sys-fs/udev
        sys-libs/zlib
        virtual/libusb:1
        x11-libs/gtk+:2
        x11-libs/libXinerama
        x11-libs/libXScrnSaver
        x11-libs/libXtst
        kerberos? ( virtual/krb5 )
        selinux? ( sys-libs/libselinux )"
DEPEND="${RDEPEND}
        >=dev-lang/nacl-toolchain-newlib-0_p9093
        dev-lang/perl
        dev-lang/yasm
        dev-python/ply
        dev-python/simplejson
        >=dev-util/gperf-3.0.3
        >=sys-devel/bison-2.4.3
        sys-devel/flex
        >=sys-devel/make-3.81-r2
        virtual/pkgconfig
        test? (
                dev-python/pyftpdlib
        )"
RDEPEND+="
        !=www-client/chromium-9999
        x11-misc/xdg-utils
        virtual/ttf-fonts"

if ! has chromium_pkg_die ${EBUILD_DEATH_HOOKS}; then
        EBUILD_DEATH_HOOKS+=" chromium_pkg_die";
fi

pkg_setup() {
        if [[ "${SLOT}" == "0" ]]; then
                CHROMIUM_SUFFIX=""
        else
                CHROMIUM_SUFFIX="-${SLOT}"
        fi
        CHROMIUM_HOME="/usr/$(get_libdir)/chromium-browser${CHROMIUM_SUFFIX}"

        # Make sure the build system will use the right tools, bug #340795.
        tc-export AR CC CXX RANLIB

        # Make sure the build system will use the right python, bug #344367.
        python_set_active_version 2
        python_pkg_setup

        if ! use selinux; then
                chromium_suid_sandbox_check_kernel_config
        fi

        if use bindist; then
                elog "bindist enabled: H.264 video support will be disabled."
        else
                elog "bindist disabled: Resulting binaries may not be legal to re-distribute."
        fi
}

src_prepare() {
        ln -s /usr/$(get_libdir)/nacl-toolchain-newlib \
                native_client/toolchain/linux_x86_newlib || die

        # zlib-1.2.5.1-r1 renames the OF macro in zconf.h, bug 383371.
        sed -i '1i#define OF(x) x' \
                third_party/zlib/contrib/minizip/{ioapi,{,un}zip}.h || die

        # Fix build without NaCl glibc toolchain.
        epatch "${FILESDIR}/${PN}-ppapi-r0.patch"

        epatch_user

        # Remove most bundled libraries. Some are still needed.
        find third_party -type f \! -iname '*.gyp*' \
                \! -path 'third_party/WebKit/*' \
                \! -path 'third_party/angle/*' \
                \! -path 'third_party/cacheinvalidation/*' \
                \! -path 'third_party/cld/*' \
                \! -path 'third_party/ffmpeg/*' \
                \! -path 'third_party/flac/flac.h' \
                \! -path 'third_party/gpsd/*' \
                \! -path 'third_party/harfbuzz/*' \
                \! -path 'third_party/hunspell/*' \
                \! -path 'third_party/hyphen/*' \
                \! -path 'third_party/iccjpeg/*' \
                \! -path 'third_party/jsoncpp/*' \
                \! -path 'third_party/khronos/*' \
                \! -path 'third_party/launchpad_translations/*' \
                \! -path 'third_party/leveldatabase/*' \
                \! -path 'third_party/libjingle/*' \
                \! -path 'third_party/libphonenumber/*' \
                \! -path 'third_party/libsrtp/*' \
                \! -path 'third_party/libusb/libusb.h' \
                \! -path 'third_party/libva/*' \
                \! -path 'third_party/libvpx/*' \
                \! -path 'third_party/libwebp/*' \
                \! -path 'third_party/libxml/chromium/*' \
                \! -path 'third_party/libXNVCtrl/*' \
                \! -path 'third_party/libyuv/*' \
                \! -path 'third_party/lss/*' \
                \! -path 'third_party/mesa/*' \
                \! -path 'third_party/modp_b64/*' \
                \! -path 'third_party/mongoose/*' \
                \! -path 'third_party/npapi/*' \
                \! -path 'third_party/openmax/*' \
                \! -path 'third_party/ots/*' \
                \! -path 'third_party/protobuf/*' \
                \! -path 'third_party/qcms/*' \
                \! -path 'third_party/re2/*' \
                \! -path 'third_party/scons-2.0.1/*' \
                \! -path 'third_party/sfntly/*' \
                \! -path 'third_party/skia/*' \
                \! -path 'third_party/smhasher/*' \
                \! -path 'third_party/speex/speex.h' \
                \! -path 'third_party/sqlite/*' \
                \! -path 'third_party/tlslite/*' \
                \! -path 'third_party/trace-viewer/*' \
                \! -path 'third_party/undoview/*' \
                \! -path 'third_party/v8-i18n/*' \
                \! -path 'third_party/webdriver/*' \
                \! -path 'third_party/webgl_conformance/*' \
                \! -path 'third_party/webrtc/*' \
                \! -path 'third_party/zlib/contrib/minizip/*' \
                -delete || die

        local v8_bundled="$(chromium_bundled_v8_version)"
        local v8_installed="$(chromium_installed_v8_version)"
        einfo "V8 version: bundled - ${v8_bundled}; installed - ${v8_installed}"

        # Remove bundled v8.
        find v8 -type f \! -iname '*.gyp*' -delete || die

        # The implementation files include v8 headers with full path,
        # like #include "v8/include/v8.h". Make sure the system headers
        # will be used.
        # TODO: find a solution that can be upstreamed.
        rmdir v8/include || die
        ln -s /usr/include v8/include || die

        # Make sure the build system will use the right python, bug #344367.
        # Only convert directories that need it, to save time.
        python_convert_shebangs -q -r 2 build tools
}

src_configure() {
        local myconf=""

        # Never tell the build system to "enable" SSE2, it has a few unexpected
        # additions, bug #336871.
        myconf+=" -Ddisable_sse2=1"

        # Disable tcmalloc, it causes problems with e.g. NVIDIA
        # drivers, bug #413637.
        myconf+=" -Dlinux_use_tcmalloc=0"

        # Disable glibc Native Client toolchain, we don't need it (bug #417019).
        myconf+=" -Ddisable_glibc=1"

        # Make it possible to remove third_party/adobe.
        echo > "${T}/flapper_version.h" || die
        myconf+=" -Dflapper_version_h_file=${T}/flapper_version.h"

        # Use system-provided libraries.
        # TODO: use_system_ffmpeg
        # TODO: use_system_hunspell (upstream changes needed).
        # TODO: use_system_ssl (http://crbug.com/58087).
        # TODO: use_system_sqlite (http://crbug.com/22208).
        # TODO: use_system_vpx
        # TODO: use_system_webp (https://chromiumcodereview.appspot.com/10496016
        #       needs to become part of webp release)
        myconf+="
                -Duse_system_bzip2=1
                -Duse_system_flac=1
                -Duse_system_icu=1
                -Duse_system_libevent=1
                -Duse_system_libjpeg=1
                -Duse_system_libpng=1
                -Duse_system_libusb=1
                -Duse_system_libxml=1
                -Duse_system_speex=1
                -Duse_system_v8=1
                -Duse_system_xdg_utils=1
                -Duse_system_yasm=1
                -Duse_system_zlib=1"

        # Optional dependencies.
        # TODO: linux_link_kerberos, bug #381289.
        myconf+="
                $(gyp_use cups)
                $(gyp_use gnome use_gconf)
                $(gyp_use gnome-keyring use_gnome_keyring)
                $(gyp_use gnome-keyring linux_link_gnome_keyring)
                $(gyp_use kerberos)
                $(gyp_use pulseaudio)
                $(gyp_use selinux selinux)"

        if ! use selinux; then
                # Enable SUID sandbox.
                myconf+="
                        -Dlinux_sandbox_path=${CHROMIUM_HOME}/chrome_sandbox
                        -Dlinux_sandbox_chrome_path=${CHROMIUM_HOME}/chrome"
        fi

        # Never use bundled gold binary. Disable gold linker flags for now.
        myconf+="
                -Dlinux_use_gold_binary=0
                -Dlinux_use_gold_flags=0"

        if ! use bindist; then
                # Enable H.624 support in bundled ffmpeg.
                myconf+=" -Dproprietary_codecs=1 -Dffmpeg_branding=Chrome"
        fi

        local myarch="$(tc-arch)"
        if [[ $myarch = amd64 ]] ; then
                myconf+=" -Dtarget_arch=x64"
        elif [[ $myarch = x86 ]] ; then
                myconf+=" -Dtarget_arch=ia32"
        else
                die "Failed to determine target arch, got '$myarch'."
        fi

        # Make sure that -Werror doesn't get added to CFLAGS by the build system.
        # Depending on GCC version the warnings are different and we don't want
        # the build to fail because of that.
        myconf+=" -Dwerror="

        # Avoid CFLAGS problems, bug #352457, bug #390147.
        if ! use custom-cflags; then
                replace-flags "-Os" "-O2"
                strip-flags
        fi

        egyp_chromium ${myconf} || die
}

src_compile() {
        local test_targets
        for x in base cacheinvalidation crypto \
                googleurl gpu media net printing sql; do
                test_targets+=" ${x}_unittests"
        done

        local make_targets="chrome chromedriver"
        if ! use selinux; then
                make_targets+=" chrome_sandbox"
        fi
        if use test; then
                make_targets+=$test_targets
        fi

        # See bug #410883 for more info about the .host mess.
        emake ${make_targets} BUILDTYPE=Release V=1 \
                CC.host="$(tc-getCC)" CFLAGS.host="${CFLAGS}" \
                CXX.host="$(tc-getCXX)" CXXFLAGS.host="${CXXFLAGS}" \
                LINK.host="$(tc-getCXX)" LDFLAGS.host="${LDFLAGS}" \
                AR.host="$(tc-getAR)" || die

        pax-mark m out/Release/chrome
        if use test; then
                for x in $test_targets; do
                        pax-mark m out/Release/${x}
                done
        fi
}

src_test() {
        # For more info see bug #350349.
        local mylocale='en_US.utf8'
        if ! locale -a | grep -q "$mylocale"; then
                eerror "${PN} requires ${mylocale} locale for tests"
                eerror "Please read the following guides for more information:"
                eerror "  http://www.gentoo.org/doc/en/guide-localization.xml"
                eerror "  http://www.gentoo.org/doc/en/utf-8.xml"
                die "locale ${mylocale} is not supported"
        fi

        # For more info see bug #370957.
        if [[ $UID -eq 0 ]]; then
                die "Tests must be run as non-root. Please use FEATURES=userpriv."
        fi

        runtest() {
                local cmd=$1
                shift
                einfo "${cmd}" "$@"
                LC_ALL="${mylocale}" VIRTUALX_COMMAND="${cmd}" virtualmake "$@"
        }

        # ICUStringConversionsTest: bug #350347.
        # MessagePumpLibeventTest: bug #398501.
        runtest out/Release/base_unittests \
                '--gtest_filter=-ICUStringConversionsTest.*:MessagePumpLibeventTest.*'

        runtest out/Release/cacheinvalidation_unittests
        runtest out/Release/crypto_unittests
        runtest out/Release/googleurl_unittests
        runtest out/Release/gpu_unittests
        runtest out/Release/media_unittests

        # NetUtilTest: bug #361885.
        # DnsConfigServiceTest.GetSystemConfig: bug #394883.
        # CertDatabaseNSSTest.ImportServerCert_SelfSigned: bug #399269.
        runtest out/Release/net_unittests \
                '--gtest_filter=-NetUtilTest.IDNToUnicode*:NetUtilTest.FormatUrl*:DnsConfigServiceTest.GetSystemConfig:CertDatabaseNSSTest.ImportServerCert_SelfSigned:URLFetcher*'

        runtest out/Release/printing_unittests
        runtest out/Release/sql_unittests
}

src_install() {
        exeinto "${CHROMIUM_HOME}"
        doexe out/Release/chrome || die

        if ! use selinux; then
                doexe out/Release/chrome_sandbox || die
                fperms 4755 "${CHROMIUM_HOME}/chrome_sandbox"
        fi

        doexe out/Release/chromedriver || die

        doexe out/Release/nacl_helper{,_bootstrap} || die
        insinto "${CHROMIUM_HOME}"
        doins out/Release/nacl_irt_*.nexe || die
        doins out/Release/libppGoogleNaClPluginChrome.so || die

        newexe "${FILESDIR}"/chromium-launcher-r2.sh chromium-launcher.sh || die
        if [[ "${CHROMIUM_SUFFIX}" != "" ]]; then
                sed "s:chromium-browser:chromium-browser${CHROMIUM_SUFFIX}:g" \
                        -i "${ED}"/"${CHROMIUM_HOME}"/chromium-launcher.sh || die
                sed "s:chromium.desktop:chromium${CHROMIUM_SUFFIX}.desktop:g" \
                        -i "${ED}"/"${CHROMIUM_HOME}"/chromium-launcher.sh || die
                sed "s:plugins:plugins --user-data-dir=\${HOME}/.config/chromium${CHROMIUM_SUFFIX}:" \
                        -i "${ED}"/"${CHROMIUM_HOME}"/chromium-launcher.sh || die
        fi

        # It is important that we name the target "chromium-browser",
        # xdg-utils expect it; bug #355517.
        dosym "${CHROMIUM_HOME}/chromium-launcher.sh" /usr/bin/chromium-browser${CHROMIUM_SUFFIX} || die
        # keep the old symlink around for consistency
        dosym "${CHROMIUM_HOME}/chromium-launcher.sh" /usr/bin/chromium${CHROMIUM_SUFFIX} || die

        # Allow users to override command-line options, bug #357629.
        dodir /etc/chromium || die
        insinto /etc/chromium
        newins "${FILESDIR}/chromium.default" "default" || die

        pushd out/Release/locales > /dev/null || die
        chromium_remove_language_paks
        popd

        insinto "${CHROMIUM_HOME}"
        doins out/Release/*.pak || die

        doins -r out/Release/locales || die
        doins -r out/Release/resources || die

        newman out/Release/chrome.1 chromium${CHROMIUM_SUFFIX}.1 || die
        newman out/Release/chrome.1 chromium-browser${CHROMIUM_SUFFIX}.1 || die

        doexe out/Release/libffmpegsumo.so || die

        # Install icons and desktop entry.
        local branding size
        for size in 16 22 24 32 48 64 128 256 ; do
                case ${size} in
                        16|32) branding="chrome/app/theme/default_100_percent/chromium" ;;
                                *) branding="chrome/app/theme/chromium" ;;
                esac
                newicon -s ${size} "${branding}/product_logo_${size}.png" \
                        chromium-browser${CHROMIUM_SUFFIX}.png
        done

        local mime_types="text/html;text/xml;application/xhtml+xml;"
        mime_types+="x-scheme-handler/http;x-scheme-handler/https;" # bug #360797
        mime_types+="x-scheme-handler/ftp;" # bug #412185
        mime_types+="x-scheme-handler/mailto;x-scheme-handler/webcal;" # bug #416393
        make_desktop_entry \
                chromium-browser${CHROMIUM_SUFFIX} \
                "Chromium${CHROMIUM_SUFFIX}" \
                chromium-browser${CHROMIUM_SUFFIX} \
                "Network;WebBrowser" \
                "MimeType=${mime_types}\nStartupWMClass=chromium-browser"
        sed -e "/^Exec/s/$/ %U/" -i "${ED}"/usr/share/applications/*.desktop || die

        # Install GNOME default application entry (bug #303100).
        if use gnome; then
                dodir /usr/share/gnome-control-center/default-apps || die
                insinto /usr/share/gnome-control-center/default-apps
                newins "${FILESDIR}"/chromium-browser.xml chromium-browser${CHROMIUM_SUFFIX}.xml || die
                if [[ "${CHROMIUM_SUFFIX}" != "" ]]; then
                        sed "s:chromium-browser:chromium-browser${CHROMIUM_SUFFIX}:g" -i \
                                "${ED}"/usr/share/gnome-control-center/default-apps/chromium-browser${CHROMIUM_SUFFIX}.xml
                fi
        fi
}
1	# Copyright 1999-2012 Gentoo Foundation
2	# Distributed under the terms of the GNU General Public License v2
3	# $Header: /var/cvsroot/gentoo-x86/www-client/chromium/chromium-22.0.1229.2.ebuild,v 1.1 2012/08/10 03:30:56 floppym Exp $
4
5	EAPI="4"
6	PYTHON_DEPEND="2:2.6"
7
8	CHROMIUM_LANGS="am ar bg bn ca cs da de el en_GB es es_LA et fa fi fil fr gu he
9	hi hr hu id it ja kn ko lt lv ml mr ms nb nl pl pt_BR pt_PT ro ru sk sl sr
10	sv sw ta te th tr uk vi zh_CN zh_TW"
11
12	inherit chromium eutils flag-o-matic multilib \
13	pax-utils portability python toolchain-funcs versionator virtualx
14
15	DESCRIPTION="Open-source version of Google Chrome web browser"
16	HOMEPAGE="http://chromium.org/"
17	SRC_URI="http://commondatastorage.googleapis.com/chromium-browser-official/${P}.tar.bz2"
18
19	LICENSE="BSD"
20	SLOT="0"
21	KEYWORDS="~amd64 ~x86"
22	IUSE="bindist cups gnome gnome-keyring kerberos pulseaudio selinux"
23
24	RDEPEND="app-arch/bzip2
25	cups? (
26	dev-libs/libgcrypt
27	>=net-print/cups-1.3.11
28	)
29	>=dev-lang/v8-3.11.10.6
30	dev-libs/dbus-glib
31	dev-libs/elfutils
32	dev-libs/expat
33	>=dev-libs/icu-49.1.1-r1
34	>=dev-libs/libevent-1.4.13
35	dev-libs/libxml2[icu]
36	dev-libs/libxslt
37	>=dev-libs/nss-3.12.3
38	gnome? ( >=gnome-base/gconf-2.24.0 )
39	gnome-keyring? ( >=gnome-base/gnome-keyring-2.28.2 )
40	>=media-libs/alsa-lib-1.0.19
41	media-libs/flac
42	>=media-libs/libjpeg-turbo-1.2.0-r1
43	media-libs/libpng
44	media-libs/speex
45	pulseaudio? ( media-sound/pulseaudio )
46	sys-fs/udev
47	sys-libs/zlib
48	virtual/libusb:1
49	x11-libs/gtk+:2
50	x11-libs/libXinerama
51	x11-libs/libXScrnSaver
52	x11-libs/libXtst
53	kerberos? ( virtual/krb5 )
54	selinux? ( sys-libs/libselinux )"
55	DEPEND="${RDEPEND}
56	>=dev-lang/nacl-toolchain-newlib-0_p9093
57	dev-lang/perl
58	dev-lang/yasm
59	dev-python/ply
60	dev-python/simplejson
61	>=dev-util/gperf-3.0.3
62	>=sys-devel/bison-2.4.3
63	sys-devel/flex
64	>=sys-devel/make-3.81-r2
65	virtual/pkgconfig
66	test? (
67	dev-python/pyftpdlib
68	)"
69	RDEPEND+="
70	!=www-client/chromium-9999
71	x11-misc/xdg-utils
72	virtual/ttf-fonts"
73
74	if ! has chromium_pkg_die ${EBUILD_DEATH_HOOKS}; then
75	EBUILD_DEATH_HOOKS+=" chromium_pkg_die";
76	fi
77
78	pkg_setup() {
79	if [[ "${SLOT}" == "0" ]]; then
80	CHROMIUM_SUFFIX=""
81	else
82	CHROMIUM_SUFFIX="-${SLOT}"
83	fi
84	CHROMIUM_HOME="/usr/$(get_libdir)/chromium-browser${CHROMIUM_SUFFIX}"
85
86	# Make sure the build system will use the right tools, bug #340795.
87	tc-export AR CC CXX RANLIB
88
89	# Make sure the build system will use the right python, bug #344367.
90	python_set_active_version 2
91	python_pkg_setup
92
93	if ! use selinux; then
94	chromium_suid_sandbox_check_kernel_config
95	fi
96
97	if use bindist; then
98	elog "bindist enabled: H.264 video support will be disabled."
99	else
100	elog "bindist disabled: Resulting binaries may not be legal to re-distribute."
101	fi
102	}
103
104	src_prepare() {
105	ln -s /usr/$(get_libdir)/nacl-toolchain-newlib \
106	native_client/toolchain/linux_x86_newlib \|\| die
107
108	# zlib-1.2.5.1-r1 renames the OF macro in zconf.h, bug 383371.
109	sed -i '1i#define OF(x) x' \
110	third_party/zlib/contrib/minizip/{ioapi,{,un}zip}.h \|\| die
111
112	# Fix build without NaCl glibc toolchain.
113	epatch "${FILESDIR}/${PN}-ppapi-r0.patch"
114
115	epatch_user
116
117	# Remove most bundled libraries. Some are still needed.
118	find third_party -type f \! -iname '.gyp' \
119	\! -path 'third_party/WebKit/*' \
120	\! -path 'third_party/angle/*' \
121	\! -path 'third_party/cacheinvalidation/*' \
122	\! -path 'third_party/cld/*' \
123	\! -path 'third_party/ffmpeg/*' \
124	\! -path 'third_party/flac/flac.h' \
125	\! -path 'third_party/gpsd/*' \
126	\! -path 'third_party/harfbuzz/*' \
127	\! -path 'third_party/hunspell/*' \
128	\! -path 'third_party/hyphen/*' \
129	\! -path 'third_party/iccjpeg/*' \
130	\! -path 'third_party/jsoncpp/*' \
131	\! -path 'third_party/khronos/*' \
132	\! -path 'third_party/launchpad_translations/*' \
133	\! -path 'third_party/leveldatabase/*' \
134	\! -path 'third_party/libjingle/*' \
135	\! -path 'third_party/libphonenumber/*' \
136	\! -path 'third_party/libsrtp/*' \
137	\! -path 'third_party/libusb/libusb.h' \
138	\! -path 'third_party/libva/*' \
139	\! -path 'third_party/libvpx/*' \
140	\! -path 'third_party/libwebp/*' \
141	\! -path 'third_party/libxml/chromium/*' \
142	\! -path 'third_party/libXNVCtrl/*' \
143	\! -path 'third_party/libyuv/*' \
144	\! -path 'third_party/lss/*' \
145	\! -path 'third_party/mesa/*' \
146	\! -path 'third_party/modp_b64/*' \
147	\! -path 'third_party/mongoose/*' \
148	\! -path 'third_party/npapi/*' \
149	\! -path 'third_party/openmax/*' \
150	\! -path 'third_party/ots/*' \
151	\! -path 'third_party/protobuf/*' \
152	\! -path 'third_party/qcms/*' \
153	\! -path 'third_party/re2/*' \
154	\! -path 'third_party/scons-2.0.1/*' \
155	\! -path 'third_party/sfntly/*' \
156	\! -path 'third_party/skia/*' \
157	\! -path 'third_party/smhasher/*' \
158	\! -path 'third_party/speex/speex.h' \
159	\! -path 'third_party/sqlite/*' \
160	\! -path 'third_party/tlslite/*' \
161	\! -path 'third_party/trace-viewer/*' \
162	\! -path 'third_party/undoview/*' \
163	\! -path 'third_party/v8-i18n/*' \
164	\! -path 'third_party/webdriver/*' \
165	\! -path 'third_party/webgl_conformance/*' \
166	\! -path 'third_party/webrtc/*' \
167	\! -path 'third_party/zlib/contrib/minizip/*' \
168	-delete \|\| die
169
170	local v8_bundled="$(chromium_bundled_v8_version)"
171	local v8_installed="$(chromium_installed_v8_version)"
172	einfo "V8 version: bundled - ${v8_bundled}; installed - ${v8_installed}"
173
174	# Remove bundled v8.
175	find v8 -type f \! -iname '.gyp' -delete \|\| die
176
177	# The implementation files include v8 headers with full path,
178	# like #include "v8/include/v8.h". Make sure the system headers
179	# will be used.
180	# TODO: find a solution that can be upstreamed.
181	rmdir v8/include \|\| die
182	ln -s /usr/include v8/include \|\| die
183
184	# Make sure the build system will use the right python, bug #344367.
185	# Only convert directories that need it, to save time.
186	python_convert_shebangs -q -r 2 build tools
187	}
188
189	src_configure() {
190	local myconf=""
191
192	# Never tell the build system to "enable" SSE2, it has a few unexpected
193	# additions, bug #336871.
194	myconf+=" -Ddisable_sse2=1"
195
196	# Disable tcmalloc, it causes problems with e.g. NVIDIA
197	# drivers, bug #413637.
198	myconf+=" -Dlinux_use_tcmalloc=0"
199
200	# Disable glibc Native Client toolchain, we don't need it (bug #417019).
201	myconf+=" -Ddisable_glibc=1"
202
203	# Make it possible to remove third_party/adobe.
204	echo > "${T}/flapper_version.h" \|\| die
205	myconf+=" -Dflapper_version_h_file=${T}/flapper_version.h"
206
207	# Use system-provided libraries.
208	# TODO: use_system_ffmpeg
209	# TODO: use_system_hunspell (upstream changes needed).
210	# TODO: use_system_ssl (http://crbug.com/58087).
211	# TODO: use_system_sqlite (http://crbug.com/22208).
212	# TODO: use_system_vpx
213	# TODO: use_system_webp (https://chromiumcodereview.appspot.com/10496016
214	# needs to become part of webp release)
215	myconf+="
216	-Duse_system_bzip2=1
217	-Duse_system_flac=1
218	-Duse_system_icu=1
219	-Duse_system_libevent=1
220	-Duse_system_libjpeg=1
221	-Duse_system_libpng=1
222	-Duse_system_libusb=1
223	-Duse_system_libxml=1
224	-Duse_system_speex=1
225	-Duse_system_v8=1
226	-Duse_system_xdg_utils=1
227	-Duse_system_yasm=1
228	-Duse_system_zlib=1"
229
230	# Optional dependencies.
231	# TODO: linux_link_kerberos, bug #381289.
232	myconf+="
233	$(gyp_use cups)
234	$(gyp_use gnome use_gconf)
235	$(gyp_use gnome-keyring use_gnome_keyring)
236	$(gyp_use gnome-keyring linux_link_gnome_keyring)
237	$(gyp_use kerberos)
238	$(gyp_use pulseaudio)
239	$(gyp_use selinux selinux)"
240
241	if ! use selinux; then
242	# Enable SUID sandbox.
243	myconf+="
244	-Dlinux_sandbox_path=${CHROMIUM_HOME}/chrome_sandbox
245	-Dlinux_sandbox_chrome_path=${CHROMIUM_HOME}/chrome"
246	fi
247
248	# Never use bundled gold binary. Disable gold linker flags for now.
249	myconf+="
250	-Dlinux_use_gold_binary=0
251	-Dlinux_use_gold_flags=0"
252
253	if ! use bindist; then
254	# Enable H.624 support in bundled ffmpeg.
255	myconf+=" -Dproprietary_codecs=1 -Dffmpeg_branding=Chrome"
256	fi
257
258	local myarch="$(tc-arch)"
259	if [[ $myarch = amd64 ]] ; then
260	myconf+=" -Dtarget_arch=x64"
261	elif [[ $myarch = x86 ]] ; then
262	myconf+=" -Dtarget_arch=ia32"
263	else
264	die "Failed to determine target arch, got '$myarch'."
265	fi
266
267	# Make sure that -Werror doesn't get added to CFLAGS by the build system.
268	# Depending on GCC version the warnings are different and we don't want
269	# the build to fail because of that.
270	myconf+=" -Dwerror="
271
272	# Avoid CFLAGS problems, bug #352457, bug #390147.
273	if ! use custom-cflags; then
274	replace-flags "-Os" "-O2"
275	strip-flags
276	fi
277
278	egyp_chromium ${myconf} \|\| die
279	}
280
281	src_compile() {
282	local test_targets
283	for x in base cacheinvalidation crypto \
284	googleurl gpu media net printing sql; do
285	test_targets+=" ${x}_unittests"
286	done
287
288	local make_targets="chrome chromedriver"
289	if ! use selinux; then
290	make_targets+=" chrome_sandbox"
291	fi
292	if use test; then
293	make_targets+=$test_targets
294	fi
295
296	# See bug #410883 for more info about the .host mess.
297	emake ${make_targets} BUILDTYPE=Release V=1 \
298	CC.host="$(tc-getCC)" CFLAGS.host="${CFLAGS}" \
299	CXX.host="$(tc-getCXX)" CXXFLAGS.host="${CXXFLAGS}" \
300	LINK.host="$(tc-getCXX)" LDFLAGS.host="${LDFLAGS}" \
301	AR.host="$(tc-getAR)" \|\| die
302
303	pax-mark m out/Release/chrome
304	if use test; then
305	for x in $test_targets; do
306	pax-mark m out/Release/${x}
307	done
308	fi
309	}
310
311	src_test() {
312	# For more info see bug #350349.
313	local mylocale='en_US.utf8'
314	if ! locale -a \| grep -q "$mylocale"; then
315	eerror "${PN} requires ${mylocale} locale for tests"
316	eerror "Please read the following guides for more information:"
317	eerror " http://www.gentoo.org/doc/en/guide-localization.xml"
318	eerror " http://www.gentoo.org/doc/en/utf-8.xml"
319	die "locale ${mylocale} is not supported"
320	fi
321
322	# For more info see bug #370957.
323	if [[ $UID -eq 0 ]]; then
324	die "Tests must be run as non-root. Please use FEATURES=userpriv."
325	fi
326
327	runtest() {
328	local cmd=$1
329	shift
330	einfo "${cmd}" "$@"
331	LC_ALL="${mylocale}" VIRTUALX_COMMAND="${cmd}" virtualmake "$@"
332	}
333
334	# ICUStringConversionsTest: bug #350347.
335	# MessagePumpLibeventTest: bug #398501.
336	runtest out/Release/base_unittests \
337	'--gtest_filter=-ICUStringConversionsTest.:MessagePumpLibeventTest.'
338
339	runtest out/Release/cacheinvalidation_unittests
340	runtest out/Release/crypto_unittests
341	runtest out/Release/googleurl_unittests
342	runtest out/Release/gpu_unittests
343	runtest out/Release/media_unittests
344
345	# NetUtilTest: bug #361885.
346	# DnsConfigServiceTest.GetSystemConfig: bug #394883.
347	# CertDatabaseNSSTest.ImportServerCert_SelfSigned: bug #399269.
348	runtest out/Release/net_unittests \
349	'--gtest_filter=-NetUtilTest.IDNToUnicode:NetUtilTest.FormatUrl:DnsConfigServiceTest.GetSystemConfig:CertDatabaseNSSTest.ImportServerCert_SelfSigned:URLFetcher*'
350
351	runtest out/Release/printing_unittests
352	runtest out/Release/sql_unittests
353	}
354
355	src_install() {
356	exeinto "${CHROMIUM_HOME}"
357	doexe out/Release/chrome \|\| die
358
359	if ! use selinux; then
360	doexe out/Release/chrome_sandbox \|\| die
361	fperms 4755 "${CHROMIUM_HOME}/chrome_sandbox"
362	fi
363
364	doexe out/Release/chromedriver \|\| die
365
366	doexe out/Release/nacl_helper{,_bootstrap} \|\| die
367	insinto "${CHROMIUM_HOME}"
368	doins out/Release/nacl_irt_*.nexe \|\| die
369	doins out/Release/libppGoogleNaClPluginChrome.so \|\| die
370
371	newexe "${FILESDIR}"/chromium-launcher-r2.sh chromium-launcher.sh \|\| die
372	if [[ "${CHROMIUM_SUFFIX}" != "" ]]; then
373	sed "s:chromium-browser:chromium-browser${CHROMIUM_SUFFIX}:g" \
374	-i "${ED}"/"${CHROMIUM_HOME}"/chromium-launcher.sh \|\| die
375	sed "s:chromium.desktop:chromium${CHROMIUM_SUFFIX}.desktop:g" \
376	-i "${ED}"/"${CHROMIUM_HOME}"/chromium-launcher.sh \|\| die
377	sed "s:plugins:plugins --user-data-dir=\${HOME}/.config/chromium${CHROMIUM_SUFFIX}:" \
378	-i "${ED}"/"${CHROMIUM_HOME}"/chromium-launcher.sh \|\| die
379	fi
380
381	# It is important that we name the target "chromium-browser",
382	# xdg-utils expect it; bug #355517.
383	dosym "${CHROMIUM_HOME}/chromium-launcher.sh" /usr/bin/chromium-browser${CHROMIUM_SUFFIX} \|\| die
384	# keep the old symlink around for consistency
385	dosym "${CHROMIUM_HOME}/chromium-launcher.sh" /usr/bin/chromium${CHROMIUM_SUFFIX} \|\| die
386
387	# Allow users to override command-line options, bug #357629.
388	dodir /etc/chromium \|\| die
389	insinto /etc/chromium
390	newins "${FILESDIR}/chromium.default" "default" \|\| die
391
392	pushd out/Release/locales > /dev/null \|\| die
393	chromium_remove_language_paks
394	popd
395
396	insinto "${CHROMIUM_HOME}"
397	doins out/Release/*.pak \|\| die
398
399	doins -r out/Release/locales \|\| die
400	doins -r out/Release/resources \|\| die
401
402	newman out/Release/chrome.1 chromium${CHROMIUM_SUFFIX}.1 \|\| die
403	newman out/Release/chrome.1 chromium-browser${CHROMIUM_SUFFIX}.1 \|\| die
404
405	doexe out/Release/libffmpegsumo.so \|\| die
406
407	# Install icons and desktop entry.
408	local branding size
409	for size in 16 22 24 32 48 64 128 256 ; do
410	case ${size} in
411	16\|32) branding="chrome/app/theme/default_100_percent/chromium" ;;
412	*) branding="chrome/app/theme/chromium" ;;
413	esac
414	newicon -s ${size} "${branding}/product_logo_${size}.png" \
415	chromium-browser${CHROMIUM_SUFFIX}.png
416	done
417
418	local mime_types="text/html;text/xml;application/xhtml+xml;"
419	mime_types+="x-scheme-handler/http;x-scheme-handler/https;" # bug #360797
420	mime_types+="x-scheme-handler/ftp;" # bug #412185
421	mime_types+="x-scheme-handler/mailto;x-scheme-handler/webcal;" # bug #416393
422	make_desktop_entry \
423	chromium-browser${CHROMIUM_SUFFIX} \
424	"Chromium${CHROMIUM_SUFFIX}" \
425	chromium-browser${CHROMIUM_SUFFIX} \
426	"Network;WebBrowser" \
427	"MimeType=${mime_types}\nStartupWMClass=chromium-browser"
428	sed -e "/^Exec/s/$/ %U/" -i "${ED}"/usr/share/applications/*.desktop \|\| die
429
430	# Install GNOME default application entry (bug #303100).
431	if use gnome; then
432	dodir /usr/share/gnome-control-center/default-apps \|\| die
433	insinto /usr/share/gnome-control-center/default-apps
434	newins "${FILESDIR}"/chromium-browser.xml chromium-browser${CHROMIUM_SUFFIX}.xml \|\| die
435	if [[ "${CHROMIUM_SUFFIX}" != "" ]]; then
436	sed "s:chromium-browser:chromium-browser${CHROMIUM_SUFFIX}:g" -i \
437	"${ED}"/usr/share/gnome-control-center/default-apps/chromium-browser${CHROMIUM_SUFFIX}.xml
438	fi
439	fi
440	}