/[gentoo-x86]/app-emulation/wine/wine-1.5.7.ebuild
Gentoo

Contents of /app-emulation/wine/wine-1.5.7.ebuild

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.10 - (show annotations) (download)
Mon Aug 5 09:31:06 2013 UTC (5 years, 4 months ago) by ssuominen
Branch: MAIN
Changes since 1.9: +2 -2 lines
Update the libjpeg dependency to use correct SLOT.

(Portage version: 2.2.0_alpha191/cvs/Linux x86_64, signed Manifest commit with key 4868F14D)

1 # Copyright 1999-2013 Gentoo Foundation
2 # Distributed under the terms of the GNU General Public License v2
3 # $Header: /var/cvsroot/gentoo-x86/app-emulation/wine/wine-1.5.7.ebuild,v 1.9 2013/03/13 17:52:48 ssuominen Exp $
4
5 EAPI="5"
6
7 inherit autotools eutils flag-o-matic multilib pax-utils
8
9 if [[ ${PV} == "9999" ]] ; then
10 EGIT_REPO_URI="git://source.winehq.org/git/wine.git"
11 inherit git-2
12 SRC_URI=""
13 #KEYWORDS=""
14 else
15 MY_P="${PN}-${PV/_/-}"
16 SRC_URI="mirror://sourceforge/${PN}/Source/${MY_P}.tar.bz2"
17 KEYWORDS="-* ~amd64 ~x86 ~x86-fbsd"
18 S=${WORKDIR}/${MY_P}
19 fi
20
21 GV="1.6"
22 MV="0.0.4"
23 PULSE_PATCH="winepulse-2012.06.15.patch"
24 DESCRIPTION="Free implementation of Windows(tm) on Unix"
25 HOMEPAGE="http://www.winehq.org/"
26 SRC_URI="${SRC_URI}
27 gecko? (
28 mirror://sourceforge/${PN}/Wine%20Gecko/${GV}/wine_gecko-${GV}-x86.msi
29 win64? ( mirror://sourceforge/${PN}/Wine%20Gecko/${GV}/wine_gecko-${GV}-x86_64.msi )
30 )
31 mono? ( mirror://sourceforge/${PN}/Wine%20Mono/${MV}/wine-mono-${MV}.msi )
32 http://source.winehq.org/patches/data/87234 -> ${PULSE_PATCH}"
33
34 LICENSE="LGPL-2.1"
35 SLOT="0"
36 IUSE="alsa capi cups custom-cflags elibc_glibc fontconfig +gecko gnutls gphoto2 gsm gstreamer jpeg lcms ldap +mono mp3 ncurses nls odbc openal opencl +opengl +oss +perl png +prelink pulseaudio samba scanner selinux ssl test +threads +truetype udisks v4l +win32 +win64 +X xcomposite xinerama xml"
37 REQUIRED_USE="elibc_glibc? ( threads )
38 mono? ( || ( win32 !win64 ) )" #286560
39 RESTRICT="test" #72375
40
41 MLIB_DEPS="amd64? (
42 gstreamer? ( app-emulation/emul-linux-x86-gstplugins )
43 truetype? ( >=app-emulation/emul-linux-x86-xlibs-2.1 )
44 X? (
45 >=app-emulation/emul-linux-x86-xlibs-2.1
46 >=app-emulation/emul-linux-x86-soundlibs-2.1
47 )
48 mp3? ( app-emulation/emul-linux-x86-soundlibs )
49 odbc? ( app-emulation/emul-linux-x86-db )
50 openal? ( app-emulation/emul-linux-x86-sdl )
51 opengl? ( app-emulation/emul-linux-x86-opengl )
52 scanner? ( app-emulation/emul-linux-x86-medialibs )
53 v4l? ( app-emulation/emul-linux-x86-medialibs )
54 app-emulation/emul-linux-x86-baselibs
55 >=sys-kernel/linux-headers-2.6
56 )"
57 RDEPEND="truetype? ( >=media-libs/freetype-2.0.0 media-fonts/corefonts )
58 perl? ( dev-lang/perl dev-perl/XML-Simple )
59 capi? ( net-dialup/capi4k-utils )
60 ncurses? ( >=sys-libs/ncurses-5.2:= )
61 fontconfig? ( media-libs/fontconfig:= )
62 gphoto2? ( media-libs/libgphoto2:= )
63 openal? ( media-libs/openal:= )
64 udisks? (
65 sys-apps/dbus
66 sys-fs/udisks:2
67 )
68 gnutls? ( net-libs/gnutls:= )
69 gstreamer? ( media-libs/gstreamer:0.10 media-libs/gst-plugins-base:0.10 )
70 X? (
71 x11-libs/libXcursor
72 x11-libs/libXrandr
73 x11-libs/libXi
74 x11-libs/libXmu
75 x11-libs/libXxf86vm
76 )
77 xinerama? ( x11-libs/libXinerama )
78 alsa? ( media-libs/alsa-lib )
79 cups? ( net-print/cups:= )
80 opencl? ( virtual/opencl )
81 opengl? (
82 virtual/glu
83 virtual/opengl
84 )
85 gsm? ( media-sound/gsm:= )
86 jpeg? ( virtual/jpeg:0= )
87 ldap? ( net-nds/openldap:= )
88 lcms? ( media-libs/lcms:0= )
89 mp3? ( >=media-sound/mpg123-1.5.0 )
90 nls? ( sys-devel/gettext )
91 odbc? ( dev-db/unixODBC:= )
92 pulseaudio? ( media-sound/pulseaudio )
93 samba? ( >=net-fs/samba-3.0.25 )
94 selinux? ( sec-policy/selinux-wine )
95 xml? ( dev-libs/libxml2 dev-libs/libxslt )
96 scanner? ( media-gfx/sane-backends:= )
97 ssl? ( dev-libs/openssl:0= )
98 png? ( media-libs/libpng:0= )
99 v4l? ( media-libs/libv4l )
100 !win64? ( ${MLIB_DEPS} )
101 win32? ( ${MLIB_DEPS} )
102 xcomposite? ( x11-libs/libXcomposite )"
103 DEPEND="${RDEPEND}
104 X? (
105 x11-proto/inputproto
106 x11-proto/xextproto
107 x11-proto/xf86vidmodeproto
108 )
109 xinerama? ( x11-proto/xineramaproto )
110 prelink? ( sys-devel/prelink )
111 virtual/pkgconfig
112 virtual/yacc
113 sys-devel/flex"
114
115 src_unpack() {
116 if use win64 ; then
117 [[ $(( $(gcc-major-version) * 100 + $(gcc-minor-version) )) -lt 404 ]] \
118 && die "you need gcc-4.4+ to build 64bit wine"
119 fi
120
121 if use win32 && use opencl; then
122 [[ x$(eselect opencl show) = "xintel" ]] &&
123 die "Cannot build wine[opencl,win32]: intel-ocl-sdk is 64-bit only" # 403947
124 fi
125
126 if [[ ${PV} == "9999" ]] ; then
127 git-2_src_unpack
128 else
129 unpack ${MY_P}.tar.bz2
130 fi
131 }
132
133 src_prepare() {
134 local md5="$(md5sum server/protocol.def)"
135 epatch "${FILESDIR}"/${PN}-1.1.15-winegcc.patch #260726
136 epatch "${FILESDIR}"/${PN}-1.4_rc2-multilib-portage.patch #395615
137 epatch "${DISTDIR}/${PULSE_PATCH}" #421365
138 epatch_user #282735
139 if [[ "$(md5sum server/protocol.def)" != "${md5}" ]]; then
140 einfo "server/protocol.def was patched; running tools/make_requests"
141 tools/make_requests || die #432348
142 fi
143 eautoreconf
144 sed -i '/^UPDATE_DESKTOP_DATABASE/s:=.*:=true:' tools/Makefile.in || die
145 sed -i '/^MimeType/d' tools/wine.desktop || die #117785
146 }
147
148 do_configure() {
149 local builddir="${WORKDIR}/wine$1"
150 mkdir -p "${builddir}"
151 pushd "${builddir}" >/dev/null
152
153 ECONF_SOURCE=${S} \
154 econf \
155 --sysconfdir=/etc/wine \
156 $(use_with alsa) \
157 $(use_with capi) \
158 $(use_with lcms cms) \
159 $(use_with cups) \
160 $(use_with ncurses curses) \
161 $(use_with udisks dbus) \
162 $(use_with fontconfig) \
163 $(use_with gnutls) \
164 $(use_with gphoto2 gphoto) \
165 $(use_with gsm) \
166 $(use_with gstreamer) \
167 --without-hal \
168 $(use_with jpeg) \
169 $(use_with ldap) \
170 $(use_with mp3 mpg123) \
171 $(use_with nls gettext) \
172 $(use_with openal) \
173 $(use_with opencl) \
174 $(use_with opengl) \
175 $(use_with ssl openssl) \
176 $(use_with oss) \
177 $(use_with png) \
178 $(use_with threads pthread) \
179 $(use_with pulseaudio pulse) \
180 $(use_with scanner sane) \
181 $(use_enable test tests) \
182 $(use_with truetype freetype) \
183 $(use_with v4l) \
184 $(use_with X x) \
185 $(use_with xcomposite) \
186 $(use_with xinerama) \
187 $(use_with xml) \
188 $(use_with xml xslt) \
189 $2
190
191 emake -j1 depend
192
193 popd >/dev/null
194 }
195
196 src_configure() {
197 export LDCONFIG=/bin/true
198 use custom-cflags || strip-flags
199
200 if use win64 ; then
201 do_configure 64 --enable-win64
202 use win32 && ABI=x86 do_configure 32 --with-wine64=../wine64
203 else
204 ABI=x86 do_configure 32 --disable-win64
205 fi
206 }
207
208 src_compile() {
209 local b
210 for b in 64 32 ; do
211 local builddir="${WORKDIR}/wine${b}"
212 [[ -d ${builddir} ]] || continue
213 emake -C "${builddir}" all
214 done
215 }
216
217 src_install() {
218 local b
219 for b in 64 32 ; do
220 local builddir="${WORKDIR}/wine${b}"
221 [[ -d ${builddir} ]] || continue
222 emake -C "${builddir}" install DESTDIR="${D}"
223 done
224 dodoc ANNOUNCE AUTHORS README
225 if use gecko ; then
226 insinto /usr/share/wine/gecko
227 doins "${DISTDIR}"/wine_gecko-${GV}-x86.msi
228 use win64 && doins "${DISTDIR}"/wine_gecko-${GV}-x86_64.msi
229 fi
230 if use mono ; then
231 insinto /usr/share/wine/mono
232 doins "${DISTDIR}"/wine-mono-${MV}.msi
233 fi
234 if ! use perl ; then
235 rm "${D}"usr/bin/{wine{dump,maker},function_grep.pl} "${D}"usr/share/man/man1/wine{dump,maker}.1 || die
236 fi
237
238 if use win32 || ! use win64; then
239 pax-mark psmr "${D}"usr/bin/wine{,-preloader} #255055
240 fi
241 use win64 && pax-mark psmr "${D}"usr/bin/wine64{,-preloader}
242
243 if use win64 && ! use win32; then
244 dosym /usr/bin/wine{64,} # 404331
245 dosym /usr/bin/wine{64,}-preloader
246 fi
247 }

  ViewVC Help
Powered by ViewVC 1.1.20