/[gentoo-x86]/x11-libs/cairo/cairo-1.12.8.ebuild
Gentoo

Contents of /x11-libs/cairo/cairo-1.12.8.ebuild

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.2 - (show annotations) (download)
Wed Nov 28 10:27:31 2012 UTC (21 months ago) by ssuominen
Branch: MAIN
Changes since 1.1: +2 -2 lines
Use virtual/udev instead of sys-fs/udev wrt #444398

(Portage version: 2.2.0_alpha142/cvs/Linux x86_64, signed Manifest commit with key 4868F14D)

1 # Copyright 1999-2012 Gentoo Foundation
2 # Distributed under the terms of the GNU General Public License v2
3 # $Header: /var/cvsroot/gentoo-x86/x11-libs/cairo/cairo-1.12.8.ebuild,v 1.1 2012/11/15 16:58:27 chithanh Exp $
4
5 EAPI=4
6
7 inherit eutils flag-o-matic autotools
8
9 if [[ ${PV} == *9999* ]]; then
10 inherit git-2
11 EGIT_REPO_URI="git://anongit.freedesktop.org/git/cairo"
12 SRC_URI=""
13 KEYWORDS=""
14 else
15 SRC_URI="http://cairographics.org/releases/${P}.tar.xz"
16 KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~x86-freebsd ~x86-interix ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
17 fi
18
19 DESCRIPTION="A vector graphics library with cross-device output support"
20 HOMEPAGE="http://cairographics.org/"
21 LICENSE="|| ( LGPL-2.1 MPL-1.1 )"
22 SLOT="0"
23 IUSE="X aqua debug directfb doc drm gallium +glib legacy-drivers opengl openvg qt4 static-libs +svg xcb"
24
25 # Test causes a circular depend on gtk+... since gtk+ needs cairo but test needs gtk+ so we need to block it
26 RESTRICT="test"
27
28 RDEPEND="media-libs/fontconfig
29 media-libs/freetype:2
30 media-libs/libpng:0
31 sys-libs/zlib
32 >=x11-libs/pixman-0.22.0
33 directfb? ( dev-libs/DirectFB )
34 glib? ( >=dev-libs/glib-2.28.6:2 )
35 opengl? ( || ( media-libs/mesa[egl] media-libs/opengl-apple ) )
36 openvg? ( media-libs/mesa[openvg] )
37 qt4? ( >=x11-libs/qt-gui-4.8:4 )
38 X? (
39 >=x11-libs/libXrender-0.6
40 x11-libs/libXext
41 x11-libs/libX11
42 drm? (
43 >=virtual/udev-136
44 gallium? ( media-libs/mesa[gallium] )
45 )
46 )
47 xcb? (
48 x11-libs/libxcb
49 x11-libs/xcb-util
50 )"
51 DEPEND="${RDEPEND}
52 virtual/pkgconfig
53 >=sys-devel/libtool-2
54 doc? (
55 >=dev-util/gtk-doc-1.6
56 ~app-text/docbook-xml-dtd-4.2
57 )
58 X? (
59 x11-proto/renderproto
60 drm? (
61 x11-proto/xproto
62 >=x11-proto/xextproto-7.1
63 )
64 )"
65
66 # drm module requires X
67 # for gallium we need to enable drm
68 REQUIRED_USE="
69 drm? ( X )
70 gallium? ( drm )
71 "
72
73 src_prepare() {
74 epatch "${FILESDIR}"/${PN}-1.8.8-interix.patch
75 use legacy-drivers && epatch "${FILESDIR}"/${PN}-1.10.0-buggy_gradients.patch
76 epatch "${FILESDIR}"/${PN}-1.10.2-qt-surface.patch
77 epatch "${FILESDIR}"/${PN}-respect-fontconfig.patch
78 epatch_user
79
80 # Slightly messed build system YAY
81 if [[ ${PV} == *9999* ]]; then
82 touch boilerplate/Makefile.am.features
83 touch src/Makefile.am.features
84 touch ChangeLog
85 fi
86
87 # We need to run elibtoolize to ensure correct so versioning on FreeBSD
88 # upgraded to an eautoreconf for the above interix patch.
89 eautoreconf
90 }
91
92 src_configure() {
93 local myopts
94
95 # SuperH doesn't have native atomics yet
96 use sh && myopts+=" --disable-atomic"
97
98 [[ ${CHOST} == *-interix* ]] && append-flags -D_REENTRANT
99 # http://bugs.freedesktop.org/show_bug.cgi?id=15463
100 [[ ${CHOST} == *-solaris* ]] && append-flags -D_POSIX_PTHREAD_SEMANTICS
101
102 #gets rid of fbmmx.c inlining warnings
103 append-flags -finline-limit=1200
104
105 use X && myopts+=" --enable-tee=yes"
106
107 use elibc_FreeBSD && myopts+=" --disable-symbol-lookup"
108
109 # --disable-xcb-lib:
110 # do not override good xlib backed by hardforcing rendering over xcb
111 econf \
112 --disable-dependency-tracking \
113 $(use_with X x) \
114 $(use_enable X xlib) \
115 $(use_enable X xlib-xrender) \
116 $(use_enable aqua quartz) \
117 $(use_enable aqua quartz-image) \
118 $(use_enable debug test-surfaces) \
119 $(use_enable directfb) \
120 $(use_enable glib gobject) \
121 $(use_enable doc gtk-doc) \
122 $(use_enable openvg vg) \
123 $(use_enable opengl gl) \
124 $(use_enable qt4 qt) \
125 $(use_enable static-libs static) \
126 $(use_enable svg) \
127 $(use_enable xcb) \
128 $(use_enable xcb xcb-shm) \
129 $(use_enable drm) \
130 $(use_enable gallium) \
131 --enable-ft \
132 --enable-pdf \
133 --enable-png \
134 --enable-ps \
135 --disable-xlib-xcb \
136 ${myopts}
137 }
138
139 src_install() {
140 # parallel make install fails
141 emake -j1 DESTDIR="${D}" install
142 find "${ED}" -name '*.la' -exec rm -f {} +
143 dodoc AUTHORS ChangeLog NEWS README
144 }

  ViewVC Help
Powered by ViewVC 1.1.20