www-client/chromium/chromium-9999-r1.ebuild

# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/www-client/chromium/chromium-9999-r1.ebuild,v 1.108 2012/05/05 19:06:26 phajdan.jr Exp $

EAPI="4"
PYTHON_DEPEND="2:2.6"

CHROMIUM_LANGS="am ar bg bn ca cs da de el en_GB es es_LA et fa fi fil fr gu he
        hi hr hu id it ja kn ko lt lv ml mr ms nb nl pl pt_BR pt_PT ro ru sk sl sr
        sv sw ta te th tr uk vi zh_CN zh_TW"

inherit chromium eutils flag-o-matic multilib \
        pax-utils portability python subversion toolchain-funcs versionator virtualx

DESCRIPTION="Open-source version of Google Chrome web browser"
HOMEPAGE="http://chromium.org/"
ESVN_REPO_URI="http://src.chromium.org/svn/trunk/src"

LICENSE="BSD"
SLOT="live"
KEYWORDS=""
IUSE="bindist cups gnome gnome-keyring kerberos pulseaudio selinux"

RDEPEND="app-arch/bzip2
        cups? (
                dev-libs/libgcrypt
                >=net-print/cups-1.3.11
        )
        >=dev-lang/v8-3.10.2.1
        dev-libs/dbus-glib
        dev-libs/elfutils
        >=dev-libs/icu-49.1.1-r1
        >=dev-libs/libevent-1.4.13
        dev-libs/libxml2[icu]
        dev-libs/libxslt
        >=dev-libs/nss-3.12.3
        gnome? ( >=gnome-base/gconf-2.24.0 )
        gnome-keyring? ( >=gnome-base/gnome-keyring-2.28.2 )
        >=media-libs/alsa-lib-1.0.19
        media-libs/flac
        >=media-libs/libjpeg-turbo-1.2.0-r1
        media-libs/libpng
        >=media-libs/libwebp-0.1.3
        media-libs/speex
        pulseaudio? ( media-sound/pulseaudio )
        sys-fs/udev
        sys-libs/zlib
        x11-libs/gtk+:2
        x11-libs/libXinerama
        x11-libs/libXScrnSaver
        x11-libs/libXtst
        kerberos? ( virtual/krb5 )
        selinux? ( sys-libs/libselinux )"
DEPEND="${RDEPEND}
        >=dev-lang/nacl-toolchain-newlib-0_p7311
        dev-lang/perl
        dev-lang/yasm
        dev-python/ply
        dev-python/simplejson
        >=dev-util/gperf-3.0.3
        >=sys-devel/bison-2.4.3
        sys-devel/flex
        >=sys-devel/make-3.81-r2
        virtual/pkgconfig
        test? (
                dev-python/pyftpdlib
        )"
RDEPEND+="
        !=www-client/chromium-9999
        x11-misc/xdg-utils
        virtual/ttf-fonts"

gclient_config() {
        einfo "gclient config -->"
        # Allow the user to keep their config if they know what they are doing.
        if ! grep -q KEEP .gclient; then
                cp -f "${FILESDIR}/dot-gclient" .gclient || die
        fi
        cat .gclient || die
}

gclient_sync() {
        einfo "gclient sync -->"
        [[ -n "${ESVN_UMASK}" ]] && eumask_push "${ESVN_UMASK}"
        # Only use a single job to prevent hangs.
        "${WORKDIR}/depot_tools/gclient" sync --nohooks --jobs=1 \
                --delete_unversioned_trees || die
        [[ -n "${ESVN_UMASK}" ]] && eumask_pop
}

gclient_runhooks() {
        # Run all hooks except gyp_chromium.
        einfo "gclient runhooks -->"
        cp src/DEPS src/DEPS.orig || die
        sed -e 's:"python", "src/build/gyp_chromium":"true":' -i src/DEPS || die
        "${WORKDIR}/depot_tools/gclient" runhooks
        local ret=$?
        mv src/DEPS.orig src/DEPS || die
        [[ ${ret} -eq 0 ]] || die "gclient runhooks failed"
}

src_unpack() {
        # First grab depot_tools.
        ESVN_REVISION= subversion_fetch "http://src.chromium.org/svn/trunk/tools/depot_tools"
        mv "${S}" "${WORKDIR}"/depot_tools || die

        cd "${ESVN_STORE_DIR}/${PN}" || die

        gclient_config
        gclient_sync

        # Disabled so that we do not download nacl toolchain.
        #gclient_runhooks
        # Remove any lingering nacl toolchain files.
        rm -rf src/native_client/toolchain/linux_x86_newlib

        subversion_wc_info

        mkdir -p "${S}" || die
        einfo "Copying source to ${S}"
        rsync -rlpgo --exclude=".svn/" src/ "${S}" || die

        # Display correct svn revision in about box, and log new version.
        echo "${ESVN_WC_REVISION}" > "${S}"/build/LASTCHANGE.in || die
        . src/chrome/VERSION
        elog "Installing/updating to version ${MAJOR}.${MINOR}.${BUILD}.${PATCH} (Developer Build ${ESVN_WC_REVISION})"
}

if ! has chromium_pkg_die ${EBUILD_DEATH_HOOKS}; then
        EBUILD_DEATH_HOOKS+=" chromium_pkg_die";
fi

pkg_setup() {
        if [[ "${SLOT}" == "0" ]]; then
                CHROMIUM_SUFFIX=""
        else
                CHROMIUM_SUFFIX="-${SLOT}"
        fi
        CHROMIUM_HOME="/usr/$(get_libdir)/chromium-browser${CHROMIUM_SUFFIX}"

        # Make sure the build system will use the right tools, bug #340795.
        tc-export AR CC CXX RANLIB

        # Make sure the build system will use the right python, bug #344367.
        python_set_active_version 2
        python_pkg_setup

        chromium_check_kernel_config

        if use bindist; then
                elog "bindist enabled: H.264 video support will be disabled."
        else
                elog "bindist disabled: Resulting binaries may not be legal to re-distribute."
        fi
}

