x11-libs/qt-mobility/qt-mobility-1.2.2_p20120403.ebuild

# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/x11-libs/qt-mobility/qt-mobility-1.2.2_p20120403.ebuild,v 1.4 2012/08/12 01:42:32 pesa Exp $

EAPI=4

inherit multilib qt4-r2 toolchain-funcs

DESCRIPTION="Additional Qt APIs for mobile devices and desktop platforms"
HOMEPAGE="http://qt.nokia.com/products/qt-addons/mobility"
SRC_URI="http://dev.gentoo.org/~pesa/distfiles/${P}.tar.gz"
LICENSE="LGPL-2.1"
SLOT="0"
KEYWORDS="~amd64 ~x86"

QT_MOBILITY_MODULES=(bearer connectivity +contacts feedback gallery
                location messaging multimedia organizer publishsubscribe
                sensors serviceframework systeminfo versit)
IUSE="bluetooth debug doc networkmanager pulseaudio qml +tools
        ${QT_MOBILITY_MODULES[@]}"

REQUIRED_USE="
        || ( ${QT_MOBILITY_MODULES[@]#[+-]} )
        versit? ( contacts )
"

RDEPEND="
        >=x11-libs/qt-core-4.7.0:4
        bearer? (
                networkmanager? (
                        net-misc/networkmanager
                        >=x11-libs/qt-dbus-4.7.0:4
                )
        )
        connectivity? (
                >=x11-libs/qt-dbus-4.7.0:4
                bluetooth? ( net-wireless/bluez )
        )
        contacts? ( >=x11-libs/qt-gui-4.7.0:4 )
        gallery? ( >=x11-libs/qt-dbus-4.7.0:4 )
        location? (
                >=x11-libs/qt-declarative-4.7.0:4
                >=x11-libs/qt-gui-4.7.0:4
                >=x11-libs/qt-sql-4.7.0:4[sqlite]
        )
        messaging? ( >=net-libs/qmf-2.0_p201209 )
        multimedia? (
                media-libs/alsa-lib
                media-libs/gstreamer:0.10
                media-libs/gst-plugins-bad:0.10
                media-libs/gst-plugins-base:0.10
                x11-libs/libX11
                x11-libs/libXext
                x11-libs/libXv
                >=x11-libs/qt-gui-4.8.0-r4:4[xv]
                >=x11-libs/qt-opengl-4.8.0:4
                pulseaudio? ( media-sound/pulseaudio[alsa] )
        )
        publishsubscribe? (
                tools? ( >=x11-libs/qt-gui-4.7.0:4 )
        )
        qml? ( >=x11-libs/qt-declarative-4.7.0:4 )
        serviceframework? (
                >=x11-libs/qt-dbus-4.7.0:4
                >=x11-libs/qt-sql-4.7.0:4[sqlite]
                tools? ( >=x11-libs/qt-gui-4.7.0:4 )
        )
        systeminfo? (
                sys-apps/util-linux
                sys-fs/udev
                x11-libs/libX11
                x11-libs/libXrandr
                >=x11-libs/qt-dbus-4.7.0:4
                >=x11-libs/qt-gui-4.7.0:4
                bluetooth? ( net-wireless/bluez )
                networkmanager? ( net-misc/networkmanager )
        )
        versit? ( >=x11-libs/qt-gui-4.7.0:4 )
"
DEPEND="${RDEPEND}
        virtual/pkgconfig
        multimedia? (
                sys-kernel/linux-headers
                x11-proto/videoproto
        )
        systeminfo? ( sys-kernel/linux-headers )
"
PDEPEND="
        connectivity? (
                bluetooth? ( app-mobilephone/obexd )
        )
"

src_prepare() {
        qt4-r2_src_prepare

        # disable building of code snippets in doc/
        # and translations (they aren't actually translated)
        sed -i -re '/SUBDIRS \+= (doc|translations)/d' qtmobility.pro || die

        # fix automagic dependency on qt-declarative
        if ! use qml; then
                sed -i -e '/SUBDIRS += declarative/d' plugins/plugins.pro || die
        fi
}

src_configure() {
        # figure out which modules to build
        local modules=
        for mod in "${QT_MOBILITY_MODULES[@]#[+-]}"; do
                use ${mod} && modules+="${mod} "
        done

        if use messaging; then
                # tell qmake where QMF is installed
                export QMF_INCLUDEDIR=$($(tc-getPKG_CONFIG) --variable includedir qmfclient)
                export QMF_LIBDIR=$($(tc-getPKG_CONFIG) --variable libdir qmfclient)
        fi

        # custom configure script
        local myconf=(
                ./configure
                -prefix "${EPREFIX}/usr"
                -headerdir "${EPREFIX}/usr/include/qt4"
                -libdir "${EPREFIX}/usr/$(get_libdir)/qt4"
                -plugindir "${EPREFIX}/usr/$(get_libdir)/qt4/plugins"
                $(use debug && echo -debug || echo -release)
                $(use doc || echo -no-docs)
                $(use tools || echo -no-tools)
                -modules "${modules}"
        )
        echo "${myconf[@]}"
        "${myconf[@]}" || die "configure failed"

        # fix automagic dependency on bluez
        if ! use bluetooth; then
                sed -i -e '/^bluez_enabled =/s:yes:no:' config.pri || die
        fi
        # fix automagic dependency on networkmanager
        if ! use networkmanager; then
                sed -i -e '/^networkmanager_enabled =/s:yes:no:' config.pri || die
        fi
        # fix automagic dependency on pulseaudio
        if ! use pulseaudio; then
                sed -i -e '/^pulseaudio_enabled =/s:yes:no:' config.pri || die
        fi

        eqmake4 -recursive
}

src_compile() {
        qt4-r2_src_compile

        use doc && emake docs
}

src_install() {
        qt4-r2_src_install

        if use doc; then
                dohtml -r doc/html/*
                dodoc doc/qch/qtmobility.qch
                docompress -x /usr/share/doc/${PF}/qtmobility.qch
        fi
}
1	pesa	1.1	# Copyright 1999-2012 Gentoo Foundation
2			# Distributed under the terms of the GNU General Public License v2
3	pesa	1.5	# $Header: /var/cvsroot/gentoo-x86/x11-libs/qt-mobility/qt-mobility-1.2.2_p20120403.ebuild,v 1.4 2012/08/12 01:42:32 pesa Exp $
4	pesa	1.1
5			EAPI=4
6
7			inherit multilib qt4-r2 toolchain-funcs
8
9			DESCRIPTION="Additional Qt APIs for mobile devices and desktop platforms"
10			HOMEPAGE="http://qt.nokia.com/products/qt-addons/mobility"
11			SRC_URI="http://dev.gentoo.org/~pesa/distfiles/${P}.tar.gz"
12			LICENSE="LGPL-2.1"
13			SLOT="0"
14			KEYWORDS="~amd64 ~x86"
15
16	pesa	1.3	QT_MOBILITY_MODULES=(bearer connectivity +contacts feedback gallery
17	pesa	1.1	location messaging multimedia organizer publishsubscribe
18			sensors serviceframework systeminfo versit)
19			IUSE="bluetooth debug doc networkmanager pulseaudio qml +tools
20			${QT_MOBILITY_MODULES[@]}"
21
22			REQUIRED_USE="
23			\|\| ( ${QT_MOBILITY_MODULES[@]#[+-]} )
24			versit? ( contacts )
25			"
26
27			RDEPEND="
28			>=x11-libs/qt-core-4.7.0:4
29			bearer? (
30			networkmanager? (
31			net-misc/networkmanager
32			>=x11-libs/qt-dbus-4.7.0:4
33			)
34			)
35			connectivity? (
36			>=x11-libs/qt-dbus-4.7.0:4
37			bluetooth? ( net-wireless/bluez )
38			)
39	pesa	1.4	contacts? ( >=x11-libs/qt-gui-4.7.0:4 )
40	pesa	1.1	gallery? ( >=x11-libs/qt-dbus-4.7.0:4 )
41			location? (
42			>=x11-libs/qt-declarative-4.7.0:4
43			>=x11-libs/qt-gui-4.7.0:4
44			>=x11-libs/qt-sql-4.7.0:4[sqlite]
45			)
46			messaging? ( >=net-libs/qmf-2.0_p201209 )
47			multimedia? (
48			media-libs/alsa-lib
49	pesa	1.5	media-libs/gstreamer:0.10
50			media-libs/gst-plugins-bad:0.10
51			media-libs/gst-plugins-base:0.10
52	pesa	1.1	x11-libs/libX11
53			x11-libs/libXext
54			x11-libs/libXv
55			>=x11-libs/qt-gui-4.8.0-r4:4[xv]
56			>=x11-libs/qt-opengl-4.8.0:4
57			pulseaudio? ( media-sound/pulseaudio[alsa] )
58			)
59			publishsubscribe? (
60			tools? ( >=x11-libs/qt-gui-4.7.0:4 )
61			)
62			qml? ( >=x11-libs/qt-declarative-4.7.0:4 )
63			serviceframework? (
64			>=x11-libs/qt-dbus-4.7.0:4
65			>=x11-libs/qt-sql-4.7.0:4[sqlite]
66			tools? ( >=x11-libs/qt-gui-4.7.0:4 )
67			)
68			systeminfo? (
69			sys-apps/util-linux
70			sys-fs/udev
71			x11-libs/libX11
72			x11-libs/libXrandr
73			>=x11-libs/qt-dbus-4.7.0:4
74			>=x11-libs/qt-gui-4.7.0:4
75			bluetooth? ( net-wireless/bluez )
76			networkmanager? ( net-misc/networkmanager )
77			)
78			versit? ( >=x11-libs/qt-gui-4.7.0:4 )
79			"
80			DEPEND="${RDEPEND}
81	pesa	1.2	virtual/pkgconfig
82	pesa	1.1	multimedia? (
83			sys-kernel/linux-headers
84			x11-proto/videoproto
85			)
86			systeminfo? ( sys-kernel/linux-headers )
87			"
88			PDEPEND="
89			connectivity? (
90			bluetooth? ( app-mobilephone/obexd )
91			)
92			"
93
94			src_prepare() {
95			qt4-r2_src_prepare
96
97			# disable building of code snippets in doc/
98			# and translations (they aren't actually translated)
99			sed -i -re '/SUBDIRS \+= (doc\|translations)/d' qtmobility.pro \|\| die
100
101			# fix automagic dependency on qt-declarative
102			if ! use qml; then
103			sed -i -e '/SUBDIRS += declarative/d' plugins/plugins.pro \|\| die
104			fi
105			}
106
107			src_configure() {
108			# figure out which modules to build
109			local modules=
110			for mod in "${QT_MOBILITY_MODULES[@]#[+-]}"; do
111			use ${mod} && modules+="${mod} "
112			done
113
114			if use messaging; then
115			# tell qmake where QMF is installed
116			export QMF_INCLUDEDIR=$($(tc-getPKG_CONFIG) --variable includedir qmfclient)
117			export QMF_LIBDIR=$($(tc-getPKG_CONFIG) --variable libdir qmfclient)
118			fi
119
120			# custom configure script
121			local myconf=(
122			./configure
123			-prefix "${EPREFIX}/usr"
124			-headerdir "${EPREFIX}/usr/include/qt4"
125			-libdir "${EPREFIX}/usr/$(get_libdir)/qt4"
126			-plugindir "${EPREFIX}/usr/$(get_libdir)/qt4/plugins"
127			$(use debug && echo -debug \|\| echo -release)
128			$(use doc \|\| echo -no-docs)
129			$(use tools \|\| echo -no-tools)
130			-modules "${modules}"
131			)
132			echo "${myconf[@]}"
133			"${myconf[@]}" \|\| die "configure failed"
134
135			# fix automagic dependency on bluez
136			if ! use bluetooth; then
137			sed -i -e '/^bluez_enabled =/s:yes:no:' config.pri \|\| die
138			fi
139			# fix automagic dependency on networkmanager
140			if ! use networkmanager; then
141			sed -i -e '/^networkmanager_enabled =/s:yes:no:' config.pri \|\| die
142			fi
143			# fix automagic dependency on pulseaudio
144			if ! use pulseaudio; then
145			sed -i -e '/^pulseaudio_enabled =/s:yes:no:' config.pri \|\| die
146			fi
147
148			eqmake4 -recursive
149			}
150
151			src_compile() {
152			qt4-r2_src_compile
153
154			use doc && emake docs
155			}
156
157			src_install() {
158			qt4-r2_src_install
159
160			if use doc; then
161			dohtml -r doc/html/*
162			dodoc doc/qch/qtmobility.qch
163			docompress -x /usr/share/doc/${PF}/qtmobility.qch
164			fi
165			}