/[gentoo-x86]/app-admin/elektra/elektra-0.8.3-r3.ebuild
Gentoo

Contents of /app-admin/elektra/elektra-0.8.3-r3.ebuild

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.1 - (show annotations) (download)
Sun Jun 22 10:01:43 2014 UTC (5 years, 7 months ago) by mgorny
Branch: MAIN
CVS Tags: HEAD
Fix dependencies. Clean up. Restrict tests since they try to write to home directory without respecting ${HOME}.

(Portage version: 2.2.10/cvs/Linux x86_64, signed Manifest commit with key EFB4464E!)

1 # Copyright 1999-2014 Gentoo Foundation
2 # Distributed under the terms of the GNU General Public License v2
3 # $Header: /var/cvsroot/gentoo-x86/app-admin/elektra/elektra-0.8.3-r2.ebuild,v 1.1 2013/04/22 14:17:35 xmw Exp $
4
5 EAPI=5
6
7 inherit cmake-multilib eutils
8
9 DESCRIPTION="universal and secure framework to store config parameters in a hierarchical key-value pair mechanism"
10 HOMEPAGE="http://freedesktop.org/wiki/Software/Elektra"
11 SRC_URI="ftp://ftp.markus-raab.org/${PN}/releases/${P}.tar.gz"
12
13 LICENSE="BSD"
14 SLOT="0"
15 KEYWORDS="~amd64 ~x86"
16 IUSE="dbus doc examples iconv inifile simpleini static-libs syslog tcl test xml yajl"
17
18 RDEPEND=">=dev-libs/libxml2-2.9.1-r4[${MULTILIB_USEDEP}]
19 dbus? ( >=sys-apps/dbus-1.6.18-r1[${MULTILIB_USEDEP}] )
20 iconv? ( >=virtual/libiconv-0-r1[${MULTILIB_USEDEP}] )
21 yajl? (
22 <dev-libs/yajl-2[${MULTILIB_USEDEP}]
23 >=dev-libs/yajl-1.0.11-r1[${MULTILIB_USEDEP}]
24 )"
25 DEPEND="${RDEPEND}
26 sys-devel/libtool
27 doc? ( app-doc/doxygen )"
28
29 # tries to write to user's home directory (and doesn't respect HOME)
30 RESTRICT="test"
31
32 src_prepare() {
33 #fix QA issues with upstream patches
34 epatch "${FILESDIR}/${P}-introduce-attributes.patch"
35 epatch "${FILESDIR}/${P}-fix-yajl-if-user-config.patch"
36
37 #move doc files to correct location
38 sed -e "s/elektra-api/${PF}/" \
39 -i cmake/ElektraCache.cmake || die
40
41 cmake-utils_src_prepare
42 }
43
44 multilib_src_configure() {
45 local my_plugins="ccode;dump;error;fstab;glob;hexcode;hidden;hosts;network;ni;null;path;resolver;struct;success;template;timeofday;tracer;type;validation"
46
47 use dbus && my_plugins+=";dbus"
48 use doc && my_plugins+=";doc"
49 use iconv && my_plugins+=";iconv"
50 use inifile && my_plugins+=";simpleini"
51 use syslog && my_plugins+=";syslog"
52 use tcl && my_plugins+=";tcl"
53 use xml && my_plugins+=";xmltool"
54 use yajl && my_plugins+=";yajl"
55
56 mycmakeargs=(
57 "-DPLUGINS=${my_plugins}"
58 "-DLATEX_COMPILER=OFF"
59 "-DTARGET_CMAKE_FOLDER=share/cmake/Modules"
60 $(multilib_is_native_abi && cmake-utils_use doc BUILD_DOCUMENTATION \
61 || echo -DBUILD_DOCUMENTATION=OFF)
62 $(multilib_is_native_abi && cmake-utils_use examples BUILD_EXAMPLES \
63 || echo -DBUILD_EXAMPLES=OFF)
64 $(cmake-utils_use static-libs BUILD_STATIC)
65 $(cmake-utils_use test BUILD_TESTING)
66 )
67
68 cmake-utils_src_configure
69 }
70
71 src_compile() {
72 dodir /usr/share/man/man3
73 cmake-multilib_src_compile
74 }
75
76 multilib_src_install() {
77 cmake-utils_src_install
78
79 if multilib_is_native_abi && use doc; then
80 rm -rf "${D}/usr/share/doc/${PF}/man" || die
81 cd doc/man/man3 || die
82 local my_f
83 for my_f in *.3 ; do
84 newman ${my_f} ${PN}-${my_f}
85 elog "installed /usr/share/man/man3/${my_f} as ${PN}-${my_f}"
86 done
87 fi
88 }
89
90 multilib_src_install_all() {
91 dodoc doc/{AUTHORS,CHANGES,NEWS,README,todo/TODO}
92 }

  ViewVC Help
Powered by ViewVC 1.1.20