/[gentoo-x86]/x11-base/xorg-server/xorg-server-1.6.5.ebuild
Gentoo

Contents of /x11-base/xorg-server/xorg-server-1.6.5.ebuild

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.1 - (hide annotations) (download)
Mon Oct 12 08:19:07 2009 UTC (4 years, 11 months ago) by remi
Branch: MAIN
x11-base/xorg-server: bump to 1.6.5, has the DGA fix
(Portage version: 2.2_rc45/cvs/Linux i686)

1 remi 1.1 # Copyright 1999-2009 Gentoo Foundation
2     # Distributed under the terms of the GNU General Public License v2
3     # $Header: /var/cvsroot/gentoo-x86/x11-base/xorg-server/xorg-server-1.6.4.ebuild,v 1.2 2009/10/02 14:10:00 remi Exp $
4    
5     EAPI="2"
6    
7     # Must be before x-modular eclass is inherited
8     #SNAPSHOT="yes"
9    
10     inherit x-modular multilib versionator
11    
12     SRC_URI="${SRC_URI}"
13     # mirror://gentoo/${P}-gentoo-patches-01.tar.bz2
14    
15     OPENGL_DIR="xorg-x11"
16    
17     DESCRIPTION="X.Org X servers"
18     KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sh ~sparc ~x86 ~x86-fbsd"
19    
20     IUSE_SERVERS="dmx kdrive xorg"
21     IUSE="${IUSE_SERVERS} tslib hal ipv6 minimal nptl sdl"
22     RDEPEND="hal? ( sys-apps/hal )
23     tslib? ( >=x11-libs/tslib-1.0 x11-proto/xcalibrateproto )
24     dev-libs/openssl
25     >=x11-libs/libXfont-1.4.0
26     >=x11-libs/xtrans-1.2.3
27     >=x11-libs/libXau-1.0.4
28     >=x11-libs/libXext-1.0.4
29     >=x11-libs/libX11-1.1.5
30     >=x11-libs/libxkbfile-1.0.4
31     >=x11-libs/libXdmcp-1.0.2
32     >=x11-libs/libXmu-1.0.3
33     >=x11-libs/libXrender-0.9.4
34     >=x11-libs/libXi-1.2.1
35     >=x11-libs/pixman-0.14.0
36     media-libs/freetype
37     >=x11-misc/xbitmaps-1.0.1
38     >=x11-misc/xkeyboard-config-1.4
39     x11-apps/xkbcomp
40     >=x11-apps/iceauth-1.0.2
41     >=x11-apps/rgb-1.0.3
42     >=x11-apps/xauth-1.0.3
43     >=x11-apps/xinit-1.0.8-r3
44     >=app-admin/eselect-opengl-1.0.8
45     >=x11-libs/libXaw-1.0.5
46     >=x11-libs/libXpm-3.5.7
47     >=x11-libs/libpciaccess-0.10.3
48     dmx? (
49     >=x11-libs/libdmx-1.0.2
50     >=x11-libs/libXfixes-4.0.3
51     )
52     !minimal? (
53     >=x11-libs/libXtst-1.0.3
54     >=x11-libs/libXres-1.0.3
55     >=media-libs/mesa-7.3_rc1[nptl=]
56     )
57     >=x11-libs/libxkbui-1.0.2
58     kdrive? ( sdl? ( media-libs/libsdl ) )"
59     # Xres is dmx-dependent
60     # Xaw is dmx-dependent
61     # Xpm is dmx-dependent, pulls in Xt
62     # xkbcomp is launched at startup but not checked by ./configure
63     DEPEND="${RDEPEND}
64     !net-dialup/dtrace
65     sys-devel/flex
66     >=x11-proto/randrproto-1.2.99.4
67     >=x11-proto/renderproto-0.9.3
68     >=x11-proto/fixesproto-4
69     >=x11-proto/damageproto-1.1
70     >=x11-proto/xextproto-7.0.4
71     >=x11-proto/xproto-7.0.14
72     >=x11-proto/xf86dgaproto-2.0.3
73     >=x11-proto/xf86rushproto-1.1.2
74     >=x11-proto/xf86vidmodeproto-2.2.2
75     >=x11-proto/compositeproto-0.4
76     >=x11-proto/recordproto-1.13.2
77     >=x11-proto/resourceproto-1.0.2
78     >=x11-proto/videoproto-2.2.2
79     >=x11-proto/scrnsaverproto-1.1.0
80     >=x11-proto/trapproto-3.4.3
81     >=x11-proto/xineramaproto-1.1.2
82     >=x11-proto/fontsproto-2.0.2
83     >=x11-proto/kbproto-1.0.3
84     >=x11-proto/inputproto-1.5.0
85     >=x11-proto/bigreqsproto-1.0.2
86     >=x11-proto/xcmiscproto-1.1.2
87     >=x11-proto/glproto-1.4.9
88     dmx? ( >=x11-proto/dmxproto-2.2.2 )
89     !minimal? (
90     >=x11-proto/xf86driproto-2.0.4
91     >=x11-proto/dri2proto-2.1
92     >=x11-libs/libdrm-2.3
93     )"
94    
95     PDEPEND="xorg? ( >=x11-base/xorg-drivers-$(get_version_component_range 1-2) )"
96     LICENSE="${LICENSE} MIT"
97    
98     EPATCH_FORCE="yes"
99     EPATCH_SUFFIX="patch"
100    
101     # These have been sent upstream
102     #UPSTREAMED_PATCHES=(
103     # "${WORKDIR}/patches/"
104     # )
105    
106     PATCHES=(
107     "${UPSTREAMED_PATCHES[@]}"
108     )
109    
110     pkg_setup() {
111     use minimal || ensure_a_server_is_building
112    
113     # SDL only available in kdrive build
114     if use kdrive && use sdl; then
115     conf_opts="${conf_opts} --enable-xsdl"
116     else
117     conf_opts="${conf_opts} --disable-xsdl"
118     fi
119    
120     # localstatedir is used for the log location; we need to override the default
121     # from ebuild.sh
122     # sysconfdir is used for the xorg.conf location; same applies
123     # --enable-install-setuid needed because sparcs default off
124     CONFIGURE_OPTIONS="
125     $(use_enable ipv6)
126     $(use_enable dmx)
127     $(use_enable kdrive)
128     $(use_enable tslib)
129     $(use_enable tslib xcalibrate)
130     $(use_enable !minimal xvfb)
131     $(use_enable !minimal xnest)
132     $(use_enable !minimal record)
133     $(use_enable !minimal xfree86-utils)
134     $(use_enable !minimal install-libxf86config)
135     $(use_enable !minimal dri)
136     $(use_enable !minimal dri2)
137     $(use_enable !minimal glx)
138     $(use_enable xorg)
139     $(use_enable nptl glx-tls)
140     $(use_enable hal config-hal)
141     --sysconfdir=/etc/X11
142     --localstatedir=/var
143     --enable-install-setuid
144     --with-fontdir=/usr/share/fonts
145     --with-xkb-output=/var/lib/xkb
146     --without-dtrace
147     ${conf_opts}"
148    
149     # (#121394) Causes window corruption
150     filter-flags -fweb
151    
152     # Incompatible with GCC 3.x SSP on x86, bug #244352
153     if use x86 ; then
154     if [[ $(gcc-major-version) -lt 4 ]]; then
155     filter-flags -fstack-protector
156     fi
157     fi
158    
159     OLD_IMPLEM="$(eselect opengl show)"
160     eselect opengl set --impl-headers ${OPENGL_DIR}
161     }
162    
163     src_install() {
164     x-modular_src_install
165    
166     dynamic_libgl_install
167    
168     server_based_install
169    
170     # Install video mode files for system-config-display
171     insinto /usr/share/xorg
172     doins hw/xfree86/common/{extra,vesa}modes \
173     || die "couldn't install extra modes"
174    
175     # Bug #151421 - this file is not built with USE="minimal"
176     # Bug #151670 - this file is also not build if USE="-xorg"
177     if ! use minimal && use xorg; then
178     # Install xorg.conf.example
179     insinto /etc/X11
180     doins hw/xfree86/xorg.conf.example \
181     || die "couldn't install xorg.conf.example"
182     fi
183     }
184    
185     pkg_postinst() {
186     switch_opengl_implem
187    
188     # Bug #135544
189     ewarn "Users of reduced blanking now need:"
190     ewarn " Option \"ReducedBlanking\""
191     ewarn "In the relevant Monitor section(s)."
192     ewarn "Make sure your reduced blanking modelines are safe!"
193    
194     echo
195     ewarn "You must rebuild all drivers if upgrading from xorg-server 1.5"
196     ewarn "or earlier, because the ABI changed. If you cannot start X because"
197     ewarn "of module version mismatch errors, this is your problem."
198    
199     echo
200     ewarn "You can generate a list of all installed packages in the x11-drivers"
201     ewarn "category using this command:"
202     ewarn "emerge portage-utils; qlist -I -C x11-drivers/"
203    
204     ebeep 5
205     epause 10
206     }
207    
208     pkg_postrm() {
209     # Get rid of module dir to ensure opengl-update works properly
210     if ! has_version x11-base/xorg-server; then
211     if [[ -e ${ROOT}/usr/$(get_libdir)/xorg/modules ]]; then
212     rm -rf "${ROOT}"/usr/$(get_libdir)/xorg/modules
213     fi
214     fi
215     }
216    
217     dynamic_libgl_install() {
218     # next section is to setup the dynamic libGL stuff
219     ebegin "Moving GL files for dynamic switching"
220     dodir /usr/$(get_libdir)/opengl/${OPENGL_DIR}/extensions
221     local x=""
222     for x in "${D}"/usr/$(get_libdir)/xorg/modules/extensions/lib{glx,dri,dri2}*; do
223     if [ -f ${x} -o -L ${x} ]; then
224     mv -f ${x} "${D}"/usr/$(get_libdir)/opengl/${OPENGL_DIR}/extensions
225     fi
226     done
227     eend 0
228     }
229    
230     server_based_install() {
231     if ! use xorg; then
232     rm "${D}"/usr/share/man/man1/Xserver.1x \
233     "${D}"/usr/$(get_libdir)/xserver/SecurityPolicy \
234     "${D}"/usr/$(get_libdir)/pkgconfig/xorg-server.pc \
235     "${D}"/usr/share/man/man1/Xserver.1x
236     fi
237     }
238    
239     switch_opengl_implem() {
240     # Switch to the xorg implementation.
241     # Use new opengl-update that will not reset user selected
242     # OpenGL interface ...
243     echo
244     eselect opengl set ${OLD_IMPLEM}
245     }
246    
247     ensure_a_server_is_building() {
248     for server in ${IUSE_SERVERS}; do
249     use ${server} && return;
250     done
251     eerror "You need to specify at least one server to build."
252     eerror "Valid servers are: ${IUSE_SERVERS}."
253     die "No servers were specified to build."
254     }

  ViewVC Help
Powered by ViewVC 1.1.20