| 1 |
# Copyright 1999-2012 Gentoo Foundation
|
| 2 |
# Distributed under the terms of the GNU General Public License v2
|
| 3 |
# $Header: /var/cvsroot/gentoo-x86/www-client/links/links-2.6.ebuild,v 1.11 2012/05/06 19:14:33 halcy0n Exp $
|
| 4 |
|
| 5 |
EAPI=4
|
| 6 |
inherit autotools eutils fdo-mime
|
| 7 |
|
| 8 |
DESCRIPTION="A fast and lightweight web browser running in both graphics and text mode"
|
| 9 |
HOMEPAGE="http://links.twibright.com/"
|
| 10 |
SRC_URI="http://${PN}.twibright.com/download/${P}.tar.bz2
|
| 11 |
mirror://debian/pool/main/${PN:0:1}/${PN}2/${PN}2_2.5-1.debian.tar.gz"
|
| 12 |
|
| 13 |
LICENSE="GPL-2"
|
| 14 |
SLOT="2"
|
| 15 |
KEYWORDS="alpha amd64 arm hppa ia64 ~mips ppc ppc64 s390 sh sparc x86 ~ppc-aix ~amd64-fbsd ~x86-fbsd ~ia64-hpux ~x86-interix ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~m68k-mint ~sparc-solaris ~x64-solaris ~x86-solaris"
|
| 16 |
IUSE="bzip2 +deprecated directfb fbcon gpm jpeg livecd lzma ssl suid svga tiff unicode X zlib"
|
| 17 |
|
| 18 |
GRAPHICS_DEPEND=">=media-libs/libpng-1.2:0" #75685
|
| 19 |
|
| 20 |
RDEPEND=">=sys-libs/ncurses-5.7-r7
|
| 21 |
bzip2? ( app-arch/bzip2 )
|
| 22 |
directfb? ( dev-libs/DirectFB )
|
| 23 |
fbcon? ( ${GRAPHICS_DEPEND} )
|
| 24 |
gpm? ( sys-libs/gpm )
|
| 25 |
jpeg? ( virtual/jpeg )
|
| 26 |
livecd? (
|
| 27 |
${GRAPHICS_DEPEND}
|
| 28 |
sys-libs/gpm
|
| 29 |
virtual/jpeg
|
| 30 |
)
|
| 31 |
lzma? ( app-arch/xz-utils )
|
| 32 |
ssl? ( dev-libs/openssl:0 )
|
| 33 |
svga? (
|
| 34 |
${GRAPHICS_DEPEND}
|
| 35 |
>=media-libs/svgalib-1.4.3
|
| 36 |
)
|
| 37 |
tiff? ( media-libs/tiff:0 )
|
| 38 |
X? (
|
| 39 |
${GRAPHICS_DEPEND}
|
| 40 |
x11-libs/libXext
|
| 41 |
)
|
| 42 |
zlib? ( sys-libs/zlib )"
|
| 43 |
|
| 44 |
DEPEND="${RDEPEND}
|
| 45 |
virtual/pkgconfig
|
| 46 |
fbcon? ( virtual/os-headers )
|
| 47 |
livecd? ( virtual/os-headers )"
|
| 48 |
|
| 49 |
REQUIRED_USE="!livecd? ( fbcon? ( gpm ) )
|
| 50 |
svga? ( suid )"
|
| 51 |
|
| 52 |
DOCS=( AUTHORS BRAILLE_HOWTO ChangeLog KEYS NEWS README SITES )
|
| 53 |
|
| 54 |
src_prepare() {
|
| 55 |
epatch "${WORKDIR}"/debian/patches/verify-ssl-certs-510417.diff
|
| 56 |
|
| 57 |
if use unicode; then
|
| 58 |
pushd intl >/dev/null
|
| 59 |
./gen-intl || die
|
| 60 |
./synclang || die
|
| 61 |
popd >/dev/null
|
| 62 |
fi
|
| 63 |
|
| 64 |
# error: conditional "am__fastdepCXX" was never defined (for eautoreconf)
|
| 65 |
sed -i -e '/AC_PROG_CXX/s:#::' configure.in || die
|
| 66 |
|
| 67 |
# Upstream configure produced by broken autoconf-2.13. This also fixes
|
| 68 |
# toolchain detection.
|
| 69 |
eautoreconf #131440 and #103483#c23
|
| 70 |
}
|
| 71 |
|
| 72 |
src_configure() {
|
| 73 |
local myconf
|
| 74 |
|
| 75 |
if use livecd; then
|
| 76 |
export ac_cv_lib_gpm_Gpm_Open=yes
|
| 77 |
myconf+=' --with-fb --with-libjpeg'
|
| 78 |
else
|
| 79 |
export ac_cv_lib_gpm_Gpm_Open=$(usex gpm)
|
| 80 |
fi
|
| 81 |
|
| 82 |
if use X || use fbcon || use directfb || use svga || use livecd; then
|
| 83 |
myconf+=' --enable-graphics'
|
| 84 |
fi
|
| 85 |
|
| 86 |
econf \
|
| 87 |
$(use_with ssl) \
|
| 88 |
$(use_with zlib) \
|
| 89 |
$(use_with bzip2) \
|
| 90 |
$(use_with lzma) \
|
| 91 |
$(use_with svga svgalib) \
|
| 92 |
$(use_with X x) \
|
| 93 |
$(use_with fbcon fb) \
|
| 94 |
$(use_with directfb) \
|
| 95 |
$(use_with jpeg libjpeg) \
|
| 96 |
$(use_with tiff libtiff) \
|
| 97 |
${myconf}
|
| 98 |
}
|
| 99 |
|
| 100 |
src_install() {
|
| 101 |
default
|
| 102 |
|
| 103 |
if use X; then
|
| 104 |
newicon Links_logo.png links.png
|
| 105 |
make_desktop_entry 'links -g %u' Links links 'Network;WebBrowser'
|
| 106 |
local d="${ED}"/usr/share/applications
|
| 107 |
echo 'MimeType=x-scheme-handler/http;' >> "${d}"/*.desktop
|
| 108 |
use ssl && sed -i -e 's:x-scheme-handler/http;:&x-scheme-handler/https;:' \
|
| 109 |
"${d}"/*.desktop
|
| 110 |
fi
|
| 111 |
|
| 112 |
nonfatal dohtml doc/links_cal/*
|
| 113 |
use deprecated && dosym links /usr/bin/links2
|
| 114 |
use suid && fperms 4755 /usr/bin/links
|
| 115 |
}
|
| 116 |
|
| 117 |
pkg_postinst() {
|
| 118 |
use X && fdo-mime_desktop_database_update
|
| 119 |
}
|
| 120 |
|
| 121 |
pkg_postrm() {
|
| 122 |
use X && fdo-mime_desktop_database_update
|
| 123 |
}
|
Parent Directory
| 
Revision Log