x11-libs/gtksourceview/gtksourceview-3.2.3.ebuild

# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/x11-libs/gtksourceview/gtksourceview-3.2.3.ebuild,v 1.9 2012/07/15 18:59:11 armin76 Exp $

EAPI="4"
GCONF_DEBUG="no"
GNOME2_LA_PUNT="yes"

inherit gnome2 virtualx

DESCRIPTION="A text widget implementing syntax highlighting and other features"
HOMEPAGE="http://projects.gnome.org/gtksourceview/"

LICENSE="GPL-2+ LGPL-2.1+"
SLOT="3.0"
IUSE="glade +introspection"
KEYWORDS="alpha amd64 arm ia64 ~mips ppc ppc64 sh sparc x86 ~x86-fbsd ~x86-freebsd ~x86-interix ~amd64-linux ~x86-linux ~ppc-macos ~x86-solaris"

RDEPEND=">=x11-libs/gtk+-3.0:3[introspection?]
        >=dev-libs/libxml2-2.6:2
        >=dev-libs/glib-2.28:2
        glade? ( >=dev-util/glade-3.9:3.10 )
        introspection? ( >=dev-libs/gobject-introspection-0.9.0 )"
DEPEND="${RDEPEND}
        dev-util/gtk-doc-am
        >=dev-util/intltool-0.40
        >=sys-devel/gettext-0.17
        virtual/pkgconfig"

pkg_setup() {
        DOCS="AUTHORS ChangeLog HACKING MAINTAINERS NEWS README"
        G2CONF="${G2CONF}
                --disable-deprecations
                --enable-providers
                $(use_enable glade glade-catalog)
                $(use_enable introspection)"
}

src_prepare() {
        gnome2_src_prepare

        sed -i -e 's:--warn-all::' gtksourceview/Makefile.in || die

        # Skip broken test until upstream bug #621383 is solved
        sed -e "/guess-language/d" \
                -e "/get-language/d" \
                -i tests/test-languagemanager.c || die
}

src_test() {
        Xemake check
}

src_install() {
        gnome2_src_install

        insinto /usr/share/${PN}-3.0/language-specs
        doins "${FILESDIR}"/2.0/gentoo.lang
}
1	# Copyright 1999-2012 Gentoo Foundation
2	# Distributed under the terms of the GNU General Public License v2
3	# $Header: /var/cvsroot/gentoo-x86/x11-libs/gtksourceview/gtksourceview-3.2.3.ebuild,v 1.9 2012/07/15 18:59:11 armin76 Exp $
4
5	EAPI="4"
6	GCONF_DEBUG="no"
7	GNOME2_LA_PUNT="yes"
8
9	inherit gnome2 virtualx
10
11	DESCRIPTION="A text widget implementing syntax highlighting and other features"
12	HOMEPAGE="http://projects.gnome.org/gtksourceview/"
13
14	LICENSE="GPL-2+ LGPL-2.1+"
15	SLOT="3.0"
16	IUSE="glade +introspection"
17	KEYWORDS="alpha amd64 arm ia64 ~mips ppc ppc64 sh sparc x86 ~x86-fbsd ~x86-freebsd ~x86-interix ~amd64-linux ~x86-linux ~ppc-macos ~x86-solaris"
18
19	RDEPEND=">=x11-libs/gtk+-3.0:3[introspection?]
20	>=dev-libs/libxml2-2.6:2
21	>=dev-libs/glib-2.28:2
22	glade? ( >=dev-util/glade-3.9:3.10 )
23	introspection? ( >=dev-libs/gobject-introspection-0.9.0 )"
24	DEPEND="${RDEPEND}
25	dev-util/gtk-doc-am
26	>=dev-util/intltool-0.40
27	>=sys-devel/gettext-0.17
28	virtual/pkgconfig"
29
30	pkg_setup() {
31	DOCS="AUTHORS ChangeLog HACKING MAINTAINERS NEWS README"
32	G2CONF="${G2CONF}
33	--disable-deprecations
34	--enable-providers
35	$(use_enable glade glade-catalog)
36	$(use_enable introspection)"
37	}
38
39	src_prepare() {
40	gnome2_src_prepare
41
42	sed -i -e 's:--warn-all::' gtksourceview/Makefile.in \|\| die
43
44	# Skip broken test until upstream bug #621383 is solved
45	sed -e "/guess-language/d" \
46	-e "/get-language/d" \
47	-i tests/test-languagemanager.c \|\| die
48	}
49
50	src_test() {
51	Xemake check
52	}
53
54	src_install() {
55	gnome2_src_install
56
57	insinto /usr/share/${PN}-3.0/language-specs
58	doins "${FILESDIR}"/2.0/gentoo.lang
59	}