/[gentoo-x86]/app-arch/zip/zip-3.0-r2.ebuild
Gentoo

Contents of /app-arch/zip/zip-3.0-r2.ebuild

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.2 - (show annotations) (download)
Sat Jan 18 01:45:41 2014 UTC (6 years, 5 months ago) by vapier
Branch: MAIN
CVS Tags: HEAD
Changes since 1.1: +2 -2 lines
Add arm64 love.

(Portage version: 2.2.8/cvs/Linux x86_64, signed Manifest commit with key D2E96200)

1 # Copyright 1999-2014 Gentoo Foundation
2 # Distributed under the terms of the GNU General Public License v2
3 # $Header: /var/cvsroot/gentoo-x86/app-arch/zip/zip-3.0-r2.ebuild,v 1.1 2014/01/05 18:26:15 vapier Exp $
4
5 EAPI="4"
6 inherit toolchain-funcs eutils flag-o-matic
7
8 MY_P="${PN}${PV//.}"
9 DESCRIPTION="Info ZIP (encryption support)"
10 HOMEPAGE="http://www.info-zip.org/"
11 SRC_URI="mirror://sourceforge/infozip/${MY_P}.zip"
12
13 LICENSE="Info-ZIP"
14 SLOT="0"
15 KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~arm-linux"
16 IUSE="bzip2 crypt natspec unicode"
17
18 RDEPEND="bzip2? ( app-arch/bzip2 )
19 natspec? ( dev-libs/libnatspec )"
20 DEPEND="${RDEPEND}
21 app-arch/unzip"
22
23 S=${WORKDIR}/${MY_P}
24
25 src_prepare() {
26 epatch "${FILESDIR}"/${PN}-3.0-no-crypt.patch #238398
27 epatch "${FILESDIR}"/${PN}-3.0-pic.patch
28 epatch "${FILESDIR}"/${PN}-3.0-exec-stack.patch
29 epatch "${FILESDIR}"/${PN}-3.0-build.patch
30 use natspec && epatch "${FILESDIR}"/${PN}-3.0-natspec.patch #275244
31 }
32
33 src_configure() {
34 append-cppflags \
35 -DLARGE_FILE_SUPPORT \
36 -DUIDGID_NOT_16BIT \
37 -D$(usex bzip2 '' NO)BZIP2_SUPPORT \
38 -D$(usex crypt '' NO)CRYPT \
39 -D$(usex unicode '' NO)UNICODE_SUPPORT
40 # Third arg disables bzip2 logic as we handle it ourselves above.
41 sh ./unix/configure "$(tc-getCC)" "-I. -DUNIX ${CFLAGS} ${CPPFLAGS}" "${T}" || die
42 if use bzip2 ; then
43 sed -i -e "s:LFLAGS2=:&'-lbz2 ':" flags || die
44 fi
45 }
46
47 src_compile() {
48 emake \
49 CPP="$(tc-getCPP)" \
50 -f unix/Makefile generic
51 }
52
53 src_install() {
54 dobin zip zipnote zipsplit
55 doman man/zip{,note,split}.1
56 if use crypt ; then
57 dobin zipcloak
58 doman man/zipcloak.1
59 fi
60 dodoc BUGS CHANGES README* TODO WHATSNEW WHERE proginfo/*.txt
61 }

  ViewVC Help
Powered by ViewVC 1.1.20