x11-base/xorg-server/xorg-server-1.3.0.0-r1.ebuild

# Copyright 1999-2007 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/x11-base/xorg-server/xorg-server-1.3.0.0-r1.ebuild,v 1.11 2007/12/11 10:58:28 vapier Exp $

# Must be before x-modular eclass is inherited
SNAPSHOT="yes"

inherit x-modular multilib

OPENGL_DIR="xorg-x11"

MESA_PN="Mesa"
MESA_PV="6.5.2"
MESA_P="${MESA_PN}-${MESA_PV}"
MESA_SRC_P="${MESA_PN}Lib-${MESA_PV}"

SRC_URI="${SRC_URI}
        mirror://sourceforge/mesa3d/${MESA_SRC_P}.tar.bz2
        http://xorg.freedesktop.org/releases/individual/xserver/${P}.tar.bz2"
DESCRIPTION="X.Org X servers"
KEYWORDS="alpha amd64 arm hppa ia64 mips ppc ppc64 sh sparc x86 ~x86-fbsd"
IUSE_INPUT_DEVICES="
        input_devices_acecad
        input_devices_aiptek
        input_devices_calcomp
        input_devices_citron
        input_devices_digitaledge
        input_devices_dmc
        input_devices_dynapro
        input_devices_elo2300
        input_devices_elographics
        input_devices_evdev
        input_devices_fpit
        input_devices_hyperpen
        input_devices_jamstudio
        input_devices_joystick
        input_devices_keyboard
        input_devices_magellan
        input_devices_microtouch
        input_devices_mouse
        input_devices_mutouch
        input_devices_palmax
        input_devices_penmount
        input_devices_spaceorb
        input_devices_summa
        input_devices_tek4957
        input_devices_ur98
        input_devices_vmmouse
        input_devices_void

        input_devices_synaptics
        input_devices_wacom"
IUSE_VIDEO_CARDS="
        video_cards_apm
        video_cards_ark
        video_cards_chips
        video_cards_cirrus
        video_cards_cyrix
        video_cards_dummy
        video_cards_epson
        video_cards_fbdev
        video_cards_glint
        video_cards_i128
        video_cards_i740
        video_cards_i810
        video_cards_impact
        video_cards_imstt
        video_cards_mach64
        video_cards_mga
        video_cards_neomagic
        video_cards_newport
        video_cards_nsc
        video_cards_nv
        video_cards_r128
        video_cards_radeon
        video_cards_rendition
        video_cards_s3
        video_cards_s3virge
        video_cards_savage
        video_cards_siliconmotion
        video_cards_sis
        video_cards_sisusb
        video_cards_sunbw2
        video_cards_suncg14
        video_cards_suncg3
        video_cards_suncg6
        video_cards_sunffb
        video_cards_sunleo
        video_cards_suntcx
        video_cards_tdfx
        video_cards_tga
        video_cards_trident
        video_cards_tseng
        video_cards_v4l
        video_cards_vesa
        video_cards_vga
        video_cards_via
        video_cards_vmware
        video_cards_voodoo
        video_cards_fglrx
        video_cards_nvidia"
IUSE_SERVERS="dmx kdrive xorg"
IUSE="${IUSE_VIDEO_CARDS}
        ${IUSE_INPUT_DEVICES}
        ${IUSE_SERVERS}
        3dfx
        dri ipv6 minimal nptl sdl xprint"
RDEPEND=">=x11-libs/libXfont-1.2.5
        x11-libs/xtrans
        x11-libs/libXau
        x11-libs/libXext
        x11-libs/libX11
        x11-libs/libxkbfile
        x11-libs/libXdmcp
        x11-libs/libXmu
        <x11-libs/libXrender-0.9.3
        x11-libs/libXi
        media-libs/freetype
        >=media-libs/mesa-6.5.2
        media-fonts/font-adobe-75dpi
        media-fonts/font-misc-misc
        media-fonts/font-cursor-misc
        x11-misc/xbitmaps
        || ( x11-misc/xkeyboard-config x11-misc/xkbdata )
        x11-apps/iceauth
        x11-apps/rgb
        x11-apps/xauth
        x11-apps/xinit
        app-admin/eselect-opengl
        x11-libs/libXaw
        x11-libs/libXpm
        x11-libs/libXxf86misc
        x11-libs/libXxf86vm
        dmx? ( x11-libs/libdmx
                        x11-libs/libXfixes )
        !minimal? ( x11-libs/libXtst
                x11-libs/libXres )
        >=x11-libs/libxkbui-1.0.2
        x11-libs/liblbxutil
        kdrive? ( sdl? ( media-libs/libsdl ) )"
        # Xres is dmx-dependent, xkbui is xorgcfg-dependent
        # Xaw is dmx- and xorgcfg-dependent
        # Xpm is dmx- and xorgcfg-dependent, pulls in Xt
        # Xxf86misc and Xxf86vm are xorgcfg-dependent
        # liblbxutil is lbx- dependent
DEPEND="${RDEPEND}
        >=x11-proto/randrproto-1.2.1
        <x11-proto/renderproto-0.9.3
        >=x11-proto/fixesproto-4
        >=x11-proto/damageproto-1.1
        x11-proto/xextproto
        x11-proto/xproto
        x11-proto/xf86dgaproto
        x11-proto/xf86miscproto
        x11-proto/xf86rushproto
        x11-proto/xf86vidmodeproto
        x11-proto/xf86bigfontproto
        >=x11-proto/compositeproto-0.3
        x11-proto/recordproto
        x11-proto/resourceproto
        x11-proto/videoproto
        >=x11-proto/scrnsaverproto-1.1.0
        x11-proto/evieext
        x11-proto/trapproto
        >=x11-proto/xineramaproto-1.1-r1
        x11-proto/fontsproto
        >=x11-proto/kbproto-1.0.3
        x11-proto/inputproto
        x11-proto/bigreqsproto
        x11-proto/xcmiscproto
        >=x11-proto/glproto-1.4.8
        dmx? ( x11-proto/dmxproto )
        dri? ( x11-proto/xf86driproto
                >=x11-libs/libdrm-2.3 )
        xprint? ( x11-proto/printproto
                x11-apps/mkfontdir
                x11-apps/mkfontscale
                x11-apps/xplsprinters )"

