/[gentoo-x86]/www-servers/thttpd/thttpd-2.25b-r9.ebuild
Gentoo

Contents of /www-servers/thttpd/thttpd-2.25b-r9.ebuild

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.2 - (show annotations) (download)
Wed Apr 4 15:05:37 2012 UTC (2 years ago) by blueness
Branch: MAIN
CVS Tags: HEAD
Changes since 1.1: +1 -1 lines
FILE REMOVED
Remove older ebuilds and patches migrated into forked code

(Portage version: 2.1.10.49/cvs/Linux x86_64)

1 # Copyright 1999-2012 Gentoo Foundation
2 # Distributed under the terms of the GNU General Public License v2
3 # $Header: /var/cvsroot/gentoo-x86/www-servers/thttpd/thttpd-2.25b-r9.ebuild,v 1.1 2012/03/24 02:59:02 blueness Exp $
4
5 EAPI="4"
6
7 WANT_AUTOCONF=2.1
8 inherit eutils flag-o-matic autotools
9
10 DESCRIPTION="Small and fast multiplexing webserver."
11 HOMEPAGE="http://www.acme.com/software/thttpd/"
12 SRC_URI="http://www.acme.com/software/thttpd/${P}.tar.gz"
13
14 LICENSE="BSD"
15 SLOT="0"
16 KEYWORDS="~amd64 ~hppa ~mips ~ppc ~sparc ~x86 ~x86-fbsd"
17 IUSE="static"
18
19 RDEPEND=""
20 DEPEND="sys-devel/autoconf:2.1"
21
22 THTTPD_USER=thttpd
23 THTTPD_GROUP=thttpd
24
25 src_prepare() {
26 epatch "${FILESDIR}"/${P}-additional-input-validation.patch
27 epatch "${FILESDIR}"/${P}-fix-buffer-overflow.patch
28 epatch "${FILESDIR}"/${P}-fix-insecure-tmp-creation.patch
29 epatch "${FILESDIR}"/${P}-glibc-2.10.patch
30 epatch "${FILESDIR}"/${P}-fix-illegal-path-info.patch
31 epatch "${FILESDIR}"/${P}-monolithic-timer.patch
32 epatch "${FILESDIR}"/${P}-use-Status-header.patch
33 epatch "${FILESDIR}"/${P}-use-X-Forwarded-For-header.patch
34 epatch "${FILESDIR}"/${P}-respect-CFLAGS--dont-link-static.patch
35 epatch "${FILESDIR}"/${P}-ogg-mime-type.patch
36 epatch "${FILESDIR}"/${P}-default-to-octet-stream.patch
37 eautoreconf
38 }
39
40 pkg_setup() {
41 ebegin "Creating thttpd user and group"
42 enewgroup ${THTTPD_GROUP}
43 enewuser ${THTTPD_USER} -1 -1 -1 ${THTTPD_GROUP}
44 eend ${?}
45 }
46
47 src_configure() {
48 use static && append-ldflags -static
49 tc-export CC
50 econf
51 }
52
53 src_install () {
54 dodir /usr/share/man/man1
55 make prefix="${ED}"/usr \
56 MANDIR="${ED}"/usr/share/man \
57 WEBGROUP=${THTTPD_GROUP} \
58 WEBDIR="${ED}"/var/www/localhost \
59 "$@" install || die "make install failed"
60
61 mv "${ED}"/usr/sbin/{,th_}htpasswd
62 mv "${ED}"/usr/share/man/man1/{,th_}htpasswd.1
63
64 newinitd "${FILESDIR}"/thttpd.init thttpd
65 newconfd "${FILESDIR}"/thttpd.confd thttpd
66
67 dodoc README INSTALL TODO
68
69 insinto /etc/logrotate.d
70 newins "${FILESDIR}/thttpd.logrotate" thttpd
71
72 insinto /etc/thttpd
73 doins "${FILESDIR}"/thttpd.conf.sample
74 }
75
76 pkg_postinst() {
77 elog "Adjust THTTPD_DOCROOT in /etc/conf.d/thttpd !"
78 }

  ViewVC Help
Powered by ViewVC 1.1.20