/[gentoo-x86]/app-arch/dpkg/dpkg-1.17.8.ebuild
Gentoo

Contents of /app-arch/dpkg/dpkg-1.17.8.ebuild

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.3 - (show annotations) (download)
Wed Apr 30 13:59:36 2014 UTC (6 years, 2 months ago) by ago
Branch: MAIN
Changes since 1.2: +2 -2 lines
Stable for amd64, wrt bug #509018

(Portage version: 2.2.8-r1/cvs/Linux x86_64, RepoMan options: --include-arches="amd64", signed Manifest commit with key 7194459F)

1 # Copyright 1999-2014 Gentoo Foundation
2 # Distributed under the terms of the GNU General Public License v2
3 # $Header: /var/cvsroot/gentoo-x86/app-arch/dpkg/dpkg-1.17.8.ebuild,v 1.2 2014/04/29 03:16:25 jer Exp $
4
5 EAPI=5
6 inherit eutils multilib autotools toolchain-funcs
7
8 DESCRIPTION="Package maintenance system for Debian"
9 HOMEPAGE="http://packages.qa.debian.org/dpkg"
10 SRC_URI="mirror://debian/pool/main/d/${PN}/${P/-/_}.tar.xz"
11
12 LICENSE="GPL-2"
13 SLOT="0"
14 KEYWORDS="~alpha amd64 ~arm hppa ~ia64 ~m68k ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-linux ~ia64-linux ~x86-linux ~ppc-macos ~x64-solaris ~x86-solaris"
15 IUSE="+bzip2 dselect +lzma nls test unicode +update-alternatives +zlib"
16 REQUIRED_USE="dselect? ( nls )"
17
18 RDEPEND="
19 >=dev-lang/perl-5.6.0
20 dev-perl/TimeDate
21 >=sys-libs/ncurses-5.2-r7
22 lzma? ( app-arch/xz-utils )
23 zlib? ( >=sys-libs/zlib-1.1.4 )
24 bzip2? ( app-arch/bzip2 )
25 "
26 DEPEND="
27 ${RDEPEND}
28 app-arch/xz-utils
29 sys-devel/flex
30 virtual/pkgconfig
31 nls? (
32 app-text/po4a
33 >=sys-devel/gettext-0.18.2
34 )
35 test? (
36 dev-perl/DateTime-Format-DateParse
37 dev-perl/IO-String
38 dev-perl/Test-Pod
39 virtual/perl-Test-Harness
40 )
41 "
42
43 DOCS=( ChangeLog THANKS TODO )
44
45 src_prepare() {
46 # do not expect Debian's gzip --rsyncable extension
47 epatch "${FILESDIR}"/${PN}-1.17.0-gzip-rsyncable.patch
48
49 epatch "${FILESDIR}"/${PN}-1.17.1-flags.patch
50
51 # Force the use of the running bash for get-version (this file is never
52 # installed, so no need to worry about hardcoding a temporary bash)
53 sed -i -e '1c\#!'"${BASH}" get-version || die
54
55 # this test depends on a Debian only gzip extension that adds --rsyncable
56 # which will therefore always fail on Gentoo. (bug #310847).
57 sed -i scripts/Makefile.am \
58 -e '/850_Dpkg_Compression.t/d' \
59 || die "sed failed"
60
61 # test fails (bug #414095)
62 sed -i utils/Makefile.am \
63 -e '/^test_cases/d;/100_update_alternatives/d' || die
64
65 use nls && strip-linguas -i po
66
67 eautoreconf
68 }
69
70 src_configure() {
71 tc-export CC
72 econf \
73 $(use_enable dselect) \
74 $(use_enable nls) \
75 $(use_enable unicode) \
76 $(use_enable update-alternatives) \
77 $(use_with bzip2 bz2) \
78 $(use_with zlib) \
79 $(use_with lzma liblzma) \
80 --disable-compiler-warnings \
81 --disable-silent-rules \
82 --disable-start-stop-daemon \
83 --localstatedir="${EPREFIX}"/var \
84 --without-selinux
85 }
86
87 src_compile() {
88 emake AR=$(tc-getAR)
89 }
90
91 src_install() {
92 default
93
94 keepdir /usr/$(get_libdir)/db/methods/{mnt,floppy,disk}
95 keepdir /usr/$(get_libdir)/db/{alternatives,info,methods,parts,updates}
96 }

  ViewVC Help
Powered by ViewVC 1.1.20