# Drivers
PDEPEND="
        xorg? (
                input_devices_acecad? ( >=x11-drivers/xf86-input-acecad-1.1.0 )
                input_devices_aiptek? ( >=x11-drivers/xf86-input-aiptek-1.0.1 )
                input_devices_calcomp? ( >=x11-drivers/xf86-input-calcomp-1.1.0 )
                input_devices_citron? ( >=x11-drivers/xf86-input-citron-2.2.0 )
                input_devices_digitaledge? ( >=x11-drivers/xf86-input-digitaledge-1.1.0 )
                input_devices_dmc? ( >=x11-drivers/xf86-input-dmc-1.1.0 )
                input_devices_dynapro? ( >=x11-drivers/xf86-input-dynapro-1.1.0 )
                input_devices_elo2300? ( >=x11-drivers/xf86-input-elo2300-1.1.0 )
                input_devices_elographics? ( >=x11-drivers/xf86-input-elographics-1.1.0 )
                input_devices_evdev? ( >=x11-drivers/xf86-input-evdev-1.1.1 )
                input_devices_fpit? ( >=x11-drivers/xf86-input-fpit-1.1.0 )
                input_devices_hyperpen? ( >=x11-drivers/xf86-input-hyperpen-1.1.0 )
                input_devices_jamstudio? ( >=x11-drivers/xf86-input-jamstudio-1.1.0 )
                input_devices_joystick? ( >=x11-drivers/xf86-input-joystick-1.1.0 )
                input_devices_keyboard? ( =x11-drivers/xf86-input-keyboard-1.1* )
                input_devices_magellan? ( >=x11-drivers/xf86-input-magellan-1.1.0 )
                input_devices_microtouch? ( >=x11-drivers/xf86-input-microtouch-1.1.0 )
                input_devices_mouse? ( >=x11-drivers/xf86-input-mouse-1.1.0 )
                input_devices_mutouch? ( >=x11-drivers/xf86-input-mutouch-1.1.0 )
                input_devices_palmax? ( >=x11-drivers/xf86-input-palmax-1.1.0 )
                input_devices_penmount? ( >=x11-drivers/xf86-input-penmount-1.1.0 )
                input_devices_spaceorb? ( >=x11-drivers/xf86-input-spaceorb-1.1.0 )
                input_devices_summa? ( >=x11-drivers/xf86-input-summa-1.1.0 )
                input_devices_tek4957? ( >=x11-drivers/xf86-input-tek4957-1.1.0 )
                input_devices_ur98? ( >=x11-drivers/xf86-input-ur98-1.1.0 )
                input_devices_vmmouse? ( >=x11-drivers/xf86-input-vmmouse-12.4.0 )
                input_devices_void? ( >=x11-drivers/xf86-input-void-1.1.0 )

                input_devices_synaptics? ( x11-drivers/synaptics )
                input_devices_wacom? ( x11-drivers/linuxwacom )

                video_cards_apm? ( >=x11-drivers/xf86-video-apm-1.1.1 )
                video_cards_ark? ( >=x11-drivers/xf86-video-ark-0.6.0 )
                video_cards_chips? ( >=x11-drivers/xf86-video-chips-1.1.1 )
                video_cards_cirrus? ( >=x11-drivers/xf86-video-cirrus-1.1.0 )
                video_cards_cyrix? ( >=x11-drivers/xf86-video-cyrix-1.1.0 )
                video_cards_dummy? ( >=x11-drivers/xf86-video-dummy-0.2.0 )
                video_cards_fbdev? ( >=x11-drivers/xf86-video-fbdev-0.2.0 )
                video_cards_glint? ( >=x11-drivers/xf86-video-glint-1.1.1 )
                video_cards_i128? ( >=x11-drivers/xf86-video-i128-1.2.0 )
                video_cards_i740? ( >=x11-drivers/xf86-video-i740-1.1.0 )
                video_cards_i810? ( >=x11-drivers/xf86-video-i810-1.6.0 )
                video_cards_impact? ( >=x11-drivers/xf86-video-impact-0.2.0 )
                video_cards_imstt? ( >=x11-drivers/xf86-video-imstt-1.1.0 )
                video_cards_mach64? ( >=x11-drivers/xf86-video-ati-6.6.0 )
                video_cards_mga? ( >=x11-drivers/xf86-video-mga-1.4.1 )
                video_cards_neomagic? ( >=x11-drivers/xf86-video-neomagic-1.1.1 )
                video_cards_newport? ( >=x11-drivers/xf86-video-newport-0.2.0 )
                video_cards_nsc? ( >=x11-drivers/xf86-video-nsc-2.8.1 )
                video_cards_nv? ( >=x11-drivers/xf86-video-nv-1.1.1 )
                video_cards_r128? ( >=x11-drivers/xf86-video-ati-6.6.0 )
                video_cards_radeon? ( >=x11-drivers/xf86-video-ati-6.6.0 )
                video_cards_rendition? ( >=x11-drivers/xf86-video-rendition-4.1.0 )
                video_cards_s3? ( >=x11-drivers/xf86-video-s3-0.4.1 )
                video_cards_s3virge? ( >=x11-drivers/xf86-video-s3virge-1.9.1 )
                video_cards_savage? ( >=x11-drivers/xf86-video-savage-2.1.1 )
                video_cards_siliconmotion? ( >=x11-drivers/xf86-video-siliconmotion-1.4.1 )
                video_cards_sis? ( >=x11-drivers/xf86-video-sis-0.9.1 )
                video_cards_sisusb? ( >=x11-drivers/xf86-video-sisusb-0.8.1 )
                video_cards_sunbw2? ( >=x11-drivers/xf86-video-sunbw2-1.1.0 )
                video_cards_suncg14? ( >=x11-drivers/xf86-video-suncg14-1.1.0 )
                video_cards_suncg3? ( >=x11-drivers/xf86-video-suncg3-1.1.0 )
                video_cards_suncg6? ( >=x11-drivers/xf86-video-suncg6-1.1.0 )
                video_cards_sunffb? ( >=x11-drivers/xf86-video-sunffb-1.1.0 )
                video_cards_sunleo? ( >=x11-drivers/xf86-video-sunleo-1.1.0 )
                video_cards_suntcx? ( >=x11-drivers/xf86-video-suntcx-1.1.0 )
                video_cards_tdfx? ( >=x11-drivers/xf86-video-tdfx-1.2.1 )
                video_cards_tga? ( >=x11-drivers/xf86-video-tga-1.1.0 )
                video_cards_trident? ( >=x11-drivers/xf86-video-trident-1.2.1 )
                video_cards_tseng? ( >=x11-drivers/xf86-video-tseng-1.1.0 )
                video_cards_v4l? ( >=x11-drivers/xf86-video-v4l-0.1.1 )
                video_cards_vesa? ( >=x11-drivers/xf86-video-vesa-1.1.0 )
                video_cards_vga? ( >=x11-drivers/xf86-video-vga-4.1.0 )
                video_cards_via? ( >=x11-drivers/xf86-video-via-0.2.1 )
                video_cards_vmware? ( >=x11-drivers/xf86-video-vmware-10.13.0 )
                video_cards_voodoo? ( >=x11-drivers/xf86-video-voodoo-1.1.0 )
                video_cards_tdfx? ( 3dfx? ( >=media-libs/glide-v3-3.10 ) )
                video_cards_nvidia? ( x11-drivers/nvidia-drivers )
                video_cards_fglrx? ( >=x11-drivers/ati-drivers-8.37.6 )
        )"
