/[gentoo-x86]/x11-libs/libdrm/libdrm-2.4.40.ebuild
Gentoo

Contents of /x11-libs/libdrm/libdrm-2.4.40.ebuild

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.4 - (show annotations) (download)
Sun Nov 18 12:25:14 2012 UTC (21 months, 2 weeks ago) by ago
Branch: MAIN
Changes since 1.3: +2 -2 lines
Stable for x86, wrt bug #440872

(Portage version: 2.1.11.31/cvs/Linux x86_64, unsigned Manifest commit)

1 # Copyright 1999-2012 Gentoo Foundation
2 # Distributed under the terms of the GNU General Public License v2
3 # $Header: /var/cvsroot/gentoo-x86/x11-libs/libdrm/libdrm-2.4.40.ebuild,v 1.3 2012/11/16 16:42:20 ago Exp $
4
5 EAPI=4
6 inherit xorg-2
7
8 EGIT_REPO_URI="git://anongit.freedesktop.org/git/mesa/drm"
9
10 DESCRIPTION="X.Org libdrm library"
11 HOMEPAGE="http://dri.freedesktop.org/"
12 if [[ ${PV} = 9999* ]]; then
13 SRC_URI=""
14 else
15 SRC_URI="http://dri.freedesktop.org/${PN}/${P}.tar.bz2"
16 fi
17
18 KEYWORDS="~alpha amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc x86 ~amd64-fbsd ~x86-fbsd ~x64-freebsd ~x86-freebsd ~amd64-linux ~x86-linux ~sparc-solaris ~x64-solaris ~x86-solaris"
19 VIDEO_CARDS="exynos intel nouveau omap radeon vmware"
20 for card in ${VIDEO_CARDS}; do
21 IUSE_VIDEO_CARDS+=" video_cards_${card}"
22 done
23
24 IUSE="${IUSE_VIDEO_CARDS} libkms"
25 RESTRICT="test" # see bug #236845
26
27 RDEPEND="dev-libs/libpthread-stubs
28 video_cards_intel? ( >=x11-libs/libpciaccess-0.10 )"
29 DEPEND="${RDEPEND}"
30
31 PATCHES=(
32 "${FILESDIR}"/${PN}-2.4.28-solaris.patch
33 "${FILESDIR}"/${PN}-2.4.40-bsd-etime.patch
34 )
35
36 src_prepare() {
37 if [[ ${PV} = 9999* ]]; then
38 # tests are restricted, no point in building them
39 sed -ie 's/tests //' "${S}"/Makefile.am
40 fi
41 xorg-2_src_prepare
42 }
43
44 src_configure() {
45 XORG_CONFIGURE_OPTIONS=(
46 --enable-udev
47 $(use_enable video_cards_exynos exynos-experimental-api)
48 $(use_enable video_cards_intel intel)
49 $(use_enable video_cards_nouveau nouveau)
50 $(use_enable video_cards_omap omap-experimental-api)
51 $(use_enable video_cards_radeon radeon)
52 $(use_enable video_cards_vmware vmwgfx)
53 $(use_enable libkms)
54 )
55 xorg-2_src_configure
56 }

  ViewVC Help
Powered by ViewVC 1.1.20