/[gentoo-x86]/app-arch/innoextract/innoextract-1.4.ebuild
Gentoo

Contents of /app-arch/innoextract/innoextract-1.4.ebuild

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.1 - (hide annotations) (download)
Mon Mar 11 19:12:15 2013 UTC (7 years, 6 months ago) by hasufell
Branch: MAIN
version bump

(Portage version: 2.2.0_alpha166/cvs/Linux x86_64, signed Manifest commit with key E73C35B3)

1 hasufell 1.1 # Copyright 2013-2013 Gentoo Foundation
2     # Distributed under the terms of the GNU General Public License v2
3     # $Header: $
4    
5     EAPI=5
6    
7     inherit eutils toolchain-funcs cmake-utils
8    
9     DESCRIPTION="A tool to unpack installers created by Inno Setup"
10     HOMEPAGE="http://innoextract.constexpr.org/"
11     SRC_URI="mirror://github/dscharrer/InnoExtract/${P}.tar.gz
12     mirror://sourceforge/${PN}/${P}.tar.gz"
13    
14     LICENSE="ZLIB"
15     SLOT="0"
16     KEYWORDS="~amd64 ~x86"
17     IUSE="c++0x debug doc +lzma static"
18    
19     RDEPEND="
20     !static? (
21     dev-libs/boost
22     virtual/libiconv
23     lzma? ( app-arch/xz-utils )
24     )"
25     DEPEND="${RDEPEND}
26     doc? ( >=app-doc/doxygen-1.8.3.1 )
27     static? (
28     app-arch/bzip2[static-libs]
29     dev-libs/boost[static-libs]
30     sys-libs/zlib[static-libs]
31     virtual/libiconv
32     lzma? ( app-arch/xz-utils[static-libs] )
33     )"
34    
35     DOCS=( README.md CHANGELOG )
36    
37     pkg_pretend() {
38     if [[ ${MERGE_TYPE} != binary ]]; then
39     # not sure about minimum clang req
40     if use c++0x && [[ $(tc-getCXX) == *g++ && $(tc-getCXX) != *clang++ ]] ; then
41     if [[ $(gcc-major-version) == 4 && $(gcc-minor-version) -lt 7 || $(gcc-major-version) -lt 4 ]] ; then
42     eerror "You need at least sys-devel/gcc-4.7.0 for C++0x capabilities"
43     die "You need at least sys-devel/gcc-4.7.0 for C++0x capabilities"
44     fi
45     fi
46     fi
47     }
48    
49     src_prepare() {
50     epatch "${FILESDIR}"/${P}-cmake.patch
51     }
52    
53     src_configure() {
54     local mycmakeargs=(
55     $(cmake-utils_use_use lzma LZMA)
56     $(cmake-utils_use_use static STATIC_LIBS)
57     $(cmake-utils_use_use c++0x CXX11)
58     $(cmake-utils_use_with debug DEBUG)
59     -DSET_OPTIMIZATION_FLAGS=OFF
60     )
61    
62     cmake-utils_src_configure
63     }
64    
65     src_compile() {
66     cmake-utils_src_compile
67     use doc && cmake-utils_src_compile doc
68     }
69    
70     src_install() {
71     cmake-utils_src_install
72     use doc && dohtml -r "${CMAKE_BUILD_DIR}"/doc/html/*
73     }

  ViewVC Help
Powered by ViewVC 1.1.20