/[gentoo-x86]/x11-libs/cairo/cairo-1.12.6.ebuild
Gentoo

Contents of /x11-libs/cairo/cairo-1.12.6.ebuild

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.3 - (show annotations) (download)
Wed Nov 28 10:27:31 2012 UTC (20 months, 4 weeks ago) by ssuominen
Branch: MAIN
Changes since 1.2: +2 -2 lines
Use virtual/udev instead of sys-fs/udev wrt #444398

(Portage version: 2.2.0_alpha142/cvs/Linux x86_64, signed Manifest commit with key 4868F14D)

1 # Copyright 1999-2012 Gentoo Foundation
2 # Distributed under the terms of the GNU General Public License v2
3 # $Header: /var/cvsroot/gentoo-x86/x11-libs/cairo/cairo-1.12.6.ebuild,v 1.2 2012/11/04 09:54:57 ssuominen Exp $
4
5 EAPI=4
6
7 inherit eutils flag-o-matic autotools
8
9 if [[ ${PV} == *9999* ]]; then
10 inherit git-2
11 EGIT_REPO_URI="git://anongit.freedesktop.org/git/cairo"
12 SRC_URI=""
13 KEYWORDS=""
14 else
15 SRC_URI="http://cairographics.org/releases/${P}.tar.xz"
16 KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~x86-freebsd ~x86-interix ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
17 fi
18
19 DESCRIPTION="A vector graphics library with cross-device output support"
20 HOMEPAGE="http://cairographics.org/"
21 LICENSE="|| ( LGPL-2.1 MPL-1.1 )"
22 SLOT="0"
23 IUSE="X aqua debug directfb doc drm gallium +glib legacy-drivers opengl openvg qt4 static-libs +svg xcb"
24
25 # Test causes a circular depend on gtk+... since gtk+ needs cairo but test needs gtk+ so we need to block it
26 RESTRICT="test"
27
28 RDEPEND="media-libs/fontconfig
29 media-libs/freetype:2
30 media-libs/libpng:0
31 sys-libs/zlib
32 >=x11-libs/pixman-0.22.0
33 directfb? ( dev-libs/DirectFB )
34 glib? ( >=dev-libs/glib-2.28.6:2 )
35 opengl? ( || ( media-libs/mesa[egl] media-libs/opengl-apple ) )
36 openvg? ( media-libs/mesa[openvg] )
37 qt4? ( >=x11-libs/qt-gui-4.8:4 )
38 X? (
39 >=x11-libs/libXrender-0.6
40 x11-libs/libX11
41 drm? (
42 >=virtual/udev-136
43 gallium? ( media-libs/mesa[gallium] )
44 )
45 )
46 xcb? (
47 x11-libs/libxcb
48 x11-libs/xcb-util
49 )"
50 DEPEND="${RDEPEND}
51 virtual/pkgconfig
52 >=sys-devel/libtool-2
53 doc? (
54 >=dev-util/gtk-doc-1.6
55 ~app-text/docbook-xml-dtd-4.2
56 )
57 X? (
58 x11-proto/renderproto
59 drm? (
60 x11-proto/xproto
61 >=x11-proto/xextproto-7.1
62 )
63 )"
64
65 # drm module requires X
66 # for gallium we need to enable drm
67 REQUIRED_USE="
68 drm? ( X )
69 gallium? ( drm )
70 "
71
72 src_prepare() {
73 epatch "${FILESDIR}"/${PN}-1.8.8-interix.patch
74 use legacy-drivers && epatch "${FILESDIR}"/${PN}-1.10.0-buggy_gradients.patch
75 epatch "${FILESDIR}"/${PN}-1.10.2-qt-surface.patch
76 epatch "${FILESDIR}"/${PN}-respect-fontconfig.patch
77 epatch_user
78
79 # Slightly messed build system YAY
80 if [[ ${PV} == *9999* ]]; then
81 touch boilerplate/Makefile.am.features
82 touch src/Makefile.am.features
83 touch ChangeLog
84 fi
85
86 # We need to run elibtoolize to ensure correct so versioning on FreeBSD
87 # upgraded to an eautoreconf for the above interix patch.
88 eautoreconf
89 }
90
91 src_configure() {
92 local myopts
93
94 # SuperH doesn't have native atomics yet
95 use sh && myopts+=" --disable-atomic"
96
97 [[ ${CHOST} == *-interix* ]] && append-flags -D_REENTRANT
98 # http://bugs.freedesktop.org/show_bug.cgi?id=15463
99 [[ ${CHOST} == *-solaris* ]] && append-flags -D_POSIX_PTHREAD_SEMANTICS
100
101 #gets rid of fbmmx.c inlining warnings
102 append-flags -finline-limit=1200
103
104 use X && myopts+=" --enable-tee=yes"
105
106 use elibc_FreeBSD && myopts+=" --disable-symbol-lookup"
107
108 # --disable-xcb-lib:
109 # do not override good xlib backed by hardforcing rendering over xcb
110 econf \
111 --disable-dependency-tracking \
112 $(use_with X x) \
113 $(use_enable X xlib) \
114 $(use_enable X xlib-xrender) \
115 $(use_enable aqua quartz) \
116 $(use_enable aqua quartz-image) \
117 $(use_enable debug test-surfaces) \
118 $(use_enable directfb) \
119 $(use_enable glib gobject) \
120 $(use_enable doc gtk-doc) \
121 $(use_enable openvg vg) \
122 $(use_enable opengl gl) \
123 $(use_enable qt4 qt) \
124 $(use_enable static-libs static) \
125 $(use_enable svg) \
126 $(use_enable xcb) \
127 $(use_enable xcb xcb-shm) \
128 $(use_enable drm) \
129 $(use_enable gallium) \
130 --enable-ft \
131 --enable-pdf \
132 --enable-png \
133 --enable-ps \
134 --disable-xlib-xcb \
135 ${myopts}
136 }
137
138 src_install() {
139 # parallel make install fails
140 emake -j1 DESTDIR="${D}" install
141 find "${ED}" -name '*.la' -exec rm -f {} +
142 dodoc AUTHORS ChangeLog NEWS README
143 }

  ViewVC Help
Powered by ViewVC 1.1.20