/[path-sandbox]/trunk/configure.ac
Gentoo

Contents of /trunk/configure.ac

Parent Directory Parent Directory | Revision Log Revision Log


Revision 234 - (show annotations) (download)
Mon Dec 5 17:14:24 2005 UTC (8 years, 10 months ago) by azarah
File size: 4378 byte(s)
Indentation fixes and other cleanups.
1 AC_PREREQ([2.59])
2 AC_INIT([sandbox], [1.2.17], [sandbox@gentoo.org])
3 AM_INIT_AUTOMAKE
4 AC_CONFIG_HEADER([config.h])
5
6 dnl Checks for programs.
7 AC_PROG_CC
8 AC_ISC_POSIX
9 AC_PROG_INSTALL
10 AC_PROG_MAKE_SET
11 AC_PROG_AWK
12 AC_CHECK_PROGS([READELF], [readelf], [false])
13
14 AC_ENABLE_SHARED
15 AC_DISABLE_STATIC
16 dnl Next four lines is a hack to prevent libtool checking for CXX/F77
17 m4_undefine([AC_PROG_CXX])
18 m4_defun([AC_PROG_CXX],[])
19 m4_undefine([AC_PROG_F77])
20 m4_defun([AC_PROG_F77],[])
21 AC_PROG_LIBTOOL
22
23 AC_PREFIX_DEFAULT([/usr])
24
25 dnl Checks for libraries.
26 dnl Checks for header files.
27 AC_FUNC_ALLOCA
28 AC_HEADER_DIRENT
29 AC_HEADER_STDC
30 AC_HEADER_SYS_WAIT
31 AC_CHECK_HEADERS([ \
32 fcntl.h limits.h memory.h stddef.h \
33 stdlib.h string.h strings.h sys/file.h \
34 sys/param.h sys/time.h unistd.h utime.h \
35 ])
36
37 dnl Checks for typedefs, structures, and compiler characteristics.
38 AC_C_CONST
39 AC_TYPE_UID_T
40 AC_TYPE_MODE_T
41 AC_TYPE_SIZE_T
42 AC_CHECK_TYPES([ptrdiff_t])
43
44 dnl Checks for library functions.
45 AC_FUNC_CHOWN
46 AC_FUNC_FORK
47 AC_FUNC_LSTAT
48 AC_FUNC_LSTAT_FOLLOWS_SLASHED_SYMLINK
49 AC_TYPE_SIGNAL
50 AC_FUNC_STAT
51 AC_CHECK_FUNCS([ \
52 bzero ftruncate getcwd lchown memmove \
53 memcpy memset mkdir pathconf realpath \
54 rmdir setenv strcasecmp strchr strdup \
55 strerror strndup strrchr strspn strstr \
56 ])
57
58 dnl Some libc's like those on bsd have dlopen() in libc, and not libdl
59 AC_CHECK_LIB([dl], [dlopen],
60 [have_libdl="yes"],
61 [have_libdl="no"]
62 )
63 if test x"$have_libdl" = xyes ; then
64 LIBDL="-ldl"
65 AC_SUBST([LIBDL])
66 DL_LIB="dl"
67 else
68 DL_LIB="c"
69 AC_CHECK_LIB([c], [dlopen],
70 [],
71 [AC_MSG_ERROR([Unable to determine library providing dlopen])]
72 )
73 fi
74
75 dnl uClibc doesn't currently provide dlvsym() so lets
76 dnl verify the toolchain supports it
77 AC_CHECK_LIB([$DL_LIB], [dlvsym],
78 [AC_DEFINE([HAVE_DLVSYM], [1], [libdl supports dlvsym])],
79 [AC_DEFINE([HAVE_DLVSYM], [0], [libdl does not support dlvsym])]
80 )
81
82 dnl when using libc5, (f)trucate's offset argument type is size_t with
83 dnl libc5, but it's off_t with libc6 (glibc2).
84 AC_MSG_CHECKING([truncate argument type])
85 TRUNC_ARG_TYPE=`echo '#include <unistd.h>' | $CC -E - | grep -q 'truncate.*size_t'`
86 if test "$TRUNC_ARG_TYPE"x != x ; then
87 AC_MSG_RESULT([size_t])
88 AC_DEFINE([TRUNCATE_T], [size_t], [truncate arg type])
89 else
90 AC_MSG_RESULT([off_t])
91 AC_DEFINE([TRUNCATE_T], [off_t], [truncate arg type])
92 fi
93
94 dnl Check if libc provides RTLD_NEXT
95 AC_MSG_CHECKING([for RTLD_NEXT])
96 AC_TRY_COMPILE([
97 #define _GNU_SOURCE
98 #include <dlfcn.h>
99 ], [
100 #if !defined(RTLD_NEXT)
101 # error no RTLD_NEXT
102 #endif
103 ],
104 [have_rtld_next="yes"],
105 [have_rtld_next="no"]
106 )
107 AC_MSG_RESULT([$have_rtld_next])
108 AM_CONDITIONAL([HAVE_RTLD_NEXT], [test x"$have_rtld_next" = xyes])
109
110 dnl we need to handle symbols differently based upon their version,
111 dnl but we have to know which symbols the libc supports first
112 AC_MSG_CHECKING([libc path])
113 echo "int main(void) { return 0; }" > libctest.c
114 LIBC_PATH=`$CC $CFLAGS -Wl,-verbose -o libctest libctest.c 2>&1 | \
115 $AWK '/attempt to open/ { if (($4 ~ /\/libc\.so/) && ($5 == "succeeded")) LIBC = $4; }; END {print LIBC}'`
116 rm -f libctest*
117 if test "$LIBC_PATH"x = x || ! test -r "$LIBC_PATH"; then
118 AC_MSG_ERROR([Unable to determine LIBC PATH])
119 fi
120 AC_MSG_RESULT([$LIBC_PATH])
121 AC_SUBST([LIBC_PATH])
122
123 dnl when intercepting libc calls, we have to know the name of the
124 dnl libc to load and search with dl*() calls
125 AC_MSG_CHECKING([libc version])
126 dnl the sed script at the end here looks funny but it's ok ...
127 dnl they're m4 escape sequences for left and right brackets
128 echo "int main(void) { return 0; }" > libctest.c
129 $CC -Wall -o libctest libctest.c
130 LIBC_VERSION=`readelf -d libctest | grep NEEDED.*libc\\.so | $AWK '{print $NF}' | sed -e 's:\@<:@::' -e 's:\@:>@::'`
131 rm -f libctest*
132 if test "$LIBC_VERSION"x = x ; then
133 AC_MSG_ERROR([Unable to determine LIBC VERSION])
134 fi
135 AC_MSG_RESULT([$LIBC_VERSION])
136 AC_DEFINE_UNQUOTED([LIBC_VERSION], ["$LIBC_VERSION"], [Name of libc to hook into])
137
138 dnl check if we have 32bit or 64bit output
139 AC_ARG_ENABLE([multilib],
140 AS_HELP_STRING([--enable-multilib],
141 [enable building for multilib setups (default=disabled)]),
142 [enable_multilib="$enableval"],
143 [enable_multilib="no"]
144 )
145
146 if test x"$enable_multilib" != xno ; then
147 AC_DEFINE([SB_HAVE_MULTILIB], [1], [Have multilib enabled system])
148 fi
149
150 AC_OUTPUT([
151 Makefile
152 scripts/Makefile
153 data/Makefile
154 src/Makefile
155 ])

Properties

Name Value
svn:eol-style native
svn:keywords Author Date Id Revision

  ViewVC Help
Powered by ViewVC 1.1.20