/[gentoo-x86]/x11-libs/cairo/cairo-9999.ebuild
Gentoo

Contents of /x11-libs/cairo/cairo-9999.ebuild

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.18 - (show annotations) (download)
Wed May 2 22:11:29 2012 UTC (2 years, 5 months ago) by pesa
Branch: MAIN
Changes since 1.17: +2 -2 lines
Raise qt-gui dependency to >=4.8 wrt bug 412177.

(Portage version: 2.2.0_alpha101/cvs/Linux x86_64)

1 # Copyright 1999-2012 Gentoo Foundation
2 # Distributed under the terms of the GNU General Public License v2
3 # $Header: /var/cvsroot/gentoo-x86/x11-libs/cairo/cairo-9999.ebuild,v 1.17 2012/05/01 17:56:20 chithanh Exp $
4
5 EAPI=4
6
7 EGIT_REPO_URI="git://anongit.freedesktop.org/git/cairo"
8 [[ ${PV} == *9999 ]] && GIT_ECLASS="git-2"
9
10 inherit eutils flag-o-matic autotools ${GIT_ECLASS}
11
12 DESCRIPTION="A vector graphics library with cross-device output support"
13 HOMEPAGE="http://cairographics.org/"
14 [[ ${PV} == *9999 ]] || SRC_URI="http://cairographics.org/releases/${P}.tar.xz"
15
16 LICENSE="|| ( LGPL-2.1 MPL-1.1 )"
17 SLOT="0"
18 KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~x86-freebsd ~x86-interix ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
19 IUSE="X aqua debug directfb doc drm gallium +glib opengl openvg qt4 static-libs +svg xcb"
20
21 # Test causes a circular depend on gtk+... since gtk+ needs cairo but test needs gtk+ so we need to block it
22 RESTRICT="test"
23
24 RDEPEND="media-libs/fontconfig
25 media-libs/freetype:2
26 media-libs/libpng:0
27 sys-libs/zlib
28 >=x11-libs/pixman-0.18.4
29 directfb? ( dev-libs/DirectFB )
30 glib? ( >=dev-libs/glib-2.28.6:2 )
31 opengl? ( virtual/opengl )
32 openvg? ( media-libs/mesa[openvg] )
33 qt4? ( >=x11-libs/qt-gui-4.8:4 )
34 svg? ( dev-libs/libxml2 )
35 X? (
36 >=x11-libs/libXrender-0.6
37 x11-libs/libXext
38 x11-libs/libX11
39 x11-libs/libXft
40 drm? (
41 >=sys-fs/udev-136
42 gallium? ( media-libs/mesa[gallium] )
43 )
44 )
45 xcb? (
46 x11-libs/libxcb
47 x11-libs/xcb-util
48 )"
49 DEPEND="${RDEPEND}
50 dev-util/pkgconfig
51 >=sys-devel/libtool-2
52 doc? (
53 >=dev-util/gtk-doc-1.6
54 ~app-text/docbook-xml-dtd-4.2
55 )
56 X? (
57 x11-proto/renderproto
58 drm? (
59 x11-proto/xproto
60 >=x11-proto/xextproto-7.1
61 )
62 )"
63
64 # drm module requires X
65 # for gallium we need to enable drm
66 REQUIRED_USE="
67 drm? ( X )
68 gallium? ( drm )
69 "
70
71 src_prepare() {
72 epatch "${FILESDIR}"/${PN}-1.8.8-interix.patch
73
74 # Slightly messed build system YAY
75 if [[ ${PV} == *9999* ]]; then
76 touch boilerplate/Makefile.am.features
77 touch src/Makefile.am.features
78 touch ChangeLog
79 fi
80
81 # We need to run elibtoolize to ensure correct so versioning on FreeBSD
82 # upgraded to an eautoreconf for the above interix patch.
83 eautoreconf
84 }
85
86 src_configure() {
87 local myopts
88
89 # SuperH doesn't have native atomics yet
90 use sh && myopts+=" --disable-atomic"
91
92 [[ ${CHOST} == *-interix* ]] && append-flags -D_REENTRANT
93 # http://bugs.freedesktop.org/show_bug.cgi?id=15463
94 [[ ${CHOST} == *-solaris* ]] && append-flags -D_POSIX_PTHREAD_SEMANTICS
95
96 #gets rid of fbmmx.c inlining warnings
97 append-flags -finline-limit=1200
98
99 use X && myopts+=" --enable-tee=yes"
100
101 # --disable-xcb-lib:
102 # do not override good xlib backed by hardforcing rendering over xcb
103 econf \
104 --disable-dependency-tracking \
105 $(use_with X x) \
106 $(use_enable X xlib) \
107 $(use_enable X xlib-xrender) \
108 $(use_enable aqua quartz) \
109 $(use_enable aqua quartz-image) \
110 $(use_enable debug test-surfaces) \
111 $(use_enable directfb) \
112 $(use_enable glib gobject) \
113 $(use_enable doc gtk-doc) \
114 $(use_enable openvg vg) \
115 $(use_enable opengl gl) \
116 $(use_enable qt4 qt) \
117 $(use_enable static-libs static) \
118 $(use_enable svg) \
119 $(use_enable xcb) \
120 $(use_enable xcb xcb-shm) \
121 $(use_enable drm) \
122 $(use_enable gallium) \
123 --enable-ft \
124 --enable-pdf \
125 --enable-png \
126 --enable-ps \
127 --disable-xlib-xcb \
128 ${myopts}
129 }
130
131 src_install() {
132 # parallel make install fails
133 emake -j1 DESTDIR="${D}" install
134 find "${ED}" -name '*.la' -exec rm -f {} +
135 dodoc AUTHORS ChangeLog NEWS README
136 }

  ViewVC Help
Powered by ViewVC 1.1.20