src_prepare() {
        ln -s /usr/$(get_libdir)/nacl-toolchain-newlib \
                native_client/toolchain/linux_x86_newlib || die

        # zlib-1.2.5.1-r1 renames the OF macro in zconf.h, bug 383371.
        sed -i '1i#define OF(x) x' \
                third_party/zlib/contrib/minizip/{ioapi,{,un}zip}.c \
                chrome/common/zip*.cc || die

        epatch_user

        # Remove most bundled libraries. Some are still needed.
        find third_party -type f \! -iname '*.gyp*' \
                \! -path 'third_party/WebKit/*' \
                \! -path 'third_party/adobe/*' \
                \! -path 'third_party/angle/*' \
                \! -path 'third_party/cacheinvalidation/*' \
                \! -path 'third_party/cld/*' \
                \! -path 'third_party/expat/*' \
                \! -path 'third_party/ffmpeg/*' \
                \! -path 'third_party/flac/flac.h' \
                \! -path 'third_party/gpsd/*' \
                \! -path 'third_party/harfbuzz/*' \
                \! -path 'third_party/hunspell/*' \
                \! -path 'third_party/iccjpeg/*' \
                \! -path 'third_party/jsoncpp/*' \
                \! -path 'third_party/json_minify/*' \
                \! -path 'third_party/khronos/*' \
                \! -path 'third_party/launchpad_translations/*' \
                \! -path 'third_party/leveldb/*' \
                \! -path 'third_party/leveldatabase/*' \
                \! -path 'third_party/libjingle/*' \
                \! -path 'third_party/libphonenumber/*' \
                \! -path 'third_party/libsrtp/*' \
                \! -path 'third_party/libusb/*' \
                \! -path 'third_party/libvpx/*' \
                \! -path 'third_party/libyuv/*' \
                \! -path 'third_party/lss/*' \
                \! -path 'third_party/mesa/*' \
                \! -path 'third_party/modp_b64/*' \
                \! -path 'third_party/mongoose/*' \
                \! -path 'third_party/npapi/*' \
                \! -path 'third_party/openmax/*' \
                \! -path 'third_party/ots/*' \
                \! -path 'third_party/protobuf/*' \
                \! -path 'third_party/scons-2.0.1/*' \
                \! -path 'third_party/sfntly/*' \
                \! -path 'third_party/skia/*' \
                \! -path 'third_party/smhasher/*' \
                \! -path 'third_party/speex/speex.h' \
                \! -path 'third_party/sqlite/*' \
                \! -path 'third_party/tcmalloc/*' \
                \! -path 'third_party/tlslite/*' \
                \! -path 'third_party/undoview/*' \
                \! -path 'third_party/v8-i18n/*' \
                \! -path 'third_party/webdriver/*' \
                \! -path 'third_party/webgl_conformance/*' \
                \! -path 'third_party/webrtc/*' \
                \! -path 'third_party/zlib/contrib/minizip/*' \
                -delete || die

        local v8_bundled="$(chromium_bundled_v8_version)"
        local v8_installed="$(chromium_installed_v8_version)"
        elog "V8 version: bundled - ${v8_bundled}; installed - ${v8_installed}"

        # Remove bundled v8.
        find v8 -type f \! -iname '*.gyp*' -delete || die

        # The implementation files include v8 headers with full path,
        # like #include "v8/include/v8.h". Make sure the system headers
        # will be used.
        # TODO: find a solution that can be upstreamed.
        rmdir v8/include || die
        ln -s /usr/include v8/include || die

        # Make sure the build system will use the right python, bug #344367.
        # Only convert directories that need it, to save time.
        python_convert_shebangs -q -r 2 build tools
}

src_configure() {
        local myconf=""

        # Never tell the build system to "enable" SSE2, it has a few unexpected
        # additions, bug #336871.
        myconf+=" -Ddisable_sse2=1"

        # Use system-provided libraries.
        # TODO: use_system_ffmpeg
        # TODO: use_system_hunspell (upstream changes needed).
        # TODO: use_system_ssl (http://crbug.com/58087).
        # TODO: use_system_sqlite (http://crbug.com/22208).
        # TODO: use_system_vpx
        myconf+="
                -Duse_system_bzip2=1
                -Duse_system_flac=1
                -Duse_system_icu=1
                -Duse_system_libevent=1
                -Duse_system_libjpeg=1
                -Duse_system_libpng=1
                -Duse_system_libwebp=1
                -Duse_system_libxml=1
                -Duse_system_speex=1
                -Duse_system_v8=1
                -Duse_system_xdg_utils=1
                -Duse_system_yasm=1
                -Duse_system_zlib=1"

        # Optional dependencies.
        # TODO: linux_link_kerberos, bug #381289.
        myconf+="
                $(gyp_use cups use_cups)
                $(gyp_use gnome use_gconf)
                $(gyp_use gnome-keyring use_gnome_keyring)
                $(gyp_use gnome-keyring linux_link_gnome_keyring)
                $(gyp_use kerberos use_kerberos)
                $(gyp_use pulseaudio use_pulseaudio)
                $(gyp_use selinux selinux)"

        if ! use selinux; then
                # Enable SUID sandbox.
                myconf+="
                        -Dlinux_sandbox_path=${CHROMIUM_HOME}/chrome_sandbox
                        -Dlinux_sandbox_chrome_path=${CHROMIUM_HOME}/chrome"
        fi

        # Never use bundled gold binary. Disable gold linker flags for now.
        myconf+="
                -Dlinux_use_gold_binary=0
                -Dlinux_use_gold_flags=0"

        if ! use bindist; then
                # Enable H.624 support in bundled ffmpeg.
                myconf+=" -Dproprietary_codecs=1 -Dffmpeg_branding=Chrome"
        fi

        local myarch="$(tc-arch)"
        if [[ $myarch = amd64 ]] ; then
                myconf+=" -Dtarget_arch=x64"
        elif [[ $myarch = x86 ]] ; then
                myconf+=" -Dtarget_arch=ia32"
        else
                die "Failed to determine target arch, got '$myarch'."
        fi

        # Make sure that -Werror doesn't get added to CFLAGS by the build system.
        # Depending on GCC version the warnings are different and we don't want
        # the build to fail because of that.
        myconf+=" -Dwerror="

        # Avoid CFLAGS problems, bug #352457, bug #390147.
        if ! use custom-cflags; then
                replace-flags "-Os" "-O2"
                strip-flags
        fi

        egyp_chromium ${myconf} || die
}

