/[gentoo-x86]/www-servers/varnish/varnish-3.0.4-r1.ebuild
Gentoo

Contents of /www-servers/varnish/varnish-3.0.4-r1.ebuild

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.1 - (show annotations) (download)
Mon Jul 8 22:11:35 2013 UTC (14 months, 3 weeks ago) by blueness
Branch: MAIN
Add sanity test and reload functionality to init.d script, bug #475600

(Portage version: 2.1.12.2/cvs/Linux x86_64, signed Manifest commit with key 0xF52D4BBA)

1 # Copyright 1999-2013 Gentoo Foundation
2 # Distributed under the terms of the GNU General Public License v2
3 # $Header: /var/cvsroot/gentoo-x86/www-servers/varnish/varnish-3.0.4.ebuild,v 1.3 2013/06/21 12:51:35 blueness Exp $
4
5 EAPI="5"
6
7 inherit autotools-utils eutils
8
9 DESCRIPTION="Varnish is a state-of-the-art, high-performance HTTP accelerator"
10 HOMEPAGE="http://www.varnish-cache.org/"
11 SRC_URI="http://repo.varnish-cache.org/source/${P}.tar.gz"
12
13 LICENSE="BSD-2 GPL-2"
14 SLOT="0"
15 KEYWORDS="~amd64 ~mips ~x86"
16 IUSE="doc jemalloc jit static-libs +tools"
17
18 CDEPEND="
19 || ( dev-libs/libedit sys-libs/readline )
20 dev-libs/libpcre[jit?]
21 jemalloc? ( dev-libs/jemalloc )
22 tools? ( sys-libs/ncurses )"
23
24 #varnish compiles stuff at run time
25 RDEPEND="
26 ${CDEPEND}
27 sys-devel/gcc"
28
29 DEPEND="
30 ${CDEPEND}
31 virtual/pkgconfig"
32
33 RESTRICT="test" #315725
34
35 DOCS=( README doc/changes.rst )
36
37 PATCHES=(
38 "${FILESDIR}"/${PN}-3.0.4-fix-automake-1.13.patch
39 "${FILESDIR}"/${PN}-3.0.4-automagic.patch
40 "${FILESDIR}"/${PN}-3.0.3-pthread-uclibc.patch
41 )
42
43 AUTOTOOLS_AUTORECONF="yes"
44
45 src_prepare() {
46 # Remove bundled libjemalloc. We also fix
47 # automagic dep in our patches, bug #461638
48 rm -rf lib/libjemalloc
49
50 autotools-utils_src_prepare
51 }
52
53 src_configure() {
54 local myeconfargs=(
55 $(use_enable static-libs static)
56 $(use_enable jit pcre-jit )
57 $(use_with jemalloc)
58 $(use_with tools)
59 --without-rst2man
60 --without-rst2html
61 )
62 autotools-utils_src_configure
63 }
64
65 src_install() {
66 autotools-utils_src_install
67
68 newinitd "${FILESDIR}"/varnishd.initd-r1 varnishd
69 newconfd "${FILESDIR}"/varnishd.confd-r1 varnishd
70
71 insinto /etc/logrotate.d
72 newins "${FILESDIR}/varnishd.logrotate" varnishd
73
74 dodir /var/log/varnish
75
76 use doc && dohtml -r "doc/sphinx/=build/html/"
77 }
78
79 pkg_postinst () {
80 elog "No demo-/sample-configfile is included in the distribution. Please"
81 elog "read the man-page for more info. A sample configuration proxying"
82 elog "localhost:8080 for localhost:80 is given in /etc/conf.d/varnishd."
83 }

  ViewVC Help
Powered by ViewVC 1.1.20