/[gentoo-x86]/x11-libs/cairo/cairo-1.8.8.ebuild
Gentoo

Contents of /x11-libs/cairo/cairo-1.8.8.ebuild

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.19 - (show annotations) (download)
Tue Jan 11 18:58:37 2011 UTC (4 years, 2 months ago) by scarabeus
Branch: MAIN
CVS Tags: HEAD
Changes since 1.18: +1 -1 lines
FILE REMOVED
Version bump fixes bug #351319. Drop older.

(Portage version: 2.2.0_alpha10/cvs/Linux x86_64)

1 # Copyright 1999-2010 Gentoo Foundation
2 # Distributed under the terms of the GNU General Public License v2
3 # $Header: /var/cvsroot/gentoo-x86/x11-libs/cairo/cairo-1.8.8.ebuild,v 1.18 2010/03/08 09:00:40 ssuominen Exp $
4
5 EAPI=2
6
7 inherit eutils flag-o-matic autotools
8
9 DESCRIPTION="A vector graphics library with cross-device output support"
10 HOMEPAGE="http://cairographics.org/"
11 SRC_URI="http://cairographics.org/releases/${P}.tar.gz"
12
13 LICENSE="|| ( LGPL-2.1 MPL-1.1 )"
14 SLOT="0"
15 KEYWORDS="alpha amd64 arm hppa ia64 ~mips ppc ppc64 s390 sh sparc x86 ~x86-fbsd ~x86-freebsd ~x86-interix ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
16 IUSE="aqua cleartype debug directfb doc glitz opengl +svg X xcb"
17
18 # Test causes a circular depend on gtk+... since gtk+ needs cairo but test needs gtk+ so we need to block it
19 RESTRICT="test"
20
21 RDEPEND="media-libs/fontconfig
22 >=media-libs/freetype-2.1.9
23 sys-libs/zlib
24 media-libs/libpng
25 >=x11-libs/pixman-0.12.0
26 directfb? ( >=dev-libs/DirectFB-0.9.24 )
27 glitz? ( >=media-libs/glitz-0.5.1 )
28 svg? ( dev-libs/libxml2 )
29 X? ( >=x11-libs/libXrender-0.6
30 x11-libs/libXext
31 x11-libs/libX11
32 x11-libs/libXft )
33 xcb? ( >=x11-libs/libxcb-0.92
34 x11-libs/xcb-util )"
35 # test? (
36 # pdf test
37 # x11-libs/pango
38 # >=x11-libs/gtk+-2.0
39 # >=app-text/poppler-bindings-0.9.2[gtk]
40 # ps test
41 # app-text/ghostscript-gpl
42 # svg test
43 # >=x11-libs/gtk+-2.0
44 # >=gnome-base/librsvg-2.15.0
45
46 DEPEND="${RDEPEND}
47 >=dev-util/pkgconfig-0.19
48 >=sys-devel/libtool-2
49 doc? ( >=dev-util/gtk-doc-1.6
50 ~app-text/docbook-xml-dtd-4.2 )
51 X? ( x11-proto/renderproto )"
52
53 src_prepare() {
54 # ClearType-like patches applied by ArchLinux
55 use cleartype && epatch "${FILESDIR}"/cairo-1.2.4-lcd-cleartype-like.diff
56
57 epatch "${FILESDIR}"/${P}-interix.patch \
58 "${FILESDIR}"/${P}-libpng14.patch
59
60 # We need to run elibtoolize to ensure correct so versioning on FreeBSD
61 # upgraded to an eautoreconf for the above interix patch.
62 eautoreconf
63 }
64
65 src_configure() {
66 [[ ${CHOST} == *-interix* ]] && append-flags -D_REENTRANT
67 # http://bugs.freedesktop.org/show_bug.cgi?id=15463
68 [[ ${CHOST} == *-solaris* ]] && append-flags -D_POSIX_PTHREAD_SEMANTICS
69
70 #gets rid of fbmmx.c inlining warnings
71 append-flags -finline-limit=1200
72
73 if use glitz && use opengl; then
74 export glitz_LIBS=$(pkg-config --libs glitz-glx)
75 fi
76
77 econf $(use_enable X xlib) $(use_enable doc gtk-doc) \
78 $(use_enable directfb) $(use_enable xcb) \
79 $(use_enable svg) $(use_enable glitz) $(use_enable X xlib-xrender) \
80 $(use_enable debug test-surfaces) --enable-pdf --enable-png \
81 --enable-ft --enable-ps \
82 $(use_enable aqua quartz) $(use_enable aqua quartz-image) \
83 || die "configure failed"
84 }
85
86 src_install() {
87 make DESTDIR="${D}" install || die "Installation failed"
88 dodoc AUTHORS ChangeLog NEWS README
89 }
90
91 pkg_postinst() {
92 if use xcb; then
93 ewarn "You have enabled the Cairo XCB backend which is used only by"
94 ewarn "a select few apps. The Cairo XCB backend is presently"
95 ewarn "un-maintained and needs a lot of work to get it caught up"
96 ewarn "to the Xrender and Xlib backends, which are the backends used"
97 ewarn "by most applications. See:"
98 ewarn "http://lists.freedesktop.org/archives/xcb/2008-December/004139.html"
99 fi
100 }

  ViewVC Help
Powered by ViewVC 1.1.20