LICENSE="${LICENSE} MIT"

PATCHES="
        ${FILESDIR}/use-composite-for-unequal-depths.patch
        ${FILESDIR}/1.2.0-fix-amd-cpu-detection.patch
        ${FILESDIR}/1.2.0-properly-free-device-devprivates-memory-leak-fix.patch
        ${FILESDIR}/1.2.0-typo-fix.patch
        ${FILESDIR}/1.2.0-zero-out-client-devprivates-on-allocation.patch
        ${FILESDIR}/1.3.0.0-use-proc-instead-of-sys.patch
        ${FILESDIR}/avoid-crash-on-minimized-xv-window.patch
        ${FILESDIR}/xorg-server-sam225bw-quirks.patch
        ${FILESDIR}/1.3-alpha-build-fix.patch
        ${FILESDIR}/1.3.0.0-xephyr_crash_at_exit.patch
        ${FILESDIR}/xorg-x11-server-1.0.1-fpic-libxf86config.patch
        "

pkg_setup() {
        use minimal || ensure_a_server_is_building

        # SDL only available in kdrive build
        if use kdrive && use sdl; then
                conf_opts="${conf_opts} --enable-xsdl"
        else
                conf_opts="${conf_opts} --disable-xsdl"
        fi

        # Only Xorg and Xgl support this, and we won't build Xgl
        # until it merges to trunk
        if use xorg; then
                conf_opts="${conf_opts} --with-mesa-source=${WORKDIR}/${MESA_P}"
        fi

        # localstatedir is used for the log location; we need to override the default
        # from ebuild.sh
        # sysconfdir is used for the xorg.conf location; same applies
        # --enable-install-setuid needed because sparcs default off
        CONFIGURE_OPTIONS="
                $(use_enable ipv6)
                $(use_enable dmx)
                $(use_enable kdrive)
                $(use_enable !minimal xvfb)
                $(use_enable !minimal xnest)
                $(use_enable !minimal install-libxf86config)
                $(use_enable dri)
                $(use_enable xorg)
                $(use_enable xprint)
                $(use_enable nptl glx-tls)
                $(use_enable !minimal xorgcfg)
                --sysconfdir=/etc/X11
                --localstatedir=/var
                --enable-install-setuid
                --with-fontdir=/usr/share/fonts
                ${conf_opts}"

        local diemsg="You must build xorg-server and mesa with the same nptl USE setting."
        if built_with_use media-libs/mesa nptl; then
                use nptl || die "${diemsg}"
        else
                use nptl && die "${diemsg}"
        fi

        # (#121394) Causes window corruption
        filter-flags -fweb

        # Nothing else provides new enough glxtokens.h
        ewarn "Forcing on xorg-x11 for new enough glxtokens.h..."
        OLD_IMPLEM="$(eselect opengl show)"
        eselect opengl set --impl-headers ${OPENGL_DIR}
}

src_unpack() {
        x-modular_specs_check
        x-modular_dri_check
        x-modular_unpack_source
        x-modular_patch_source

        # Set up kdrive servers to build
        if use kdrive; then
                kdrive_setup
        fi

        # Make sure eautoreconf gets run if we need the autoconf/make
        # changes.
        if [[ ${SNAPSHOT} != "yes" ]]; then
                if use kdrive; then
                        eautoreconf
                fi
        fi
        x-modular_reconf_source
}

src_install() {
        x-modular_src_install

        dynamic_libgl_install

        server_based_install

        # Install video mode files for system-config-display
        insinto /usr/share/xorg
        doins hw/xfree86/common/{extra,vesa}modes \
                || die "couldn't install extra modes"

        # Bug #151421 - this file is not built with USE="minimal"
        # Bug #151670 - this file is also not build if USE="-xorg"
        if ! use minimal &&     use xorg; then
                # Install xorg.conf.example
                insinto /etc/X11
                doins hw/xfree86/xorg.conf.example \
                        || die "couldn't install xorg.conf.example"
        fi
}

pkg_postinst() {
        switch_opengl_implem

        # Bug #135544
        ewarn "Users of reduced blanking now need:"
        ewarn "   Option \"ReducedBlanking\""
        ewarn "In the relevant Monitor section(s)."
        ewarn "Make sure your reduced blanking modelines are safe!"
}

pkg_postrm() {
        # Get rid of module dir to ensure opengl-update works properly
        if ! has_version x11-base/xorg-server; then
                if [[ -e ${ROOT}/usr/$(get_libdir)/xorg/modules ]]; then
                        rm -rf "${ROOT}"/usr/$(get_libdir)/xorg/modules
                fi
        fi
}

