/[gentoo-x86]/x11-terms/xterm/xterm-281.ebuild
Gentoo

Contents of /x11-terms/xterm/xterm-281.ebuild

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.2 - (show annotations) (download)
Wed Jan 9 16:23:40 2013 UTC (20 months, 1 week ago) by ssuominen
Branch: MAIN
CVS Tags: HEAD
Changes since 1.1: +1 -1 lines
FILE REMOVED
old

(Portage version: 2.2.0_alpha149/cvs/Linux x86_64, signed Manifest commit with key 4868F14D)

1 # Copyright 1999-2012 Gentoo Foundation
2 # Distributed under the terms of the GNU General Public License v2
3 # $Header: /var/cvsroot/gentoo-x86/x11-terms/xterm/xterm-281.ebuild,v 1.1 2012/06/26 17:30:06 ssuominen Exp $
4
5 EAPI=4
6 inherit eutils multilib
7
8 DESCRIPTION="Terminal Emulator for X Windows"
9 HOMEPAGE="http://dickey.his.com/xterm/"
10 SRC_URI="ftp://invisible-island.net/${PN}/${P}.tgz"
11
12 LICENSE="MIT"
13 SLOT="0"
14 KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~x86-interix ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
15 IUSE="toolbar truetype unicode Xaw3d"
16
17 COMMON_DEPEND="kernel_linux? ( sys-libs/libutempter )
18 kernel_FreeBSD? ( || ( >=sys-freebsd/freebsd-lib-9.0 sys-libs/libutempter ) )
19 >=sys-libs/ncurses-5.7-r7
20 x11-apps/xmessage
21 x11-libs/libX11
22 x11-libs/libXaw
23 x11-libs/libXft
24 x11-libs/libxkbfile
25 x11-libs/libXmu
26 x11-libs/libXrender
27 x11-libs/libXt
28 unicode? ( x11-apps/luit )
29 Xaw3d? ( x11-libs/libXaw3d )"
30 RDEPEND="${COMMON_DEPEND}
31 media-fonts/font-misc-misc"
32 DEPEND="${COMMON_DEPEND}
33 virtual/pkgconfig
34 x11-proto/kbproto
35 x11-proto/xproto"
36
37 pkg_setup() {
38 DEFAULTS_DIR="${EPREFIX}"/usr/share/X11/app-defaults
39 }
40
41 src_configure() {
42 # looking for reason why crosscompile failed? try restoring this:
43 # --x-libraries="${ROOT}usr/$(get_libdir)"
44 # -ssuominen, 2011
45
46 econf \
47 --libdir="${EPREFIX}"/etc \
48 --disable-full-tgetent \
49 --with-app-defaults=${DEFAULTS_DIR} \
50 --disable-setuid \
51 --disable-setgid \
52 --with-utempter \
53 --with-x \
54 $(use_with Xaw3d) \
55 --disable-imake \
56 --enable-256-color \
57 --enable-broken-osc \
58 --enable-broken-st \
59 --enable-exec-xterm \
60 $(use_enable truetype freetype) \
61 --enable-i18n \
62 --enable-load-vt-fonts \
63 --enable-logging \
64 $(use_enable toolbar) \
65 $(use_enable unicode mini-luit) \
66 $(use_enable unicode luit) \
67 --enable-wide-chars \
68 --enable-dabbrev \
69 --enable-warnings
70 }
71
72 src_install() {
73 emake DESTDIR="${D}" install
74 dodoc README{,.i18n} ctlseqs.txt
75 dohtml xterm.log.html
76 domenu *.desktop
77
78 # Fix permissions -- it grabs them from live system, and they can
79 # be suid or sgid like they were in pre-unix98 pty or pre-utempter days,
80 # respectively (#69510).
81 # (info from Thomas Dickey) - Donnie Berkholz <spyderous@gentoo.org>
82 fperms 0755 /usr/bin/xterm
83
84 # restore the navy blue
85 sed -i -e "s:blue2$:blue:" "${ED}"${DEFAULTS_DIR}/XTerm-color
86 }

  ViewVC Help
Powered by ViewVC 1.1.20