/[gentoo-x86]/app-emacs/vm/vm-8.2.0_beta.ebuild
Gentoo

Contents of /app-emacs/vm/vm-8.2.0_beta.ebuild

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.3 - (show annotations) (download)
Thu Apr 4 21:17:46 2013 UTC (5 years, 2 months ago) by ulm
Branch: MAIN
CVS Tags: HEAD
Changes since 1.2: +7 -4 lines
Fix build failure with texinfo-5.1, bug 464312. Specify LICENSE more precisely. Remove old.

(Portage version: 2.1.11.60/cvs/Linux x86_64, signed Manifest commit with key 9433907D693FB5B8!)

1 # Copyright 1999-2013 Gentoo Foundation
2 # Distributed under the terms of the GNU General Public License v2
3 # $Header: /var/cvsroot/gentoo-x86/app-emacs/vm/vm-8.2.0_beta.ebuild,v 1.2 2012/07/29 17:14:56 armin76 Exp $
4
5 EAPI=4
6
7 inherit elisp eutils
8
9 MY_PV="${PV/_beta/b}"
10 MY_P="${PN}-${MY_PV}"
11 DESCRIPTION="The VM mail reader for Emacs"
12 HOMEPAGE="http://www.nongnu.org/viewmail/"
13 SRC_URI="http://launchpad.net/vm/${PV%.*}.x/${MY_PV}/+download/${MY_P}.tgz"
14
15 LICENSE="GPL-2+"
16 SLOT="0"
17 KEYWORDS="~amd64 ~ppc ~x86"
18 IUSE="bbdb ssl"
19
20 DEPEND="bbdb? ( app-emacs/bbdb )"
21 RDEPEND="!app-emacs/u-vm-color
22 ${DEPEND}
23 ssl? ( net-misc/stunnel )"
24 DEPEND="${DEPEND}
25 sys-apps/texinfo"
26
27 S="${WORKDIR}/${MY_P}"
28 SITEFILE="50${PN}-gentoo.el"
29
30 src_prepare() {
31 epatch "${FILESDIR}/${P}-datadir.patch"
32 epatch "${FILESDIR}/${P}-texinfo-5.patch"
33
34 if ! use bbdb; then
35 elog "Excluding vm-pcrisis.el since the \"bbdb\" USE flag is not set."
36 epatch "${FILESDIR}/${PN}-8.0-no-pcrisis.patch"
37 fi
38 }
39
40 src_configure() {
41 econf \
42 --with-emacs="emacs" \
43 --with-lispdir="${SITELISP}/${PN}" \
44 --with-etcdir="${SITEETC}/${PN}" \
45 --with-docdir="/usr/share/doc/${PF}" \
46 $(use bbdb && echo "--with-other-dirs=${SITELISP}/bbdb")
47 }
48
49 src_compile() {
50 emake -j1
51 }
52
53 src_install() {
54 emake -j1 DESTDIR="${D}" install
55 elisp-site-file-install "${FILESDIR}/${SITEFILE}"
56
57 # delete duplicate documentation
58 find "${D}/${SITEETC}/${PN}" -type d -name pixmaps -prune \
59 -o -type f -exec rm '{}' '+' || die
60 rm "${D}/usr/share/doc/${PF}/COPYING" || die
61
62 dodoc example.vm
63 # NEWS is accessed from lisp and must not be compressed
64 docompress -x /usr/share/doc/${PF}/NEWS
65 }

  ViewVC Help
Powered by ViewVC 1.1.20