/[gentoo-x86]/x11-libs/cairo/cairo-1.12.12.ebuild
Gentoo

Contents of /x11-libs/cairo/cairo-1.12.12.ebuild

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.3 - (show annotations) (download)
Sat Mar 2 23:43:43 2013 UTC (16 months, 4 weeks ago) by hwoarang
Branch: MAIN
Changes since 1.2: +2 -2 lines
Move Qt dependencies to the new category

(Portage version: 2.1.11.52/cvs/Linux x86_64, signed Manifest commit with key C2BA7F3C!)

1 # Copyright 1999-2013 Gentoo Foundation
2 # Distributed under the terms of the GNU General Public License v2
3 # $Header: /var/cvsroot/gentoo-x86/x11-libs/cairo/cairo-1.12.12.ebuild,v 1.2 2013/02/22 18:44:21 zmedico Exp $
4
5 EAPI=5
6
7 inherit eutils flag-o-matic autotools
8
9 if [[ ${PV} == *9999* ]]; then
10 inherit git-2
11 EGIT_REPO_URI="git://anongit.freedesktop.org/git/cairo"
12 SRC_URI=""
13 KEYWORDS=""
14 else
15 SRC_URI="http://cairographics.org/releases/${P}.tar.xz"
16 KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~x86-freebsd ~x86-interix ~amd64-linux ~arm-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
17 fi
18
19 DESCRIPTION="A vector graphics library with cross-device output support"
20 HOMEPAGE="http://cairographics.org/"
21 LICENSE="|| ( LGPL-2.1 MPL-1.1 )"
22 SLOT="0"
23 IUSE="X aqua debug directfb doc drm gallium +glib legacy-drivers opengl openvg qt4 static-libs +svg xcb"
24
25 # Test causes a circular depend on gtk+... since gtk+ needs cairo but test needs gtk+ so we need to block it
26 RESTRICT="test"
27
28 RDEPEND="media-libs/fontconfig
29 media-libs/freetype:2
30 media-libs/libpng:0
31 sys-libs/zlib
32 >=x11-libs/pixman-0.28.0
33 directfb? ( dev-libs/DirectFB )
34 glib? ( >=dev-libs/glib-2.28.6:2 )
35 opengl? ( || ( media-libs/mesa[egl] media-libs/opengl-apple ) )
36 openvg? ( media-libs/mesa[openvg] )
37 qt4? ( >=dev-qt/qtgui-4.8:4 )
38 X? (
39 >=x11-libs/libXrender-0.6
40 x11-libs/libXext
41 x11-libs/libX11
42 drm? (
43 >=virtual/udev-136
44 gallium? ( media-libs/mesa[gallium] )
45 )
46 )
47 xcb? (
48 x11-libs/libxcb
49 x11-libs/xcb-util
50 )"
51 DEPEND="${RDEPEND}
52 virtual/pkgconfig
53 >=sys-devel/libtool-2
54 doc? (
55 >=dev-util/gtk-doc-1.6
56 ~app-text/docbook-xml-dtd-4.2
57 )
58 X? (
59 x11-proto/renderproto
60 drm? (
61 x11-proto/xproto
62 >=x11-proto/xextproto-7.1
63 )
64 )"
65
66 # drm module requires X
67 # for gallium we need to enable drm
68 REQUIRED_USE="
69 drm? ( X )
70 gallium? ( drm )
71 "
72
73 src_prepare() {
74 epatch "${FILESDIR}"/${PN}-1.8.8-interix.patch
75 use legacy-drivers && epatch "${FILESDIR}"/${PN}-1.10.0-buggy_gradients.patch
76 epatch "${FILESDIR}"/${PN}-1.10.2-qt-surface.patch
77 epatch "${FILESDIR}"/${PN}-respect-fontconfig.patch
78 epatch "${FILESDIR}"/${P}-disable-test-suite.patch
79 epatch_user
80
81 # Slightly messed build system YAY
82 if [[ ${PV} == *9999* ]]; then
83 touch boilerplate/Makefile.am.features
84 touch src/Makefile.am.features
85 touch ChangeLog
86 fi
87
88 # We need to run elibtoolize to ensure correct so versioning on FreeBSD
89 # upgraded to an eautoreconf for the above interix patch.
90 eautoreconf
91 }
92
93 src_configure() {
94 local myopts
95
96 # SuperH doesn't have native atomics yet
97 use sh && myopts+=" --disable-atomic"
98
99 [[ ${CHOST} == *-interix* ]] && append-flags -D_REENTRANT
100 # http://bugs.freedesktop.org/show_bug.cgi?id=15463
101 [[ ${CHOST} == *-solaris* ]] && append-flags -D_POSIX_PTHREAD_SEMANTICS
102
103 #gets rid of fbmmx.c inlining warnings
104 append-flags -finline-limit=1200
105
106 use X && myopts+=" --enable-tee=yes"
107
108 use elibc_FreeBSD && myopts+=" --disable-symbol-lookup"
109
110 # --disable-xcb-lib:
111 # do not override good xlib backed by hardforcing rendering over xcb
112 econf \
113 --disable-dependency-tracking \
114 $(use_with X x) \
115 $(use_enable X xlib) \
116 $(use_enable X xlib-xrender) \
117 $(use_enable aqua quartz) \
118 $(use_enable aqua quartz-image) \
119 $(use_enable debug test-surfaces) \
120 $(use_enable directfb) \
121 $(use_enable glib gobject) \
122 $(use_enable doc gtk-doc) \
123 $(use_enable openvg vg) \
124 $(use_enable opengl gl) \
125 $(use_enable qt4 qt) \
126 $(use_enable static-libs static) \
127 $(use_enable svg) \
128 $(use_enable xcb) \
129 $(use_enable xcb xcb-shm) \
130 $(use_enable drm) \
131 $(use_enable gallium) \
132 --enable-ft \
133 --enable-pdf \
134 --enable-png \
135 --enable-ps \
136 --disable-xlib-xcb \
137 ${myopts}
138 }
139
140 src_install() {
141 # parallel make install fails
142 emake -j1 DESTDIR="${D}" install
143 find "${ED}" -name '*.la' -exec rm -f {} +
144 dodoc AUTHORS ChangeLog NEWS README
145 }

  ViewVC Help
Powered by ViewVC 1.1.20