/[gentoo-x86]/app-admin/elektra/elektra-0.7.1-r3.ebuild
Gentoo

Contents of /app-admin/elektra/elektra-0.7.1-r3.ebuild

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.1 - (show annotations) (download)
Sat Apr 13 00:24:42 2013 UTC (6 years, 10 months ago) by xmw
Branch: MAIN
Revbump to address bug 463868, thanks Andreas Sturmlechner

(Portage version: 2.2.0_alpha171/cvs/Linux x86_64, signed Manifest commit with key 62EEF090)

1 # Copyright 1999-2013 Gentoo Foundation
2 # Distributed under the terms of the GNU General Public License v2
3 # $Header: /var/cvsroot/gentoo-x86/app-admin/elektra/elektra-0.7.1-r2.ebuild,v 1.3 2012/11/06 19:26:18 mr_bones_ Exp $
4
5 EAPI=4
6
7 inherit autotools eutils
8
9 DESCRIPTION="universal and secure framework to store config parameters in a hierarchical key-value pair mechanism"
10 HOMEPAGE="http://freedesktop.org/wiki/Software/Elektra"
11 SRC_URI="ftp://ftp.markus-raab.org/${PN}/${P}.tar.gz"
12
13 LICENSE="BSD"
14 SLOT="0"
15 KEYWORDS="~amd64 ~x86"
16 IUSE="gcov iconv static-libs test"
17
18 RDEPEND="dev-libs/libxml2"
19 DEPEND="${RDEPEND}
20 sys-devel/libtool
21 iconv? ( virtual/libiconv )
22 test? ( dev-libs/libxml2[static-libs] )"
23
24 src_prepare() {
25 einfo 'Removing bundled libltdl'
26 rm -rf libltdl || die
27
28 epatch \
29 "${FILESDIR}"/${P}-test.patch \
30 "${FILESDIR}"/${P}-ltdl.patch \
31 "${FILESDIR}"/${P}-automake-1.12.patch \
32 "${FILESDIR}"/${P}-remove-ddefault-link.patch
33
34 touch config.rpath
35 eautoreconf
36 }
37
38 src_configure() {
39 # berkeleydb, daemon, fstab, gconf, python do not work
40 econf \
41 --enable-filesys \
42 --enable-hosts \
43 --enable-ini \
44 --enable-passwd \
45 --disable-berkeleydb \
46 --disable-fstab \
47 --disable-gconf \
48 --disable-daemon \
49 --enable-cpp \
50 --disable-python \
51 $(use_enable gcov) \
52 $(use_enable iconv) \
53 $(use_enable static-libs static) \
54 --with-docdir=/usr/share/doc/${PF} \
55 --with-develdocdir=/usr/share/doc/${PF}
56 }
57
58 src_install() {
59 emake DESTDIR="${D}" install
60
61 local my_f=""
62 #avoid collision with kerberos (bug 403025)
63 for my_f in kdb kdbbackend.h kdbos.h kdbtools.h keyset kdb.h \
64 kdbloader.h kdbprivate.h key ; do
65 mv "${D}"/usr/include/{,elektra-}"${my_f}" || die
66 elog "/usr/include/${my_f} installed as elektra-${my_f}"
67 done
68 sed -e '/^#include/s:kdbos.h:elektra-kdbos.h:' \
69 -i "${D}"/usr/include/elektra-kdb.h || die
70
71 #avoid collision with allegro (bug 409305)
72 for my_f in $(find "${D}"/usr/share/man/man3 -name "key.3*") ; do
73 mv "${my_f}" "${my_f/key/elektra-key}" || die
74 elog "/usr/share/man/man3/$(basename "${my_f}") installed as $(basename "${my_f/key/elektra-key}")"
75 done
76
77 if ! use static-libs; then
78 find "${D}" -name "*.a" -delete || die
79 fi
80
81 dodoc AUTHORS ChangeLog NEWS README TODO
82 }

  ViewVC Help
Powered by ViewVC 1.1.20