/[gentoo-x86]/x11-libs/cairo/cairo-9999.ebuild
Gentoo

Contents of /x11-libs/cairo/cairo-9999.ebuild

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.1 - (hide annotations) (download)
Wed Sep 8 19:58:39 2010 UTC (3 years, 7 months ago) by scarabeus
Branch: MAIN
Sync with x11 overlay. Move live ebuild here from overlay.

(Portage version: 2.2_rc75/cvs/Linux x86_64)

1 scarabeus 1.1 # Copyright 1999-2010 Gentoo Foundation
2     # Distributed under the terms of the GNU General Public License v2
3     # $Header: $
4    
5     EAPI=3
6    
7     EGIT_REPO_URI="git://anongit.freedesktop.org/git/cairo"
8     [[ ${PV} == *9999 ]] && GIT_ECLASS="git"
9    
10     inherit eutils flag-o-matic autotools ${GIT_ECLASS}
11    
12     DESCRIPTION="A vector graphics library with cross-device output support"
13     HOMEPAGE="http://cairographics.org/"
14     [[ ${PV} == *9999 ]] || SRC_URI="http://cairographics.org/releases/${P}.tar.gz"
15    
16     LICENSE="|| ( LGPL-2.1 MPL-1.1 )"
17     SLOT="0"
18     KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~x86-fbsd ~x86-freebsd ~x86-interix ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
19     IUSE="X aqua debug directfb doc drm gallium opengl openvg qt static-libs +svg xcb"
20    
21     # Test causes a circular depend on gtk+... since gtk+ needs cairo but test needs gtk+ so we need to block it
22     RESTRICT="test"
23    
24     RDEPEND="media-libs/fontconfig
25     media-libs/freetype:2
26     media-libs/libpng:0
27     sys-libs/zlib
28     >=x11-libs/pixman-0.18.4
29     directfb? ( dev-libs/DirectFB )
30     opengl? ( virtual/opengl )
31     qt? ( x11-libs/qt-gui )
32     svg? ( dev-libs/libxml2 )
33     X? (
34     >=x11-libs/libXrender-0.6
35     x11-libs/libXext
36     x11-libs/libX11
37     x11-libs/libXft
38     drm? (
39     >=sys-fs/udev-136
40     gallium? ( media-libs/mesa[gallium] )
41     )
42     xcb? (
43     || (
44     <=x11-libs/libX11-1.3.5[xcb]
45     >x11-libs/libX11-1.3.5
46     )
47     )
48     )
49     xcb? (
50     x11-libs/libxcb
51     x11-libs/xcb-util
52     )"
53     DEPEND="${RDEPEND}
54     dev-util/pkgconfig
55     >=sys-devel/libtool-2
56     doc? (
57     >=dev-util/gtk-doc-1.6
58     ~app-text/docbook-xml-dtd-4.2
59     )
60     X? (
61     x11-proto/renderproto
62     drm? (
63     x11-proto/xproto
64     >=x11-proto/xextproto-7.1
65     )
66     )"
67    
68     src_prepare() {
69     epatch "${FILESDIR}"/${PN}-1.8.8-interix.patch
70    
71     # Slightly messed build system YAY
72     if [[ ${PV} == *9999* ]]; then
73     touch boilerplate/Makefile.am.features
74     touch src/Makefile.am.features
75     touch ChangeLog
76     fi
77    
78     # We need to run elibtoolize to ensure correct so versioning on FreeBSD
79     # upgraded to an eautoreconf for the above interix patch.
80     eautoreconf
81     }
82    
83     src_configure() {
84     local myopts
85    
86     [[ ${CHOST} == *-interix* ]] && append-flags -D_REENTRANT
87     # http://bugs.freedesktop.org/show_bug.cgi?id=15463
88     [[ ${CHOST} == *-solaris* ]] && append-flags -D_POSIX_PTHREAD_SEMANTICS
89    
90     #gets rid of fbmmx.c inlining warnings
91     append-flags -finline-limit=1200
92    
93     if use X; then
94     myopts+="
95     $(use_enable drm)
96     $(use_enable xcb xcb-shm)
97     "
98    
99     if use drm; then
100     myopts+="
101     $(use_enable gallium)
102     $(use_enable xcb xcb-drm)
103     "
104     else
105     use gallium && ewarn "Gallium use requires drm use enabled. So disabling for now."
106     myopts+="
107     --disable-gallium
108     --disable-xcb-drm
109     "
110     fi
111     else
112     use drm && ewarn "drm use requires X use enabled. So disabling for now."
113     myopts+="
114     --disable-drm
115     --disable-xcb-lib
116     "
117     fi
118    
119     econf \
120     --disable-dependency-tracking \
121     $(use_with X x) \
122     $(use_enable X xlib) \
123     $(use_enable X xlib-xrender) \
124     $(use_enable aqua quartz) \
125     $(use_enable aqua quartz-image) \
126     $(use_enable debug test-surfaces) \
127     $(use_enable directfb) \
128     $(use_enable doc gtk-doc) \
129     $(use_enable openvg vg) \
130     $(use_enable opengl gl) \
131     $(use_enable qt) \
132     $(use_enable static-libs static) \
133     $(use_enable svg) \
134     $(use_enable xcb) \
135     $(use_enable xcb xcb-shm) \
136     --enable-ft \
137     --enable-pdf \
138     --enable-png \
139     --enable-ps \
140     ${myopts}
141     }
142    
143     src_install() {
144     # parallel make install fails
145     emake -j1 DESTDIR="${D}" install || die "Installation failed"
146     dodoc AUTHORS ChangeLog NEWS README || die
147    
148     use static-libs || find "${D}" -type f -name '*.la' -exec rm -f '{}' \;
149     }

  ViewVC Help
Powered by ViewVC 1.1.20