kdrive_setup() {
        local card real_card disable_card kdrive_fbdev kdrive_vesa

        einfo "Removing unused kdrive drivers ..."

        # Some kdrive servers require fbdev and vesa
        kdrive_fbdev="radeon neomagic sis siliconmotion"
        # Some kdrive servers require just vesa
        kdrive_vesa="chips mach64 mga nv glint r128 via"

        for card in ${IUSE_VIDEO_CARDS}; do
                real_card=${card#video_cards_}

                # Differences between VIDEO_CARDS name and kdrive server name
                real_card=${real_card/glint/pm2}
                real_card=${real_card/radeon/ati}
                real_card=${real_card/%nv/nvidia}
                real_card=${real_card/siliconmotion/smi}
                real_card=${real_card/%sis/sis300}

                disable_card=0

                # Check whether it's a valid kdrive server before we waste time
                # on the rest of this
                if ! grep -q -o "\b${real_card}\b" "${S}"/hw/kdrive/Makefile.am; then
                        continue
                fi

                if ! use ${card}; then
                        if use x86; then
                                # Some kdrive servers require fbdev and vesa
                                for i in ${kdrive_fbdev}; do
                                        if use video_cards_${i}; then
                                                if [[ ${real_card} = fbdev ]] \
                                                        || [[ ${real_card} = vesa ]]; then
                                                        continue 2 # Don't disable
                                                fi
                                                fi
                                done

                                # Some kdrive servers require just vesa
                                for i in ${kdrive_vesa}; do
                                        if use video_cards_${i}; then
                                                if [[ ${real_card} = vesa ]]; then
                                                        continue 2 # Don't disable
                                                fi
                                        fi
                                done
                        fi
                        disable_card=1
                # Bug #150052
                # fbdev is the only VIDEO_CARDS setting that works on non-x86
                elif ! use x86 \
                        && [[ ${real_card} != fbdev ]]; then
                        ewarn "  $real_card does not work on your architecture; disabling."
                        disable_card=1
                fi

                if [[ $disable_card = 1 ]]; then
                        ebegin "  ${real_card}"
                        sed -i \
                                -e "s:\b${real_card}\b::g" \
                                "${S}"/hw/kdrive/Makefile.am \
                                || die "sed of ${real_card} failed"
                        eend
                fi

        done

        # smi and via are the only things on line 2. If line 2 ends up blank,
        # we need to get rid of the backslash at the end of line 1.
        if ! use video_cards_siliconmotion && ! use video_cards_via; then
                sed -i \
                        -e "s:^\(VESA_SUBDIRS.*\)\\\:\1:g" \
                        "${S}"/hw/kdrive/Makefile.am
        fi
}

dynamic_libgl_install() {
        # next section is to setup the dynamic libGL stuff
        ebegin "Moving GL files for dynamic switching"
                dodir /usr/$(get_libdir)/opengl/${OPENGL_DIR}/extensions
                local x=""
                for x in "${D}"/usr/$(get_libdir)/xorg/modules/extensions/libglx*; do
                        if [ -f ${x} -o -L ${x} ]; then
                                mv -f ${x} "${D}"/usr/$(get_libdir)/opengl/${OPENGL_DIR}/extensions
                        fi
                done
        eend 0
}

server_based_install() {
        use xprint && xprint_src_install

        if ! use xorg; then
                rm "${D}"/usr/share/man/man1/Xserver.1x \
                        "${D}"/usr/$(get_libdir)/xserver/SecurityPolicy \
                        "${D}"/usr/$(get_libdir)/pkgconfig/xorg-server.pc \
                        "${D}"/usr/share/man/man1/Xserver.1x
        fi
}

switch_opengl_implem() {
                # Switch to the xorg implementation.
                # Use new opengl-update that will not reset user selected
                # OpenGL interface ...
                echo
#               eselect opengl set --use-old ${OPENGL_DIR}
                eselect opengl set ${OLD_IMPLEM}
}

xprint_src_install() {
        # RH-style init script, we provide a wrapper
        exeinto /usr/$(get_libdir)/misc
        doexe "${S}"/hw/xprint/etc/init.d/xprint
        # Install the wrapper
        newinitd "${FILESDIR}"/xprint.init xprint
        # Install profile scripts
        insinto /etc/profile.d
        doins "${S}"/hw/xprint/etc/profile.d/xprint*
        insinto /etc/X11/xinit/xinitrc.d
        doins "${S}"/hw/xprint/etc/Xsession.d/92xprint-xpserverlist
        # Patch profile scripts
        sed -e "s:/bin/sh.*get_xpserverlist:/usr/$(get_libdir)/misc/xprint \
                get_xpserverlist:g" -i "${D}"/etc/profile.d/xprint* \
                "${D}"/etc/X11/xinit/xinitrc.d/92xprint-xpserverlist
        # Move profile scripts, we can't touch /etc/profile.d/ in Gentoo
        dodoc "${D}"/etc/profile.d/xprint*
        rm -f "${D}"/etc/profile.d/xprint*
}

ensure_a_server_is_building() {
        for server in ${IUSE_SERVERS}; do
                use ${server} && return;
        done
        eerror "You need to specify at least one server to build."
        eerror "Valid servers are: ${IUSE_SERVERS}."
        die "No servers were specified to build."
}
1	# Copyright 1999-2007 Gentoo Foundation
2	# Distributed under the terms of the GNU General Public License v2
3	# $Header: /var/cvsroot/gentoo-x86/x11-base/xorg-server/xorg-server-1.3.0.0-r1.ebuild,v 1.11 2007/12/11 10:58:28 vapier Exp $
4
5	# Must be before x-modular eclass is inherited
6	SNAPSHOT="yes"
7
8	inherit x-modular multilib
9
10	OPENGL_DIR="xorg-x11"
11
12	MESA_PN="Mesa"
13	MESA_PV="6.5.2"
14	MESA_P="${MESA_PN}-${MESA_PV}"
15	MESA_SRC_P="${MESA_PN}Lib-${MESA_PV}"
16
17	SRC_URI="${SRC_URI}
18	mirror://sourceforge/mesa3d/${MESA_SRC_P}.tar.bz2
19	http://xorg.freedesktop.org/releases/individual/xserver/${P}.tar.bz2"
20	DESCRIPTION="X.Org X servers"
21	KEYWORDS="alpha amd64 arm hppa ia64 mips ppc ppc64 sh sparc x86 ~x86-fbsd"
22	IUSE_INPUT_DEVICES="
23	input_devices_acecad
24	input_devices_aiptek
25	input_devices_calcomp
26	input_devices_citron
27	input_devices_digitaledge
28	input_devices_dmc
29	input_devices_dynapro
30	input_devices_elo2300
31	input_devices_elographics
32	input_devices_evdev
33	input_devices_fpit
34	input_devices_hyperpen
35	input_devices_jamstudio
36	input_devices_joystick
37	input_devices_keyboard
38	input_devices_magellan
39	input_devices_microtouch
40	input_devices_mouse
41	input_devices_mutouch
42	input_devices_palmax
43	input_devices_penmount
44	input_devices_spaceorb
45	input_devices_summa
46	input_devices_tek4957
47	input_devices_ur98
48	input_devices_vmmouse
49	input_devices_void
50
51	input_devices_synaptics
52	input_devices_wacom"
53	IUSE_VIDEO_CARDS="
54	video_cards_apm
55	video_cards_ark
56	video_cards_chips
57	video_cards_cirrus
58	video_cards_cyrix
59	video_cards_dummy
60	video_cards_epson
61	video_cards_fbdev
62	video_cards_glint
63	video_cards_i128
64	video_cards_i740
65	video_cards_i810
66	video_cards_impact
67	video_cards_imstt
68	video_cards_mach64
69	video_cards_mga
70	video_cards_neomagic
71	video_cards_newport
72	video_cards_nsc
73	video_cards_nv
74	video_cards_r128
75	video_cards_radeon
76	video_cards_rendition
77	video_cards_s3
78	video_cards_s3virge
79	video_cards_savage
80	video_cards_siliconmotion
81	video_cards_sis
82	video_cards_sisusb
83	video_cards_sunbw2
84	video_cards_suncg14
85	video_cards_suncg3
86	video_cards_suncg6
87	video_cards_sunffb
88	video_cards_sunleo
89	video_cards_suntcx
90	video_cards_tdfx
91	video_cards_tga
92	video_cards_trident
93	video_cards_tseng
94	video_cards_v4l
95	video_cards_vesa
96	video_cards_vga
97	video_cards_via
98	video_cards_vmware
99	video_cards_voodoo
100	video_cards_fglrx
101	video_cards_nvidia"
102	IUSE_SERVERS="dmx kdrive xorg"
103	IUSE="${IUSE_VIDEO_CARDS}
104	${IUSE_INPUT_DEVICES}
105	${IUSE_SERVERS}
106	3dfx
107	dri ipv6 minimal nptl sdl xprint"
108	RDEPEND=">=x11-libs/libXfont-1.2.5
109	x11-libs/xtrans
110	x11-libs/libXau
111	x11-libs/libXext
112	x11-libs/libX11
113	x11-libs/libxkbfile
114	x11-libs/libXdmcp
115	x11-libs/libXmu
116	<x11-libs/libXrender-0.9.3
117	x11-libs/libXi
118	media-libs/freetype
119	>=media-libs/mesa-6.5.2
120	media-fonts/font-adobe-75dpi
121	media-fonts/font-misc-misc
122	media-fonts/font-cursor-misc
123	x11-misc/xbitmaps
124	\|\| ( x11-misc/xkeyboard-config x11-misc/xkbdata )
125	x11-apps/iceauth
126	x11-apps/rgb
127	x11-apps/xauth
128	x11-apps/xinit
129	app-admin/eselect-opengl
130	x11-libs/libXaw
131	x11-libs/libXpm
132	x11-libs/libXxf86misc
133	x11-libs/libXxf86vm
134	dmx? ( x11-libs/libdmx
135	x11-libs/libXfixes )
136	!minimal? ( x11-libs/libXtst
137	x11-libs/libXres )
138	>=x11-libs/libxkbui-1.0.2
139	x11-libs/liblbxutil
140	kdrive? ( sdl? ( media-libs/libsdl ) )"
141	# Xres is dmx-dependent, xkbui is xorgcfg-dependent
142	# Xaw is dmx- and xorgcfg-dependent
143	# Xpm is dmx- and xorgcfg-dependent, pulls in Xt
144	# Xxf86misc and Xxf86vm are xorgcfg-dependent
145	# liblbxutil is lbx- dependent
146	DEPEND="${RDEPEND}
147	>=x11-proto/randrproto-1.2.1
148	<x11-proto/renderproto-0.9.3
149	>=x11-proto/fixesproto-4
150	>=x11-proto/damageproto-1.1
151	x11-proto/xextproto
152	x11-proto/xproto
153	x11-proto/xf86dgaproto
154	x11-proto/xf86miscproto
155	x11-proto/xf86rushproto
156	x11-proto/xf86vidmodeproto
157	x11-proto/xf86bigfontproto
158	>=x11-proto/compositeproto-0.3
159	x11-proto/recordproto
160	x11-proto/resourceproto
161	x11-proto/videoproto
162	>=x11-proto/scrnsaverproto-1.1.0
163	x11-proto/evieext
164	x11-proto/trapproto
165	>=x11-proto/xineramaproto-1.1-r1
166	x11-proto/fontsproto
167	>=x11-proto/kbproto-1.0.3
168	x11-proto/inputproto
169	x11-proto/bigreqsproto
170	x11-proto/xcmiscproto
171	>=x11-proto/glproto-1.4.8
172	dmx? ( x11-proto/dmxproto )
173	dri? ( x11-proto/xf86driproto
174	>=x11-libs/libdrm-2.3 )
175	xprint? ( x11-proto/printproto
176	x11-apps/mkfontdir
177	x11-apps/mkfontscale
178	x11-apps/xplsprinters )"
179
180	# Drivers
181	PDEPEND="
182	xorg? (
183	input_devices_acecad? ( >=x11-drivers/xf86-input-acecad-1.1.0 )
184	input_devices_aiptek? ( >=x11-drivers/xf86-input-aiptek-1.0.1 )
185	input_devices_calcomp? ( >=x11-drivers/xf86-input-calcomp-1.1.0 )
186	input_devices_citron? ( >=x11-drivers/xf86-input-citron-2.2.0 )
187	input_devices_digitaledge? ( >=x11-drivers/xf86-input-digitaledge-1.1.0 )
188	input_devices_dmc? ( >=x11-drivers/xf86-input-dmc-1.1.0 )
189	input_devices_dynapro? ( >=x11-drivers/xf86-input-dynapro-1.1.0 )
190	input_devices_elo2300? ( >=x11-drivers/xf86-input-elo2300-1.1.0 )
191	input_devices_elographics? ( >=x11-drivers/xf86-input-elographics-1.1.0 )
192	input_devices_evdev? ( >=x11-drivers/xf86-input-evdev-1.1.1 )
193	input_devices_fpit? ( >=x11-drivers/xf86-input-fpit-1.1.0 )
194	input_devices_hyperpen? ( >=x11-drivers/xf86-input-hyperpen-1.1.0 )
195	input_devices_jamstudio? ( >=x11-drivers/xf86-input-jamstudio-1.1.0 )
196	input_devices_joystick? ( >=x11-drivers/xf86-input-joystick-1.1.0 )
197	input_devices_keyboard? ( =x11-drivers/xf86-input-keyboard-1.1* )
198	input_devices_magellan? ( >=x11-drivers/xf86-input-magellan-1.1.0 )
199	input_devices_microtouch? ( >=x11-drivers/xf86-input-microtouch-1.1.0 )
200	input_devices_mouse? ( >=x11-drivers/xf86-input-mouse-1.1.0 )
201	input_devices_mutouch? ( >=x11-drivers/xf86-input-mutouch-1.1.0 )
202	input_devices_palmax? ( >=x11-drivers/xf86-input-palmax-1.1.0 )
203	input_devices_penmount? ( >=x11-drivers/xf86-input-penmount-1.1.0 )
204	input_devices_spaceorb? ( >=x11-drivers/xf86-input-spaceorb-1.1.0 )
205	input_devices_summa? ( >=x11-drivers/xf86-input-summa-1.1.0 )
206	input_devices_tek4957? ( >=x11-drivers/xf86-input-tek4957-1.1.0 )
207	input_devices_ur98? ( >=x11-drivers/xf86-input-ur98-1.1.0 )
208	input_devices_vmmouse? ( >=x11-drivers/xf86-input-vmmouse-12.4.0 )
209	input_devices_void? ( >=x11-drivers/xf86-input-void-1.1.0 )
210
211	input_devices_synaptics? ( x11-drivers/synaptics )
212	input_devices_wacom? ( x11-drivers/linuxwacom )
213
214	video_cards_apm? ( >=x11-drivers/xf86-video-apm-1.1.1 )
215	video_cards_ark? ( >=x11-drivers/xf86-video-ark-0.6.0 )
216	video_cards_chips? ( >=x11-drivers/xf86-video-chips-1.1.1 )
217	video_cards_cirrus? ( >=x11-drivers/xf86-video-cirrus-1.1.0 )
218	video_cards_cyrix? ( >=x11-drivers/xf86-video-cyrix-1.1.0 )
219	video_cards_dummy? ( >=x11-drivers/xf86-video-dummy-0.2.0 )
220	video_cards_fbdev? ( >=x11-drivers/xf86-video-fbdev-0.2.0 )
221	video_cards_glint? ( >=x11-drivers/xf86-video-glint-1.1.1 )
222	video_cards_i128? ( >=x11-drivers/xf86-video-i128-1.2.0 )
223	video_cards_i740? ( >=x11-drivers/xf86-video-i740-1.1.0 )
224	video_cards_i810? ( >=x11-drivers/xf86-video-i810-1.6.0 )
225	video_cards_impact? ( >=x11-drivers/xf86-video-impact-0.2.0 )
226	video_cards_imstt? ( >=x11-drivers/xf86-video-imstt-1.1.0 )
227	video_cards_mach64? ( >=x11-drivers/xf86-video-ati-6.6.0 )
228	video_cards_mga? ( >=x11-drivers/xf86-video-mga-1.4.1 )
229	video_cards_neomagic? ( >=x11-drivers/xf86-video-neomagic-1.1.1 )
230	video_cards_newport? ( >=x11-drivers/xf86-video-newport-0.2.0 )
231	video_cards_nsc? ( >=x11-drivers/xf86-video-nsc-2.8.1 )
232	video_cards_nv? ( >=x11-drivers/xf86-video-nv-1.1.1 )
233	video_cards_r128? ( >=x11-drivers/xf86-video-ati-6.6.0 )
234	video_cards_radeon? ( >=x11-drivers/xf86-video-ati-6.6.0 )
235	video_cards_rendition? ( >=x11-drivers/xf86-video-rendition-4.1.0 )
236	video_cards_s3? ( >=x11-drivers/xf86-video-s3-0.4.1 )
237	video_cards_s3virge? ( >=x11-drivers/xf86-video-s3virge-1.9.1 )
238	video_cards_savage? ( >=x11-drivers/xf86-video-savage-2.1.1 )
239	video_cards_siliconmotion? ( >=x11-drivers/xf86-video-siliconmotion-1.4.1 )
240	video_cards_sis? ( >=x11-drivers/xf86-video-sis-0.9.1 )
241	video_cards_sisusb? ( >=x11-drivers/xf86-video-sisusb-0.8.1 )
242	video_cards_sunbw2? ( >=x11-drivers/xf86-video-sunbw2-1.1.0 )
243	video_cards_suncg14? ( >=x11-drivers/xf86-video-suncg14-1.1.0 )
244	video_cards_suncg3? ( >=x11-drivers/xf86-video-suncg3-1.1.0 )
245	video_cards_suncg6? ( >=x11-drivers/xf86-video-suncg6-1.1.0 )
246	video_cards_sunffb? ( >=x11-drivers/xf86-video-sunffb-1.1.0 )
247	video_cards_sunleo? ( >=x11-drivers/xf86-video-sunleo-1.1.0 )
248	video_cards_suntcx? ( >=x11-drivers/xf86-video-suntcx-1.1.0 )
249	video_cards_tdfx? ( >=x11-drivers/xf86-video-tdfx-1.2.1 )
250	video_cards_tga? ( >=x11-drivers/xf86-video-tga-1.1.0 )
251	video_cards_trident? ( >=x11-drivers/xf86-video-trident-1.2.1 )
252	video_cards_tseng? ( >=x11-drivers/xf86-video-tseng-1.1.0 )
253	video_cards_v4l? ( >=x11-drivers/xf86-video-v4l-0.1.1 )
254	video_cards_vesa? ( >=x11-drivers/xf86-video-vesa-1.1.0 )
255	video_cards_vga? ( >=x11-drivers/xf86-video-vga-4.1.0 )
256	video_cards_via? ( >=x11-drivers/xf86-video-via-0.2.1 )
257	video_cards_vmware? ( >=x11-drivers/xf86-video-vmware-10.13.0 )
258	video_cards_voodoo? ( >=x11-drivers/xf86-video-voodoo-1.1.0 )
259	video_cards_tdfx? ( 3dfx? ( >=media-libs/glide-v3-3.10 ) )
260	video_cards_nvidia? ( x11-drivers/nvidia-drivers )
261	video_cards_fglrx? ( >=x11-drivers/ati-drivers-8.37.6 )
262	)"
263	LICENSE="${LICENSE} MIT"
264
265	PATCHES="
266	${FILESDIR}/use-composite-for-unequal-depths.patch
267	${FILESDIR}/1.2.0-fix-amd-cpu-detection.patch
268	${FILESDIR}/1.2.0-properly-free-device-devprivates-memory-leak-fix.patch
269	${FILESDIR}/1.2.0-typo-fix.patch
270	${FILESDIR}/1.2.0-zero-out-client-devprivates-on-allocation.patch
271	${FILESDIR}/1.3.0.0-use-proc-instead-of-sys.patch
272	${FILESDIR}/avoid-crash-on-minimized-xv-window.patch
273	${FILESDIR}/xorg-server-sam225bw-quirks.patch
274	${FILESDIR}/1.3-alpha-build-fix.patch
275	${FILESDIR}/1.3.0.0-xephyr_crash_at_exit.patch
276	${FILESDIR}/xorg-x11-server-1.0.1-fpic-libxf86config.patch
277	"
278
279	pkg_setup() {
280	use minimal \|\| ensure_a_server_is_building
281
282	# SDL only available in kdrive build
283	if use kdrive && use sdl; then
284	conf_opts="${conf_opts} --enable-xsdl"
285	else
286	conf_opts="${conf_opts} --disable-xsdl"
287	fi
288
289	# Only Xorg and Xgl support this, and we won't build Xgl
290	# until it merges to trunk
291	if use xorg; then
292	conf_opts="${conf_opts} --with-mesa-source=${WORKDIR}/${MESA_P}"
293	fi
294
295	# localstatedir is used for the log location; we need to override the default
296	# from ebuild.sh
297	# sysconfdir is used for the xorg.conf location; same applies
298	# --enable-install-setuid needed because sparcs default off
299	CONFIGURE_OPTIONS="
300	$(use_enable ipv6)
301	$(use_enable dmx)
302	$(use_enable kdrive)
303	$(use_enable !minimal xvfb)
304	$(use_enable !minimal xnest)
305	$(use_enable !minimal install-libxf86config)
306	$(use_enable dri)
307	$(use_enable xorg)
308	$(use_enable xprint)
309	$(use_enable nptl glx-tls)
310	$(use_enable !minimal xorgcfg)
311	--sysconfdir=/etc/X11
312	--localstatedir=/var
313	--enable-install-setuid
314	--with-fontdir=/usr/share/fonts
315	${conf_opts}"
316
317	local diemsg="You must build xorg-server and mesa with the same nptl USE setting."
318	if built_with_use media-libs/mesa nptl; then
319	use nptl \|\| die "${diemsg}"
320	else
321	use nptl && die "${diemsg}"
322	fi
323
324	# (#121394) Causes window corruption
325	filter-flags -fweb
326
327	# Nothing else provides new enough glxtokens.h
328	ewarn "Forcing on xorg-x11 for new enough glxtokens.h..."
329	OLD_IMPLEM="$(eselect opengl show)"
330	eselect opengl set --impl-headers ${OPENGL_DIR}
331	}
332
333	src_unpack() {
334	x-modular_specs_check
335	x-modular_dri_check
336	x-modular_unpack_source
337	x-modular_patch_source
338
339	# Set up kdrive servers to build
340	if use kdrive; then
341	kdrive_setup
342	fi
343
344	# Make sure eautoreconf gets run if we need the autoconf/make
345	# changes.
346	if [[ ${SNAPSHOT} != "yes" ]]; then
347	if use kdrive; then
348	eautoreconf
349	fi
350	fi
351	x-modular_reconf_source
352	}
353
354	src_install() {
355	x-modular_src_install
356
357	dynamic_libgl_install
358
359	server_based_install
360
361	# Install video mode files for system-config-display
362	insinto /usr/share/xorg
363	doins hw/xfree86/common/{extra,vesa}modes \
364	\|\| die "couldn't install extra modes"
365
366	# Bug #151421 - this file is not built with USE="minimal"
367	# Bug #151670 - this file is also not build if USE="-xorg"
368	if ! use minimal && use xorg; then
369	# Install xorg.conf.example
370	insinto /etc/X11
371	doins hw/xfree86/xorg.conf.example \
372	\|\| die "couldn't install xorg.conf.example"
373	fi
374	}
375
376	pkg_postinst() {
377	switch_opengl_implem
378
379	# Bug #135544
380	ewarn "Users of reduced blanking now need:"
381	ewarn " Option \"ReducedBlanking\""
382	ewarn "In the relevant Monitor section(s)."
383	ewarn "Make sure your reduced blanking modelines are safe!"
384	}
385
386	pkg_postrm() {
387	# Get rid of module dir to ensure opengl-update works properly
388	if ! has_version x11-base/xorg-server; then
389	if [[ -e ${ROOT}/usr/$(get_libdir)/xorg/modules ]]; then
390	rm -rf "${ROOT}"/usr/$(get_libdir)/xorg/modules
391	fi
392	fi
393	}
394
395	kdrive_setup() {
396	local card real_card disable_card kdrive_fbdev kdrive_vesa
397
398	einfo "Removing unused kdrive drivers ..."
399
400	# Some kdrive servers require fbdev and vesa
401	kdrive_fbdev="radeon neomagic sis siliconmotion"
402	# Some kdrive servers require just vesa
403	kdrive_vesa="chips mach64 mga nv glint r128 via"
404
405	for card in ${IUSE_VIDEO_CARDS}; do
406	real_card=${card#video_cards_}
407
408	# Differences between VIDEO_CARDS name and kdrive server name
409	real_card=${real_card/glint/pm2}
410	real_card=${real_card/radeon/ati}
411	real_card=${real_card/%nv/nvidia}
412	real_card=${real_card/siliconmotion/smi}
413	real_card=${real_card/%sis/sis300}
414
415	disable_card=0
416
417	# Check whether it's a valid kdrive server before we waste time
418	# on the rest of this
419	if ! grep -q -o "\b${real_card}\b" "${S}"/hw/kdrive/Makefile.am; then
420	continue
421	fi
422
423	if ! use ${card}; then
424	if use x86; then
425	# Some kdrive servers require fbdev and vesa
426	for i in ${kdrive_fbdev}; do
427	if use video_cards_${i}; then
428	if [[ ${real_card} = fbdev ]] \
429	\|\| [[ ${real_card} = vesa ]]; then
430	continue 2 # Don't disable
431	fi
432	fi
433	done
434
435	# Some kdrive servers require just vesa
436	for i in ${kdrive_vesa}; do
437	if use video_cards_${i}; then
438	if [[ ${real_card} = vesa ]]; then
439	continue 2 # Don't disable
440	fi
441	fi
442	done
443	fi
444	disable_card=1
445	# Bug #150052
446	# fbdev is the only VIDEO_CARDS setting that works on non-x86
447	elif ! use x86 \
448	&& [[ ${real_card} != fbdev ]]; then
449	ewarn " $real_card does not work on your architecture; disabling."
450	disable_card=1
451	fi
452
453	if [[ $disable_card = 1 ]]; then
454	ebegin " ${real_card}"
455	sed -i \
456	-e "s:\b${real_card}\b::g" \
457	"${S}"/hw/kdrive/Makefile.am \
458	\|\| die "sed of ${real_card} failed"
459	eend
460	fi
461
462	done
463
464	# smi and via are the only things on line 2. If line 2 ends up blank,
465	# we need to get rid of the backslash at the end of line 1.
466	if ! use video_cards_siliconmotion && ! use video_cards_via; then
467	sed -i \
468	-e "s:^\(VESA_SUBDIRS.*\)\\\:\1:g" \
469	"${S}"/hw/kdrive/Makefile.am
470	fi
471	}
472
473	dynamic_libgl_install() {
474	# next section is to setup the dynamic libGL stuff
475	ebegin "Moving GL files for dynamic switching"
476	dodir /usr/$(get_libdir)/opengl/${OPENGL_DIR}/extensions
477	local x=""
478	for x in "${D}"/usr/$(get_libdir)/xorg/modules/extensions/libglx*; do
479	if [ -f ${x} -o -L ${x} ]; then
480	mv -f ${x} "${D}"/usr/$(get_libdir)/opengl/${OPENGL_DIR}/extensions
481	fi
482	done
483	eend 0
484	}
485
486	server_based_install() {
487	use xprint && xprint_src_install
488
489	if ! use xorg; then
490	rm "${D}"/usr/share/man/man1/Xserver.1x \
491	"${D}"/usr/$(get_libdir)/xserver/SecurityPolicy \
492	"${D}"/usr/$(get_libdir)/pkgconfig/xorg-server.pc \
493	"${D}"/usr/share/man/man1/Xserver.1x
494	fi
495	}
496
497	switch_opengl_implem() {
498	# Switch to the xorg implementation.
499	# Use new opengl-update that will not reset user selected
500	# OpenGL interface ...
501	echo
502	# eselect opengl set --use-old ${OPENGL_DIR}
503	eselect opengl set ${OLD_IMPLEM}
504	}
505
506	xprint_src_install() {
507	# RH-style init script, we provide a wrapper
508	exeinto /usr/$(get_libdir)/misc
509	doexe "${S}"/hw/xprint/etc/init.d/xprint
510	# Install the wrapper
511	newinitd "${FILESDIR}"/xprint.init xprint
512	# Install profile scripts
513	insinto /etc/profile.d
514	doins "${S}"/hw/xprint/etc/profile.d/xprint*
515	insinto /etc/X11/xinit/xinitrc.d
516	doins "${S}"/hw/xprint/etc/Xsession.d/92xprint-xpserverlist
517	# Patch profile scripts
518	sed -e "s:/bin/sh.*get_xpserverlist:/usr/$(get_libdir)/misc/xprint \
519	get_xpserverlist:g" -i "${D}"/etc/profile.d/xprint* \
520	"${D}"/etc/X11/xinit/xinitrc.d/92xprint-xpserverlist
521	# Move profile scripts, we can't touch /etc/profile.d/ in Gentoo
522	dodoc "${D}"/etc/profile.d/xprint*
523	rm -f "${D}"/etc/profile.d/xprint*
524	}
525
526	ensure_a_server_is_building() {
527	for server in ${IUSE_SERVERS}; do
528	use ${server} && return;
529	done
530	eerror "You need to specify at least one server to build."
531	eerror "Valid servers are: ${IUSE_SERVERS}."
532	die "No servers were specified to build."
533	}