src_compile() {
        local test_targets
        for x in base cacheinvalidation crypto \
                googleurl gpu media net printing; do
                test_targets+=" ${x}_unittests"
        done

        local make_targets="chrome chromedriver"
        if ! use selinux; then
                make_targets+=" chrome_sandbox"
        fi
        if use test; then
                make_targets+=$test_targets
        fi

        # See bug #410883 for more info about the .host mess.
        emake ${make_targets} BUILDTYPE=Release V=1 \
                CC.host="$(tc-getCC)" CFLAGS.host="${CFLAGS}" \
                CXX.host="$(tc-getCXX)" CXXFLAGS.host="${CXXFLAGS}" \
                LINK.host="$(tc-getCXX)" LDFLAGS.host="${LDFLAGS}" \
                AR.host="$(tc-getAR)" || die

        pax-mark m out/Release/chrome
        if use test; then
                for x in $test_targets; do
                        pax-mark m out/Release/${x}
                done
        fi
}

src_test() {
        # For more info see bug #350349.
        local mylocale='en_US.utf8'
        if ! locale -a | grep -q "$mylocale"; then
                eerror "${PN} requires ${mylocale} locale for tests"
                eerror "Please read the following guides for more information:"
                eerror "  http://www.gentoo.org/doc/en/guide-localization.xml"
                eerror "  http://www.gentoo.org/doc/en/utf-8.xml"
                die "locale ${mylocale} is not supported"
        fi

        # For more info see bug #370957.
        if [[ $UID -eq 0 ]]; then
                die "Tests must be run as non-root. Please use FEATURES=userpriv."
        fi

        # ICUStringConversionsTest: bug #350347.
        # MessagePumpLibeventTest: bug #398501.
        LC_ALL="${mylocale}" VIRTUALX_COMMAND=out/Release/base_unittests virtualmake \
                '--gtest_filter=-ICUStringConversionsTest.*:MessagePumpLibeventTest.*'

        LC_ALL="${mylocale}" VIRTUALX_COMMAND=out/Release/cacheinvalidation_unittests virtualmake
        LC_ALL="${mylocale}" VIRTUALX_COMMAND=out/Release/crypto_unittests virtualmake
        LC_ALL="${mylocale}" VIRTUALX_COMMAND=out/Release/googleurl_unittests virtualmake
        LC_ALL="${mylocale}" VIRTUALX_COMMAND=out/Release/gpu_unittests virtualmake
        LC_ALL="${mylocale}" VIRTUALX_COMMAND=out/Release/media_unittests virtualmake

        # NetUtilTest: bug #361885.
        # DnsConfigServiceTest.GetSystemConfig: bug #394883.
        # CertDatabaseNSSTest.ImportServerCert_SelfSigned: bug #399269.
        LC_ALL="${mylocale}" VIRTUALX_COMMAND=out/Release/net_unittests virtualmake \
                '--gtest_filter=-NetUtilTest.IDNToUnicode*:NetUtilTest.FormatUrl*:DnsConfigServiceTest.GetSystemConfig:CertDatabaseNSSTest.ImportServerCert_SelfSigned'

        LC_ALL="${mylocale}" VIRTUALX_COMMAND=out/Release/printing_unittests virtualmake
}

