/[gentoo-x86]/x11-libs/cairo/cairo-1.12.16.ebuild
Gentoo

Contents of /x11-libs/cairo/cairo-1.12.16.ebuild

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.13 - (show annotations) (download)
Tue Jun 10 01:03:13 2014 UTC (6 months, 2 weeks ago) by vapier
Branch: MAIN
CVS Tags: HEAD
Changes since 1.12: +2 -3 lines
Add arm64/m68k love.

(Portage version: 2.2.10/cvs/Linux x86_64, signed Manifest commit with key D2E96200)

1 # Copyright 1999-2014 Gentoo Foundation
2 # Distributed under the terms of the GNU General Public License v2
3 # $Header: /var/cvsroot/gentoo-x86/x11-libs/cairo/cairo-1.12.16.ebuild,v 1.12 2014/06/08 09:15:54 ago Exp $
4
5 EAPI=5
6
7 inherit eutils flag-o-matic autotools
8
9 if [[ ${PV} == *9999* ]]; then
10 inherit git-2
11 EGIT_REPO_URI="git://anongit.freedesktop.org/git/cairo"
12 SRC_URI=""
13 else
14 SRC_URI="http://cairographics.org/releases/${P}.tar.xz"
15 KEYWORDS="alpha amd64 arm arm64 hppa ia64 m68k ~mips ppc ppc64 ~s390 ~sh sparc x86 ~amd64-fbsd ~x86-fbsd ~x86-freebsd ~x86-interix ~amd64-linux ~arm-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
16 fi
17
18 DESCRIPTION="A vector graphics library with cross-device output support"
19 HOMEPAGE="http://cairographics.org/"
20 LICENSE="|| ( LGPL-2.1 MPL-1.1 )"
21 SLOT="0"
22 IUSE="X aqua debug directfb doc drm gallium gles2 +glib legacy-drivers opengl openvg qt4 static-libs +svg valgrind xcb xlib-xcb"
23
24 # Test causes a circular depend on gtk+... since gtk+ needs cairo but test needs gtk+ so we need to block it
25 RESTRICT="test"
26
27 RDEPEND="dev-libs/lzo
28 media-libs/fontconfig
29 media-libs/freetype:2
30 media-libs/libpng:0=
31 sys-libs/zlib
32 >=x11-libs/pixman-0.28.0
33 directfb? ( dev-libs/DirectFB )
34 gles2? ( media-libs/mesa[gles2] )
35 glib? ( >=dev-libs/glib-2.28.6:2 )
36 opengl? ( || ( media-libs/mesa[egl] media-libs/opengl-apple ) )
37 openvg? ( media-libs/mesa[openvg] )
38 qt4? ( >=dev-qt/qtgui-4.8:4 )
39 X? (
40 >=x11-libs/libXrender-0.6
41 x11-libs/libXext
42 x11-libs/libX11
43 drm? (
44 >=virtual/udev-136
45 gallium? ( media-libs/mesa[gallium] )
46 )
47 )
48 xcb? (
49 x11-libs/libxcb
50 x11-libs/xcb-util
51 )"
52 DEPEND="${RDEPEND}
53 virtual/pkgconfig
54 >=sys-devel/libtool-2
55 doc? (
56 >=dev-util/gtk-doc-1.6
57 ~app-text/docbook-xml-dtd-4.2
58 )
59 X? (
60 x11-proto/renderproto
61 drm? (
62 x11-proto/xproto
63 >=x11-proto/xextproto-7.1
64 )
65 )"
66
67 # drm module requires X
68 # for gallium we need to enable drm
69 REQUIRED_USE="
70 drm? ( X )
71 gallium? ( drm )
72 gles2? ( !opengl )
73 openvg? ( || ( gles2 opengl ) )
74 xlib-xcb? ( xcb )
75 "
76
77 src_prepare() {
78 epatch "${FILESDIR}"/${PN}-1.8.8-interix.patch
79 use legacy-drivers && epatch "${FILESDIR}"/${PN}-1.10.0-buggy_gradients.patch
80 epatch "${FILESDIR}"/${PN}-respect-fontconfig.patch
81 epatch_user
82
83 # Slightly messed build system YAY
84 if [[ ${PV} == *9999* ]]; then
85 touch boilerplate/Makefile.am.features
86 touch src/Makefile.am.features
87 touch ChangeLog
88 fi
89
90 # We need to run elibtoolize to ensure correct so versioning on FreeBSD
91 # upgraded to an eautoreconf for the above interix patch.
92 eautoreconf
93 }
94
95 src_configure() {
96 local myopts
97
98 [[ ${CHOST} == *-interix* ]] && append-flags -D_REENTRANT
99
100 use elibc_FreeBSD && myopts+=" --disable-symbol-lookup"
101
102 econf \
103 --disable-dependency-tracking \
104 $(use_with X x) \
105 $(use_enable X tee) \
106 $(use_enable X xlib) \
107 $(use_enable X xlib-xrender) \
108 $(use_enable aqua quartz) \
109 $(use_enable aqua quartz-image) \
110 $(use_enable debug test-surfaces) \
111 $(use_enable drm) \
112 $(use_enable directfb) \
113 $(use_enable gallium) \
114 $(use_enable gles2 glesv2) \
115 $(use_enable glib gobject) \
116 $(use_enable doc gtk-doc) \
117 $(use_enable openvg vg) \
118 $(use_enable opengl gl) \
119 $(use_enable qt4 qt) \
120 $(use_enable static-libs static) \
121 $(use_enable svg) \
122 $(use_enable valgrind) \
123 $(use_enable xcb) \
124 $(use_enable xcb xcb-shm) \
125 $(use_enable xlib-xcb) \
126 --enable-ft \
127 --enable-pdf \
128 --enable-png \
129 --enable-ps \
130 ${myopts}
131 }
132
133 src_install() {
134 # parallel make install fails
135 emake -j1 DESTDIR="${D}" install
136 find "${ED}" -name '*.la' -exec rm -f {} +
137 dodoc AUTHORS ChangeLog NEWS README
138 }
139
140 pkg_postinst() {
141 if use !xlib-xcb; then
142 if has_version net-misc/nxserver-freenx \
143 || has_version net-misc/x2goserver; then
144 ewarn "cairo-1.12 is known to cause GTK+ errors with NX servers."
145 ewarn "Enable USE=\"xlib-xcb\" if you notice incorrect behavior in GTK+"
146 ewarn "applications that are running inside NX sessions. For details, see"
147 ewarn "https://bugs.gentoo.org/441878 or https://bugs.freedesktop.org/59173"
148 fi
149 fi
150 }

  ViewVC Help
Powered by ViewVC 1.1.20