/[gentoo-x86]/x11-terms/kterm/kterm-6.2.0-r5.ebuild
Gentoo

Contents of /x11-terms/kterm/kterm-6.2.0-r5.ebuild

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.8 - (show annotations) (download)
Thu Aug 9 13:50:56 2012 UTC (2 years, 1 month ago) by ottxor
Branch: MAIN
Changes since 1.7: +8 -10 lines
added prefix support

(Portage version: 2.2.0_alpha120/cvs/Linux i686)

1 # Copyright 1999-2012 Gentoo Foundation
2 # Distributed under the terms of the GNU General Public License v2
3 # $Header: /var/cvsroot/gentoo-x86/x11-terms/kterm/kterm-6.2.0-r5.ebuild,v 1.7 2012/05/31 08:27:25 ago Exp $
4
5 EAPI=4
6
7 inherit eutils flag-o-matic toolchain-funcs
8
9 DESCRIPTION="Japanese Kanji X Terminal"
10 SRC_URI="ftp://ftp.x.org/contrib/applications/${P}.tar.gz
11 http://www.asahi-net.or.jp/~hc3j-tkg/kterm/${P}-wpi.patch.gz
12 http://www.st.rim.or.jp/~hanataka/${P}.ext02.patch.gz"
13 # until someone who reads japanese can find a better place
14 HOMEPAGE="http://www.asahi-net.or.jp/~hc3j-tkg/kterm/"
15
16 LICENSE="MIT as-is"
17 SLOT="0"
18 KEYWORDS="-alpha amd64 ppc ~sparc x86 ~amd64-linux ~x86-linux ~ppc-macos"
19 IUSE="Xaw3d"
20
21 RDEPEND="app-text/rman
22 sys-libs/ncurses
23 x11-libs/libXmu
24 x11-libs/libXpm
25 x11-libs/libxkbfile
26 x11-libs/libXaw
27 x11-libs/libXp
28 Xaw3d? ( x11-libs/libXaw3d )"
29 DEPEND="${RDEPEND}
30 x11-misc/gccmakedep
31 x11-misc/imake"
32
33 src_prepare(){
34 epatch "${WORKDIR}"/${P}-wpi.patch # wallpaper patch
35 epatch "${WORKDIR}"/${P}.ext02.patch # JIS 0213 support
36 epatch "${FILESDIR}"/${P}-openpty.patch
37 epatch "${FILESDIR}"/${P}-gentoo.patch
38 epatch "${FILESDIR}"/${PN}-ad-gentoo.diff
39 epatch "${FILESDIR}"/${PV}-underline.patch
40
41 if use Xaw3d ; then
42 epatch "${FILESDIR}"/kterm-6.2.0-Xaw3d.patch
43 fi
44 }
45
46 src_compile(){
47 xmkmf -a || die
48 emake CC="$(tc-getCC)" CDEBUGFLAGS="${CFLAGS}" LOCAL_LDFLAGS="${LDFLAGS}" \
49 XAPPLOADDIR="${EPREFIX}"/usr/share/X11/app-defaults
50 }
51
52 src_install(){
53 emake DESTDIR="${D}" BINDIR="${EPREFIX}"/usr/bin XAPPLOADDIR="${EPREFIX}"/usr/share/X11/app-defaults install
54
55 # install man pages
56 newman kterm.man kterm.1
57 insinto /usr/share/man/ja/man1
58 iconv -f ISO-2022-JP -t EUC-JP kterm.jman > kterm.ja.1
59 newins kterm.ja.1 kterm.1
60
61 # Remove link to avoid collision
62 rm -f "${ED}"/usr/lib/X11/app-defaults
63
64 dodoc README.kt
65 }
66
67 pkg_postinst() {
68 elog
69 elog "KTerm wallpaper support is enabled."
70 elog "In order to use this feature,"
71 elog "you need specify favourite xpm file with -wp option"
72 elog
73 elog "\t% kterm -wp filename.xpm"
74 elog
75 elog "or set it with X resource"
76 elog
77 elog "\tKTerm*wallPaper: /path/to/filename.xpm"
78 elog
79 }

  ViewVC Help
Powered by ViewVC 1.1.20