/[gentoo-x86]/app-arch/tar/tar-1.26-r1.ebuild
Gentoo

Contents of /app-arch/tar/tar-1.26-r1.ebuild

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.17 - (show annotations) (download)
Sat Jan 18 01:55:14 2014 UTC (15 months, 2 weeks ago) by vapier
Branch: MAIN
CVS Tags: HEAD
Changes since 1.16: +3 -3 lines
Add arm64 love.

(Portage version: 2.2.8/cvs/Linux x86_64, signed Manifest commit with key D2E96200)

1 # Copyright 1999-2014 Gentoo Foundation
2 # Distributed under the terms of the GNU General Public License v2
3 # $Header: /var/cvsroot/gentoo-x86/app-arch/tar/tar-1.26-r1.ebuild,v 1.16 2013/10/15 09:03:17 polynomial-c Exp $
4
5 EAPI="3"
6
7 inherit flag-o-matic eutils autotools
8
9 DESCRIPTION="Use this to make tarballs :)"
10 HOMEPAGE="http://www.gnu.org/software/tar/"
11 SRC_URI="mirror://gnu/tar/${P}.tar.bz2
12 mirror://gnu-alpha/tar/${P}.tar.bz2"
13
14 LICENSE="GPL-3+"
15 SLOT="0"
16 KEYWORDS="alpha amd64 arm arm64 hppa ia64 m68k ~mips ppc ppc64 s390 sh sparc x86 ~ppc-aix ~amd64-fbsd ~x86-fbsd ~x64-freebsd ~x86-freebsd ~hppa-hpux ~ia64-hpux ~x86-interix ~amd64-linux ~arm-linux ~ia64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~m68k-mint ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
17 IUSE="minimal nls static userland_GNU xattr"
18
19 RDEPEND="xattr? ( sys-apps/attr )"
20 DEPEND="${RDEPEND}
21 nls? ( >=sys-devel/gettext-0.10.35 )"
22
23 src_prepare() {
24 epatch "${FILESDIR}"/${P}-xattr.patch #382067
25 epatch "${FILESDIR}"/${P}-no-gets.patch
26 eautoreconf
27
28 if ! use userland_GNU ; then
29 sed -i \
30 -e 's:/backup\.sh:/gbackup.sh:' \
31 scripts/{backup,dump-remind,restore}.in \
32 || die "sed non-GNU"
33 fi
34 }
35
36 src_configure() {
37 use static && append-ldflags -static
38 FORCE_UNSAFE_CONFIGURE=1 \
39 econf \
40 --enable-backup-scripts \
41 --bindir="${EPREFIX}"/bin \
42 --libexecdir="${EPREFIX}"/usr/sbin \
43 $(usex userland_GNU "" "--program-prefix=g") \
44 $(use_enable nls) \
45 $(use_enable xattr)
46 }
47
48 src_install() {
49 emake DESTDIR="${D}" install || die
50
51 local p=$(usex userland_GNU "" "g")
52 if [[ -z ${p} ]] ; then
53 # a nasty yet required piece of baggage
54 exeinto /etc
55 doexe "${FILESDIR}"/rmt || die
56 fi
57
58 # autoconf looks for gtar before tar (in configure scripts), hence
59 # in Prefix it is important that it is there, otherwise, a gtar from
60 # the host system (FreeBSD, Solaris, Darwin) will be found instead
61 # of the Prefix provided (GNU) tar
62 if use prefix ; then
63 dosym tar /bin/gtar
64 fi
65
66 dodoc AUTHORS ChangeLog* NEWS README* THANKS
67 newman "${FILESDIR}"/tar.1 ${p}tar.1
68 mv "${ED}"/usr/sbin/${p}backup{,-tar}
69 mv "${ED}"/usr/sbin/${p}restore{,-tar}
70
71 if use minimal ; then
72 find "${ED}"/etc "${ED}"/*bin/ "${ED}"/usr/*bin/ \
73 -type f -a '!' '(' -name tar -o -name ${p}tar ')' \
74 -delete
75 fi
76 }

  ViewVC Help
Powered by ViewVC 1.1.20