src_install() {
        exeinto "${CHROMIUM_HOME}"
        doexe out/Release/chrome || die

        if ! use selinux; then
                doexe out/Release/chrome_sandbox || die
                fperms 4755 "${CHROMIUM_HOME}/chrome_sandbox"
        fi

        doexe out/Release/chromedriver || die

        doexe out/Release/nacl_helper{,_bootstrap} || die
        insinto "${CHROMIUM_HOME}"
        doins out/Release/nacl_irt_* || die
        doins out/Release/libppGoogleNaClPluginChrome.so || die

        newexe "${FILESDIR}"/chromium-launcher-r2.sh chromium-launcher.sh || die
        if [[ "${CHROMIUM_SUFFIX}" != "" ]]; then
                sed "s:chromium-browser:chromium-browser${CHROMIUM_SUFFIX}:g" \
                        -i "${ED}"/"${CHROMIUM_HOME}"/chromium-launcher.sh || die
                sed "s:chromium.desktop:chromium${CHROMIUM_SUFFIX}.desktop:g" \
                        -i "${ED}"/"${CHROMIUM_HOME}"/chromium-launcher.sh || die
                sed "s:plugins:plugins --user-data-dir=\${HOME}/.config/chromium${CHROMIUM_SUFFIX}:" \
                        -i "${ED}"/"${CHROMIUM_HOME}"/chromium-launcher.sh || die
        fi

        # It is important that we name the target "chromium-browser",
        # xdg-utils expect it; bug #355517.
        dosym "${CHROMIUM_HOME}/chromium-launcher.sh" /usr/bin/chromium-browser${CHROMIUM_SUFFIX} || die
        # keep the old symlink around for consistency
        dosym "${CHROMIUM_HOME}/chromium-launcher.sh" /usr/bin/chromium${CHROMIUM_SUFFIX} || die

        # Allow users to override command-line options, bug #357629.
        dodir /etc/chromium || die
        insinto /etc/chromium
        newins "${FILESDIR}/chromium.default" "default" || die

        pushd out/Release/locales > /dev/null || die
        chromium_remove_language_paks
        popd

        insinto "${CHROMIUM_HOME}"
        doins out/Release/*.pak || die

        doins -r out/Release/locales || die
        doins -r out/Release/resources || die

        newman out/Release/chrome.1 chromium${CHROMIUM_SUFFIX}.1 || die
        newman out/Release/chrome.1 chromium-browser${CHROMIUM_SUFFIX}.1 || die

        doexe out/Release/libffmpegsumo.so || die

        # Install icons and desktop entry.
        for SIZE in 16 22 24 32 48 64 128 256 ; do
                insinto /usr/share/icons/hicolor/${SIZE}x${SIZE}/apps
                newins chrome/app/theme/chromium/product_logo_${SIZE}.png \
                        chromium-browser${CHROMIUM_SUFFIX}.png || die
        done
        local mime_types="text/html;text/xml;application/xhtml+xml;"
        mime_types+="x-scheme-handler/http;x-scheme-handler/https;" # bug #360797
        mime_types+="x-scheme-handler/ftp;" # bug #412185
        make_desktop_entry \
                chromium-browser${CHROMIUM_SUFFIX} \
                "Chromium${CHROMIUM_SUFFIX}" \
                chromium-browser${CHROMIUM_SUFFIX} \
                "Network;WebBrowser" \
                "MimeType=${mime_types}\nStartupWMClass=chromium-browser"
        sed -e "/^Exec/s/$/ %U/" -i "${ED}"/usr/share/applications/*.desktop || die

        # Install GNOME default application entry (bug #303100).
        if use gnome; then
                dodir /usr/share/gnome-control-center/default-apps || die
                insinto /usr/share/gnome-control-center/default-apps
                newins "${FILESDIR}"/chromium-browser.xml chromium-browser${CHROMIUM_SUFFIX}.xml || die
                if [[ "${CHROMIUM_SUFFIX}" != "" ]]; then
                        sed "s:chromium-browser:chromium-browser${CHROMIUM_SUFFIX}:g" -i \
                                "${ED}"/usr/share/gnome-control-center/default-apps/chromium-browser${CHROMIUM_SUFFIX}.xml
                fi
        fi
}
1	floppym	1.84	# Copyright 1999-2012 Gentoo Foundation
2	wired	1.1	# Distributed under the terms of the GNU General Public License v2
3	phajdan.jr	1.109	# $Header: /var/cvsroot/gentoo-x86/www-client/chromium/chromium-9999-r1.ebuild,v 1.108 2012/05/05 19:06:26 phajdan.jr Exp $
4	wired	1.1
5	phajdan.jr	1.61	EAPI="4"
6	wired	1.1	PYTHON_DEPEND="2:2.6"
7
8	floppym	1.99	CHROMIUM_LANGS="am ar bg bn ca cs da de el en_GB es es_LA et fa fi fil fr gu he
9			hi hr hu id it ja kn ko lt lv ml mr ms nb nl pl pt_BR pt_PT ro ru sk sl sr
10			sv sw ta te th tr uk vi zh_CN zh_TW"
11
12			inherit chromium eutils flag-o-matic multilib \
13	phajdan.jr	1.21	pax-utils portability python subversion toolchain-funcs versionator virtualx
14	wired	1.1
15			DESCRIPTION="Open-source version of Google Chrome web browser"
16			HOMEPAGE="http://chromium.org/"
17	floppym	1.51	ESVN_REPO_URI="http://src.chromium.org/svn/trunk/src"
18	wired	1.1
19			LICENSE="BSD"
20			SLOT="live"
21			KEYWORDS=""
22	phajdan.jr	1.104	IUSE="bindist cups gnome gnome-keyring kerberos pulseaudio selinux"
23	wired	1.1
24			RDEPEND="app-arch/bzip2
25	floppym	1.78	cups? (
26			dev-libs/libgcrypt
27			>=net-print/cups-1.3.11
28			)
29	phajdan.jr	1.105	>=dev-lang/v8-3.10.2.1
30	wired	1.1	dev-libs/dbus-glib
31	phajdan.jr	1.57	dev-libs/elfutils
32	phajdan.jr	1.109	>=dev-libs/icu-49.1.1-r1
33	wired	1.1	>=dev-libs/libevent-1.4.13
34			dev-libs/libxml2[icu]
35			dev-libs/libxslt
36			>=dev-libs/nss-3.12.3
37			gnome? ( >=gnome-base/gconf-2.24.0 )
38			gnome-keyring? ( >=gnome-base/gnome-keyring-2.28.2 )
39			>=media-libs/alsa-lib-1.0.19
40			media-libs/flac
41	phajdan.jr	1.94	>=media-libs/libjpeg-turbo-1.2.0-r1
42	wired	1.1	media-libs/libpng
43	floppym	1.93	>=media-libs/libwebp-0.1.3
44	wired	1.1	media-libs/speex
45	phajdan.jr	1.45	pulseaudio? ( media-sound/pulseaudio )
46	floppym	1.87	sys-fs/udev
47	wired	1.1	sys-libs/zlib
48			x11-libs/gtk+:2
49	phajdan.jr	1.37	x11-libs/libXinerama
50	wired	1.1	x11-libs/libXScrnSaver
51	phajdan.jr	1.45	x11-libs/libXtst
52	phajdan.jr	1.104	kerberos? ( virtual/krb5 )
53			selinux? ( sys-libs/libselinux )"
54	wired	1.1	DEPEND="${RDEPEND}
55	phajdan.jr	1.81	>=dev-lang/nacl-toolchain-newlib-0_p7311
56	wired	1.1	dev-lang/perl
57	phajdan.jr	1.72	dev-lang/yasm
58	phajdan.jr	1.98	dev-python/ply
59	floppym	1.49	dev-python/simplejson
60	wired	1.1	>=dev-util/gperf-3.0.3
61	phajdan.jr	1.35	>=sys-devel/bison-2.4.3
62	wired	1.1	sys-devel/flex
63	phajdan.jr	1.13	>=sys-devel/make-3.81-r2
64	jdhore	1.107	virtual/pkgconfig
65	phajdan.jr	1.96	test? (
66			dev-python/pyftpdlib
67			)"
68	wired	1.1	RDEPEND+="
69			!=www-client/chromium-9999
70			x11-misc/xdg-utils
71			virtual/ttf-fonts"
72
73	floppym	1.51	gclient_config() {
74			einfo "gclient config -->"
75			# Allow the user to keep their config if they know what they are doing.
76			if ! grep -q KEEP .gclient; then
77			cp -f "${FILESDIR}/dot-gclient" .gclient \|\| die
78			fi
79			cat .gclient \|\| die
80			}
81
82			gclient_sync() {
83			einfo "gclient sync -->"
84	floppym	1.91	[[ -n "${ESVN_UMASK}" ]] && eumask_push "${ESVN_UMASK}"
85	phajdan.jr	1.82	# Only use a single job to prevent hangs.
86			"${WORKDIR}/depot_tools/gclient" sync --nohooks --jobs=1 \
87	floppym	1.51	--delete_unversioned_trees \|\| die
88	floppym	1.91	[[ -n "${ESVN_UMASK}" ]] && eumask_pop
89	floppym	1.51	}
90
91	floppym	1.48	gclient_runhooks() {
92	floppym	1.51	# Run all hooks except gyp_chromium.
93			einfo "gclient runhooks -->"
94	floppym	1.48	cp src/DEPS src/DEPS.orig \|\| die
95			sed -e 's:"python", "src/build/gyp_chromium":"true":' -i src/DEPS \|\| die
96			"${WORKDIR}/depot_tools/gclient" runhooks
97			local ret=$?
98			mv src/DEPS.orig src/DEPS \|\| die
99			[[ ${ret} -eq 0 ]] \|\| die "gclient runhooks failed"
100			}
101
102	wired	1.1	src_unpack() {
103	floppym	1.51	# First grab depot_tools.
104			ESVN_REVISION= subversion_fetch "http://src.chromium.org/svn/trunk/tools/depot_tools"
105	phajdan.jr	1.24	mv "${S}" "${WORKDIR}"/depot_tools \|\| die
106	wired	1.1
107	phajdan.jr	1.25	cd "${ESVN_STORE_DIR}/${PN}" \|\| die
108	wired	1.1
109	floppym	1.51	gclient_config
110			gclient_sync
111	floppym	1.70
112			# Disabled so that we do not download nacl toolchain.
113	mr_bones_	1.71	#gclient_runhooks
114	floppym	1.70	# Remove any lingering nacl toolchain files.
115			rm -rf src/native_client/toolchain/linux_x86_newlib
116	wired	1.1
117	floppym	1.51	subversion_wc_info
118	wired	1.1
119	phajdan.jr	1.24	mkdir -p "${S}" \|\| die
120	floppym	1.51	einfo "Copying source to ${S}"
121	phajdan.jr	1.24	rsync -rlpgo --exclude=".svn/" src/ "${S}" \|\| die
122	wired	1.1
123	phajdan.jr	1.24	# Display correct svn revision in about box, and log new version.
124	floppym	1.51	echo "${ESVN_WC_REVISION}" > "${S}"/build/LASTCHANGE.in \|\| die
125	wired	1.1	. src/chrome/VERSION
126	floppym	1.51	elog "Installing/updating to version ${MAJOR}.${MINOR}.${BUILD}.${PATCH} (Developer Build ${ESVN_WC_REVISION})"
127	wired	1.1	}
128
129	floppym	1.102	if ! has chromium_pkg_die ${EBUILD_DEATH_HOOKS}; then
130	floppym	1.99	EBUILD_DEATH_HOOKS+=" chromium_pkg_die";
131	phajdan.jr	1.61	fi
132
133	wired	1.1	pkg_setup() {
134	phajdan.jr	1.64	if [[ "${SLOT}" == "0" ]]; then
135			CHROMIUM_SUFFIX=""
136			else
137			CHROMIUM_SUFFIX="-${SLOT}"
138			fi
139			CHROMIUM_HOME="/usr/$(get_libdir)/chromium-browser${CHROMIUM_SUFFIX}"
140	wired	1.1
141			# Make sure the build system will use the right tools, bug #340795.
142			tc-export AR CC CXX RANLIB
143
144			# Make sure the build system will use the right python, bug #344367.
145			python_set_active_version 2
146			python_pkg_setup
147
148	floppym	1.99	chromium_check_kernel_config
149	phajdan.jr	1.72
150	floppym	1.53	if use bindist; then
151			elog "bindist enabled: H.264 video support will be disabled."
152			else
153			elog "bindist disabled: Resulting binaries may not be legal to re-distribute."
154			fi
155	wired	1.1	}
156
157			src_prepare() {
158	phajdan.jr	1.62	ln -s /usr/$(get_libdir)/nacl-toolchain-newlib \
159			native_client/toolchain/linux_x86_newlib \|\| die
160
161	floppym	1.55	# zlib-1.2.5.1-r1 renames the OF macro in zconf.h, bug 383371.
162			sed -i '1i#define OF(x) x' \
163			third_party/zlib/contrib/minizip/{ioapi,{,un}zip}.c \
164	floppym	1.77	chrome/common/zip*.cc \|\| die
165	floppym	1.55
166	floppym	1.51	epatch_user
167
168	wired	1.1	# Remove most bundled libraries. Some are still needed.
169			find third_party -type f \! -iname '.gyp' \
170			\! -path 'third_party/WebKit/*' \
171	phajdan.jr	1.95	\! -path 'third_party/adobe/*' \
172	wired	1.1	\! -path 'third_party/angle/*' \
173			\! -path 'third_party/cacheinvalidation/*' \
174			\! -path 'third_party/cld/*' \
175			\! -path 'third_party/expat/*' \
176			\! -path 'third_party/ffmpeg/*' \
177			\! -path 'third_party/flac/flac.h' \
178			\! -path 'third_party/gpsd/*' \
179			\! -path 'third_party/harfbuzz/*' \
180			\! -path 'third_party/hunspell/*' \
181			\! -path 'third_party/iccjpeg/*' \
182	floppym	1.65	\! -path 'third_party/jsoncpp/*' \
183	phajdan.jr	1.97	\! -path 'third_party/json_minify/*' \
184	floppym	1.80	\! -path 'third_party/khronos/*' \
185	wired	1.1	\! -path 'third_party/launchpad_translations/*' \
186	phajdan.jr	1.10	\! -path 'third_party/leveldb/*' \
187	phajdan.jr	1.45	\! -path 'third_party/leveldatabase/*' \
188	wired	1.1	\! -path 'third_party/libjingle/*' \
189	phajdan.jr	1.24	\! -path 'third_party/libphonenumber/*' \
190	phajdan.jr	1.89	\! -path 'third_party/libsrtp/*' \
191	phajdan.jr	1.106	\! -path 'third_party/libusb/*' \
192	phajdan.jr	1.40	\! -path 'third_party/libvpx/*' \
193	floppym	1.83	\! -path 'third_party/libyuv/*' \
194	phajdan.jr	1.57	\! -path 'third_party/lss/*' \
195	wired	1.1	\! -path 'third_party/mesa/*' \
196			\! -path 'third_party/modp_b64/*' \
197	phajdan.jr	1.45	\! -path 'third_party/mongoose/*' \
198	wired	1.1	\! -path 'third_party/npapi/*' \
199			\! -path 'third_party/openmax/*' \
200			\! -path 'third_party/ots/*' \
201			\! -path 'third_party/protobuf/*' \
202	phajdan.jr	1.57	\! -path 'third_party/scons-2.0.1/*' \
203	phajdan.jr	1.40	\! -path 'third_party/sfntly/*' \
204	wired	1.1	\! -path 'third_party/skia/*' \
205	floppym	1.52	\! -path 'third_party/smhasher/*' \
206	wired	1.1	\! -path 'third_party/speex/speex.h' \
207			\! -path 'third_party/sqlite/*' \
208			\! -path 'third_party/tcmalloc/*' \
209	phajdan.jr	1.97	\! -path 'third_party/tlslite/*' \
210	wired	1.1	\! -path 'third_party/undoview/*' \
211	phajdan.jr	1.45	\! -path 'third_party/v8-i18n/*' \
212			\! -path 'third_party/webdriver/*' \
213	phajdan.jr	1.40	\! -path 'third_party/webgl_conformance/*' \
214	phajdan.jr	1.36	\! -path 'third_party/webrtc/*' \
215	wired	1.1	\! -path 'third_party/zlib/contrib/minizip/*' \
216			-delete \|\| die
217
218	floppym	1.99	local v8_bundled="$(chromium_bundled_v8_version)"
219			local v8_installed="$(chromium_installed_v8_version)"
220	phajdan.jr	1.58	elog "V8 version: bundled - ${v8_bundled}; installed - ${v8_installed}"
221
222			# Remove bundled v8.
223			find v8 -type f \! -iname '.gyp' -delete \|\| die
224
225			# The implementation files include v8 headers with full path,
226			# like #include "v8/include/v8.h". Make sure the system headers
227			# will be used.
228			# TODO: find a solution that can be upstreamed.
229			rmdir v8/include \|\| die
230			ln -s /usr/include v8/include \|\| die
231
232	wired	1.1	# Make sure the build system will use the right python, bug #344367.
233			# Only convert directories that need it, to save time.
234			python_convert_shebangs -q -r 2 build tools
235			}
236
237			src_configure() {
238			local myconf=""
239
240			# Never tell the build system to "enable" SSE2, it has a few unexpected
241			# additions, bug #336871.
242			myconf+=" -Ddisable_sse2=1"
243
244			# Use system-provided libraries.
245	phajdan.jr	1.40	# TODO: use_system_ffmpeg
246	wired	1.1	# TODO: use_system_hunspell (upstream changes needed).
247			# TODO: use_system_ssl (http://crbug.com/58087).
248			# TODO: use_system_sqlite (http://crbug.com/22208).
249	phajdan.jr	1.40	# TODO: use_system_vpx
250	wired	1.1	myconf+="
251			-Duse_system_bzip2=1
252	phajdan.jr	1.2	-Duse_system_flac=1
253	wired	1.1	-Duse_system_icu=1
254			-Duse_system_libevent=1
255			-Duse_system_libjpeg=1
256			-Duse_system_libpng=1
257	phajdan.jr	1.22	-Duse_system_libwebp=1
258	wired	1.1	-Duse_system_libxml=1
259			-Duse_system_speex=1
260	phajdan.jr	1.58	-Duse_system_v8=1
261	wired	1.1	-Duse_system_xdg_utils=1
262	phajdan.jr	1.72	-Duse_system_yasm=1
263	wired	1.1	-Duse_system_zlib=1"
264
265	phajdan.jr	1.8	# Optional dependencies.
266	phajdan.jr	1.54	# TODO: linux_link_kerberos, bug #381289.
267	phajdan.jr	1.8	myconf+="
268	floppym	1.73	$(gyp_use cups use_cups)
269	phajdan.jr	1.8	$(gyp_use gnome use_gconf)
270			$(gyp_use gnome-keyring use_gnome_keyring)
271	phajdan.jr	1.45	$(gyp_use gnome-keyring linux_link_gnome_keyring)
272			$(gyp_use kerberos use_kerberos)
273	phajdan.jr	1.104	$(gyp_use pulseaudio use_pulseaudio)
274			$(gyp_use selinux selinux)"
275	wired	1.1
276	phajdan.jr	1.104	if ! use selinux; then
277			# Enable SUID sandbox.
278			myconf+="
279			-Dlinux_sandbox_path=${CHROMIUM_HOME}/chrome_sandbox
280			-Dlinux_sandbox_chrome_path=${CHROMIUM_HOME}/chrome"
281			fi
282	wired	1.1
283	floppym	1.92	# Never use bundled gold binary. Disable gold linker flags for now.
284			myconf+="
285			-Dlinux_use_gold_binary=0
286			-Dlinux_use_gold_flags=0"
287
288	floppym	1.53	if ! use bindist; then
289			# Enable H.624 support in bundled ffmpeg.
290			myconf+=" -Dproprietary_codecs=1 -Dffmpeg_branding=Chrome"
291			fi
292
293	phajdan.jr	1.31	local myarch="$(tc-arch)"
294	wired	1.1	if [[ $myarch = amd64 ]] ; then
295			myconf+=" -Dtarget_arch=x64"
296			elif [[ $myarch = x86 ]] ; then
297			myconf+=" -Dtarget_arch=ia32"
298			else
299			die "Failed to determine target arch, got '$myarch'."
300			fi
301
302			# Make sure that -Werror doesn't get added to CFLAGS by the build system.
303			# Depending on GCC version the warnings are different and we don't want
304			# the build to fail because of that.
305			myconf+=" -Dwerror="
306
307	phajdan.jr	1.76	# Avoid CFLAGS problems, bug #352457, bug #390147.
308	floppym	1.84	if ! use custom-cflags; then
309			replace-flags "-Os" "-O2"
310			strip-flags
311			fi
312	wired	1.1
313	floppym	1.99	egyp_chromium ${myconf} \|\| die
314	wired	1.1	}
315
316			src_compile() {
317	phajdan.jr	1.103	local test_targets
318			for x in base cacheinvalidation crypto \
319			googleurl gpu media net printing; do
320			test_targets+=" ${x}_unittests"
321			done
322
323	phajdan.jr	1.104	local make_targets="chrome chromedriver"
324			if ! use selinux; then
325			make_targets+=" chrome_sandbox"
326			fi
327	phajdan.jr	1.103	if use test; then
328			make_targets+=$test_targets
329			fi
330
331			# See bug #410883 for more info about the .host mess.
332			emake ${make_targets} BUILDTYPE=Release V=1 \
333			CC.host="$(tc-getCC)" CFLAGS.host="${CFLAGS}" \
334			CXX.host="$(tc-getCXX)" CXXFLAGS.host="${CXXFLAGS}" \
335			LINK.host="$(tc-getCXX)" LDFLAGS.host="${LDFLAGS}" \
336			AR.host="$(tc-getAR)" \|\| die
337
338	wired	1.1	pax-mark m out/Release/chrome
339			if use test; then
340	phajdan.jr	1.103	for x in $test_targets; do
341			pax-mark m out/Release/${x}
342			done
343	wired	1.1	fi
344			}
345
346			src_test() {
347			# For more info see bug #350349.
348			local mylocale='en_US.utf8'
349			if ! locale -a \| grep -q "$mylocale"; then
350			eerror "${PN} requires ${mylocale} locale for tests"
351			eerror "Please read the following guides for more information:"
352			eerror " http://www.gentoo.org/doc/en/guide-localization.xml"
353			eerror " http://www.gentoo.org/doc/en/utf-8.xml"
354			die "locale ${mylocale} is not supported"
355			fi
356
357	phajdan.jr	1.32	# For more info see bug #370957.
358			if [[ $UID -eq 0 ]]; then
359			die "Tests must be run as non-root. Please use FEATURES=userpriv."
360			fi
361
362	phajdan.jr	1.86	# ICUStringConversionsTest: bug #350347.
363			# MessagePumpLibeventTest: bug #398501.
364	phajdan.jr	1.8	LC_ALL="${mylocale}" VIRTUALX_COMMAND=out/Release/base_unittests virtualmake \
365	phajdan.jr	1.86	'--gtest_filter=-ICUStringConversionsTest.:MessagePumpLibeventTest.'
366	phajdan.jr	1.13
367	phajdan.jr	1.74	LC_ALL="${mylocale}" VIRTUALX_COMMAND=out/Release/cacheinvalidation_unittests virtualmake
368	phajdan.jr	1.20	LC_ALL="${mylocale}" VIRTUALX_COMMAND=out/Release/crypto_unittests virtualmake
369			LC_ALL="${mylocale}" VIRTUALX_COMMAND=out/Release/googleurl_unittests virtualmake
370	phajdan.jr	1.74	LC_ALL="${mylocale}" VIRTUALX_COMMAND=out/Release/gpu_unittests virtualmake
371			LC_ALL="${mylocale}" VIRTUALX_COMMAND=out/Release/media_unittests virtualmake
372	phajdan.jr	1.20
373	phajdan.jr	1.13	# NetUtilTest: bug #361885.
374	phajdan.jr	1.86	# DnsConfigServiceTest.GetSystemConfig: bug #394883.
375	phajdan.jr	1.94	# CertDatabaseNSSTest.ImportServerCert_SelfSigned: bug #399269.
376	phajdan.jr	1.13	LC_ALL="${mylocale}" VIRTUALX_COMMAND=out/Release/net_unittests virtualmake \
377	phajdan.jr	1.94	'--gtest_filter=-NetUtilTest.IDNToUnicode:NetUtilTest.FormatUrl:DnsConfigServiceTest.GetSystemConfig:CertDatabaseNSSTest.ImportServerCert_SelfSigned'
378	phajdan.jr	1.74
379			LC_ALL="${mylocale}" VIRTUALX_COMMAND=out/Release/printing_unittests virtualmake
380	wired	1.1	}
381
382			src_install() {
383			exeinto "${CHROMIUM_HOME}"
384	phajdan.jr	1.45	doexe out/Release/chrome \|\| die
385	phajdan.jr	1.104
386			if ! use selinux; then
387			doexe out/Release/chrome_sandbox \|\| die
388			fperms 4755 "${CHROMIUM_HOME}/chrome_sandbox"
389			fi
390	phajdan.jr	1.30
391	phajdan.jr	1.63	doexe out/Release/chromedriver \|\| die
392	phajdan.jr	1.45
393	phajdan.jr	1.108	doexe out/Release/nacl_helper{,_bootstrap} \|\| die
394	phajdan.jr	1.62	insinto "${CHROMIUM_HOME}"
395	phajdan.jr	1.108	doins out/Release/nacl_irt_* \|\| die
396			doins out/Release/libppGoogleNaClPluginChrome.so \|\| die
397	phajdan.jr	1.30
398	phajdan.jr	1.28	newexe "${FILESDIR}"/chromium-launcher-r2.sh chromium-launcher.sh \|\| die
399	phajdan.jr	1.64	if [[ "${CHROMIUM_SUFFIX}" != "" ]]; then
400			sed "s:chromium-browser:chromium-browser${CHROMIUM_SUFFIX}:g" \
401			-i "${ED}"/"${CHROMIUM_HOME}"/chromium-launcher.sh \|\| die
402			sed "s:chromium.desktop:chromium${CHROMIUM_SUFFIX}.desktop:g" \
403			-i "${ED}"/"${CHROMIUM_HOME}"/chromium-launcher.sh \|\| die
404			sed "s:plugins:plugins --user-data-dir=\${HOME}/.config/chromium${CHROMIUM_SUFFIX}:" \
405			-i "${ED}"/"${CHROMIUM_HOME}"/chromium-launcher.sh \|\| die
406			fi
407	wired	1.1
408			# It is important that we name the target "chromium-browser",
409			# xdg-utils expect it; bug #355517.
410	phajdan.jr	1.64	dosym "${CHROMIUM_HOME}/chromium-launcher.sh" /usr/bin/chromium-browser${CHROMIUM_SUFFIX} \|\| die
411	wired	1.1	# keep the old symlink around for consistency
412	phajdan.jr	1.64	dosym "${CHROMIUM_HOME}/chromium-launcher.sh" /usr/bin/chromium${CHROMIUM_SUFFIX} \|\| die
413	wired	1.1
414	phajdan.jr	1.28	# Allow users to override command-line options, bug #357629.
415			dodir /etc/chromium \|\| die
416			insinto /etc/chromium
417			newins "${FILESDIR}/chromium.default" "default" \|\| die
418
419	floppym	1.99	pushd out/Release/locales > /dev/null \|\| die
420			chromium_remove_language_paks
421			popd
422	phajdan.jr	1.29
423	wired	1.1	insinto "${CHROMIUM_HOME}"
424	phajdan.jr	1.108	doins out/Release/*.pak \|\| die
425	wired	1.1
426			doins -r out/Release/locales \|\| die
427			doins -r out/Release/resources \|\| die
428
429	phajdan.jr	1.64	newman out/Release/chrome.1 chromium${CHROMIUM_SUFFIX}.1 \|\| die
430			newman out/Release/chrome.1 chromium-browser${CHROMIUM_SUFFIX}.1 \|\| die
431	wired	1.1
432	phajdan.jr	1.40	doexe out/Release/libffmpegsumo.so \|\| die
433	wired	1.1
434	phajdan.jr	1.9	# Install icons and desktop entry.
435	floppym	1.47	for SIZE in 16 22 24 32 48 64 128 256 ; do
436	phajdan.jr	1.9	insinto /usr/share/icons/hicolor/${SIZE}x${SIZE}/apps
437			newins chrome/app/theme/chromium/product_logo_${SIZE}.png \
438	phajdan.jr	1.64	chromium-browser${CHROMIUM_SUFFIX}.png \|\| die
439	phajdan.jr	1.9	done
440	phajdan.jr	1.11	local mime_types="text/html;text/xml;application/xhtml+xml;"
441			mime_types+="x-scheme-handler/http;x-scheme-handler/https;" # bug #360797
442	phajdan.jr	1.106	mime_types+="x-scheme-handler/ftp;" # bug #412185
443	phajdan.jr	1.64	make_desktop_entry \
444			chromium-browser${CHROMIUM_SUFFIX} \
445			"Chromium${CHROMIUM_SUFFIX}" \
446			chromium-browser${CHROMIUM_SUFFIX} \
447	phajdan.jr	1.41	"Network;WebBrowser" \
448	phajdan.jr	1.34	"MimeType=${mime_types}\nStartupWMClass=chromium-browser"
449	grobian	1.38	sed -e "/^Exec/s/$/ %U/" -i "${ED}"/usr/share/applications/*.desktop \|\| die
450	wired	1.1
451			# Install GNOME default application entry (bug #303100).
452			if use gnome; then
453			dodir /usr/share/gnome-control-center/default-apps \|\| die
454			insinto /usr/share/gnome-control-center/default-apps
455	phajdan.jr	1.64	newins "${FILESDIR}"/chromium-browser.xml chromium-browser${CHROMIUM_SUFFIX}.xml \|\| die
456			if [[ "${CHROMIUM_SUFFIX}" != "" ]]; then
457			sed "s:chromium-browser:chromium-browser${CHROMIUM_SUFFIX}:g" -i \
458			"${ED}"/usr/share/gnome-control-center/default-apps/chromium-browser${CHROMIUM_SUFFIX}.xml
459			fi
460	wired	1.1	fi
461			}