/[gentoo-x86]/www-client/epiphany/epiphany-3.4.2.ebuild
Gentoo

Contents of /www-client/epiphany/epiphany-3.4.2.ebuild

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.2 - (show annotations) (download)
Sat May 19 21:58:10 2012 UTC (22 months, 4 weeks ago) by tetromino
Branch: MAIN
Changes since 1.1: +2 -1 lines
Fix test failure on hardened (bug #415801, thanks to Markus Oehme).

(Portage version: 2.2.0_alpha107/cvs/Linux x86_64)

1 # Copyright 1999-2012 Gentoo Foundation
2 # Distributed under the terms of the GNU General Public License v2
3 # $Header: /var/cvsroot/gentoo-x86/www-client/epiphany/epiphany-3.4.2.ebuild,v 1.1 2012/05/19 21:31:31 tetromino Exp $
4
5 EAPI="4"
6 GCONF_DEBUG="yes"
7
8 inherit autotools eutils gnome2 pax-utils versionator virtualx
9 if [[ ${PV} = 9999 ]]; then
10 inherit gnome2-live
11 fi
12
13 DESCRIPTION="GNOME webbrowser based on Webkit"
14 HOMEPAGE="http://projects.gnome.org/epiphany/"
15
16 LICENSE="GPL-2"
17 SLOT="0"
18 IUSE="avahi doc +introspection +jit +nss test"
19 KEYWORDS="~alpha ~amd64 ~ia64 ~ppc ~ppc64 ~sparc ~x86"
20
21 # XXX: Should we add seed support? Seed seems to be unmaintained now.
22 RDEPEND="
23 >=dev-libs/glib-2.31.2:2
24 >=x11-libs/gtk+-3.3.14:3[introspection?]
25 >=dev-libs/libxml2-2.6.12:2
26 >=dev-libs/libxslt-1.1.7
27 >=app-text/iso-codes-0.35
28 >=net-libs/webkit-gtk-1.7.92:3[introspection?]
29 >=net-libs/libsoup-gnome-2.37.1:2.4
30 >=gnome-base/gnome-keyring-2.26.0
31 >=gnome-base/gsettings-desktop-schemas-0.0.1
32 >=x11-libs/libnotify-0.5.1
33
34 dev-db/sqlite:3
35 x11-libs/libICE
36 x11-libs/libSM
37 x11-libs/libX11
38
39 x11-themes/gnome-icon-theme
40 x11-themes/gnome-icon-theme-symbolic
41
42 avahi? ( >=net-dns/avahi-0.6.22 )
43 introspection? ( >=dev-libs/gobject-introspection-0.9.5 )
44 !jit? ( net-libs/webkit-gtk[-jit] )
45 nss? ( dev-libs/nss )"
46 # paxctl needed for bug #407085
47 DEPEND="${RDEPEND}
48 app-text/gnome-doc-utils
49 >=dev-util/intltool-0.40
50 sys-devel/gettext
51 virtual/pkgconfig
52 jit? ( sys-apps/paxctl )
53 doc? ( >=dev-util/gtk-doc-1 )"
54
55 pkg_setup() {
56 DOCS="AUTHORS ChangeLog* HACKING MAINTAINERS NEWS README TODO"
57 G2CONF="${G2CONF}
58 --enable-shared
59 --disable-schemas-compile
60 --disable-scrollkeeper
61 --disable-static
62 --with-distributor-name=Gentoo
63 $(use_enable avahi zeroconf)
64 $(use_enable introspection)
65 $(use_enable nss)
66 $(use_enable test tests)"
67 }
68
69 src_prepare() {
70 # Build-time segfaults under PaX with USE=introspection when building
71 # against webkit-gtk[introspection,jit]
72 if use introspection && use jit; then
73 epatch "${FILESDIR}/${PN}-3.3.90-paxctl-introspection.patch"
74 cp "${FILESDIR}/paxctl.sh" "${S}/" || die
75 eautoreconf
76 fi
77 gnome2_src_prepare
78 }
79
80 src_compile() {
81 # needed to avoid "Command line `dbus-launch ...' exited with non-zero exit status 1"
82 unset DISPLAY
83 gnome2_src_compile
84 }
85
86 src_test() {
87 # FIXME: this should be handled at eclass level
88 "${EROOT}${GLIB_COMPILE_SCHEMAS}" --allow-any-name "${S}/data" || die
89
90 use jit && pax-mark m $(list-paxables tests/test*) #415801
91 GSETTINGS_SCHEMA_DIR="${S}/data" Xemake check
92 }
93
94 src_install() {
95 gnome2_src_install
96 use jit && pax-mark m "${ED}usr/bin/epiphany"
97 }

  ViewVC Help
Powered by ViewVC 1.1.20