/[gentoo-x86]/app-admin/webapp-config/webapp-config-1.52-r1.ebuild
Gentoo

Contents of /app-admin/webapp-config/webapp-config-1.52-r1.ebuild

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.13 - (show annotations) (download)
Wed Apr 8 07:30:31 2015 UTC (3 years, 7 months ago) by mgorny
Branch: MAIN
CVS Tags: HEAD
Changes since 1.12: +3 -3 lines
Remove old Python implementations

(Portage version: 2.2.18/cvs/Linux x86_64, signed Manifest commit with key EFB4464E!)

1 # Copyright 1999-2015 Gentoo Foundation
2 # Distributed under the terms of the GNU General Public License v2
3 # $Header: /var/cvsroot/gentoo-x86/app-admin/webapp-config/webapp-config-1.52-r1.ebuild,v 1.12 2014/12/28 06:33:54 floppym Exp $
4
5 EAPI="5"
6
7 PYTHON_COMPAT=( python{2_7,3_3} )
8
9 inherit distutils-r1
10
11 SRC_URI="http://dev.gentoo.org/~twitch153/${PN}/${P}.tar.bz2"
12 KEYWORDS="alpha amd64 arm hppa ia64 ~m68k ~mips ppc ppc64 ~s390 ~sh sparc x86 ~x86-fbsd"
13
14 DESCRIPTION="Gentoo's installer for web-based applications"
15 HOMEPAGE="http://sourceforge.net/projects/webapp-config/"
16
17 LICENSE="GPL-2"
18 SLOT="0"
19 IUSE="+portage"
20
21 DEPEND="app-text/xmlto
22 !dev-python/configparser"
23 RDEPEND="portage? ( sys-apps/portage[${PYTHON_USEDEP}] )"
24
25 python_prepare() {
26 epatch "${FILESDIR}/${P}-nulls-doctest.patch"
27 }
28
29 python_compile_all() {
30 emake -C doc/
31 }
32
33 python_install() {
34 # According to this discussion:
35 # http://mail.python.org/pipermail/distutils-sig/2004-February/003713.html
36 # distutils does not provide for specifying two different script install
37 # locations. Since we only install one script here the following should
38 # be ok
39 distutils-r1_python_install --install-scripts="/usr/sbin"
40 }
41
42 python_install_all() {
43 distutils-r1_python_install_all
44
45 insinto /etc/vhosts
46 doins config/webapp-config
47
48 keepdir /usr/share/webapps
49 keepdir /var/db/webapps
50
51 dodoc AUTHORS
52 doman doc/*.[58]
53 dohtml doc/*.[58].html
54 }
55
56 python_test() {
57 PYTHONPATH="." "${PYTHON}" WebappConfig/tests/dtest.py \
58 || die "Testing failed with ${EPYTHON}"
59 }
60
61 pkg_postinst() {
62 elog "Now that you have upgraded webapp-config, you **must** update your"
63 elog "config files in /etc/vhosts/webapp-config before you emerge any"
64 elog "packages that use webapp-config."
65 }

  ViewVC Help
Powered by ViewVC 1.1.20