/[gentoo-x86]/app-emulation/wine/wine-1.7.21-r1.ebuild
Gentoo

Contents of /app-emulation/wine/wine-1.7.21-r1.ebuild

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.1 - (show annotations) (download)
Sat Jul 11 07:54:37 2015 UTC (3 years, 9 months ago) by np-hardass
Branch: MAIN
CVS Tags: HEAD
Fixes bugs #548100, #539830, #543446, update to new multilib dependency code, and unify ebuild code/build system

(Portage version: 2.2.20/cvs/Linux x86_64, signed Manifest commit with key 18F89C67)

1 # Copyright 1999-2015 Gentoo Foundation
2 # Distributed under the terms of the GNU General Public License v2
3 # $Header: $
4
5 EAPI="5"
6
7 AUTOTOOLS_AUTORECONF=1
8 PLOCALES="ar bg ca cs da de el en en_US eo es fa fi fr he hi hr hu it ja ko lt ml nb_NO nl or pa pl pt_BR pt_PT rm ro ru sk sl sr_RS@cyrillic sr_RS@latin sv te th tr uk wa zh_CN zh_TW"
9 PLOCALE_BACKUP="en"
10
11 inherit autotools-utils eutils fdo-mime flag-o-matic gnome2-utils l10n multilib multilib-minimal pax-utils toolchain-funcs virtualx
12
13 if [[ ${PV} == "9999" ]] ; then
14 EGIT_REPO_URI="git://source.winehq.org/git/wine.git http://source.winehq.org/git/wine.git"
15 EGIT_BRANCH="master"
16 inherit git-r3
17 SRC_URI=""
18 #KEYWORDS=""
19 else
20 MY_P="${PN}-${PV/_/-}"
21 SRC_URI="mirror://sourceforge/${PN}/Source/${MY_P}.tar.bz2"
22 KEYWORDS="-* ~amd64 ~x86 ~x86-fbsd"
23 S=${WORKDIR}/${MY_P}
24 fi
25
26 GV="2.24"
27 MV="4.5.2"
28 STAGING_P="wine-staging-${PV}"
29 STAGING_DIR="${WORKDIR}/${STAGING_P}"
30 WINE_GENTOO="wine-gentoo-2015.03.07"
31 PULSE_PATCHES="winepulse-patches-1.7.21"
32 DESCRIPTION="Free implementation of Windows(tm) on Unix"
33 HOMEPAGE="http://www.winehq.org/"
34 SRC_URI="${SRC_URI}
35 gecko? (
36 abi_x86_32? ( mirror://sourceforge/${PN}/Wine%20Gecko/${GV}/wine_gecko-${GV}-x86.msi )
37 abi_x86_64? ( mirror://sourceforge/${PN}/Wine%20Gecko/${GV}/wine_gecko-${GV}-x86_64.msi )
38 )
39 mono? ( mirror://sourceforge/${PN}/Wine%20Mono/${MV}/wine-mono-${MV}.msi )
40 pulseaudio? ( http://dev.gentoo.org/~tetromino/distfiles/${PN}/${PULSE_PATCHES}.tar.bz2 )
41 http://dev.gentoo.org/~tetromino/distfiles/${PN}/${WINE_GENTOO}.tar.bz2"
42
43 if [[ ${PV} == "9999" ]] ; then
44 STAGING_EGIT_REPO_URI="git://github.com/wine-compholio/wine-staging.git"
45 else
46 SRC_URI="${SRC_URI}
47 staging? ( https://github.com/wine-compholio/wine-staging/archive/v${PV}.tar.gz -> ${STAGING_P}.tar.gz )"
48 fi
49
50 LICENSE="LGPL-2.1"
51 SLOT="0"
52 IUSE="+abi_x86_32 +abi_x86_64 +alsa capi cups custom-cflags dos elibc_glibc +fontconfig +gecko gphoto2 gsm gstreamer +jpeg +lcms ldap +mono mp3 ncurses netapi nls odbc openal opencl +opengl osmesa oss +perl pipelight +png +prelink pulseaudio +realtime +run-exes samba scanner selinux +ssl staging test +threads +truetype +udisks v4l +X +xcomposite xinerama +xml"
53 REQUIRED_USE="|| ( abi_x86_32 abi_x86_64 )
54 test? ( abi_x86_32 )
55 elibc_glibc? ( threads )
56 gstreamer? ( pulseaudio )
57 mono? ( abi_x86_32 )
58 pipelight? ( staging )
59 osmesa? ( opengl )" #286560
60 # winepulse patches needed for gstreamer due to http://bugs.winehq.org/show_bug.cgi?id=30557
61
62 # FIXME: the test suite is unsuitable for us; many tests require net access
63 # or fail due to Xvfb's opengl limitations.
64 RESTRICT="test"
65
66 COMMON_DEPEND="
67 truetype? ( >=media-libs/freetype-2.0.0[${MULTILIB_USEDEP}] )
68 capi? ( net-dialup/capi4k-utils )
69 ncurses? ( >=sys-libs/ncurses-5.2:=[${MULTILIB_USEDEP}] )
70 udisks? ( sys-apps/dbus[${MULTILIB_USEDEP}] )
71 fontconfig? ( media-libs/fontconfig:=[${MULTILIB_USEDEP}] )
72 gphoto2? ( media-libs/libgphoto2:=[${MULTILIB_USEDEP}] )
73 openal? ( media-libs/openal:=[${MULTILIB_USEDEP}] )
74 gstreamer? (
75 media-libs/gstreamer:0.10[${MULTILIB_USEDEP}]
76 media-libs/gst-plugins-base:0.10[${MULTILIB_USEDEP}]
77 )
78 X? (
79 x11-libs/libXcursor[${MULTILIB_USEDEP}]
80 x11-libs/libXext[${MULTILIB_USEDEP}]
81 x11-libs/libXrandr[${MULTILIB_USEDEP}]
82 x11-libs/libXi[${MULTILIB_USEDEP}]
83 x11-libs/libXxf86vm[${MULTILIB_USEDEP}]
84 )
85 xinerama? ( x11-libs/libXinerama[${MULTILIB_USEDEP}] )
86 alsa? ( media-libs/alsa-lib[${MULTILIB_USEDEP}] )
87 cups? ( net-print/cups:=[${MULTILIB_USEDEP}] )
88 opencl? ( virtual/opencl[${MULTILIB_USEDEP}] )
89 opengl? (
90 virtual/glu[${MULTILIB_USEDEP}]
91 virtual/opengl[${MULTILIB_USEDEP}]
92 )
93 gsm? ( media-sound/gsm:=[${MULTILIB_USEDEP}] )
94 jpeg? ( virtual/jpeg:0=[${MULTILIB_USEDEP}] )
95 ldap? ( net-nds/openldap:=[${MULTILIB_USEDEP}] )
96 lcms? ( media-libs/lcms:2=[${MULTILIB_USEDEP}] )
97 mp3? ( >=media-sound/mpg123-1.5.0[${MULTILIB_USEDEP}] )
98 netapi? ( net-fs/samba[netapi(+),${MULTILIB_USEDEP}] )
99 nls? ( sys-devel/gettext[${MULTILIB_USEDEP}] )
100 odbc? ( dev-db/unixODBC:=[${MULTILIB_USEDEP}] )
101 osmesa? ( media-libs/mesa[osmesa,${MULTILIB_USEDEP}] )
102 pulseaudio? ( media-sound/pulseaudio[${MULTILIB_USEDEP}] )
103 staging? ( sys-apps/attr[${MULTILIB_USEDEP}] )
104 xml? (
105 dev-libs/libxml2[${MULTILIB_USEDEP}]
106 dev-libs/libxslt[${MULTILIB_USEDEP}]
107 )
108 scanner? ( media-gfx/sane-backends:=[${MULTILIB_USEDEP}] )
109 ssl? ( net-libs/gnutls:=[${MULTILIB_USEDEP}] )
110 png? ( media-libs/libpng:0=[${MULTILIB_USEDEP}] )
111 v4l? ( media-libs/libv4l[${MULTILIB_USEDEP}] )
112 xcomposite? ( x11-libs/libXcomposite[${MULTILIB_USEDEP}] )
113 abi_x86_32? (
114 !app-emulation/emul-linux-x86-baselibs[-abi_x86_32(-)]
115 !<app-emulation/emul-linux-x86-baselibs-20140508-r14
116 !app-emulation/emul-linux-x86-db[-abi_x86_32(-)]
117 !<app-emulation/emul-linux-x86-db-20140508-r3
118 !app-emulation/emul-linux-x86-medialibs[-abi_x86_32(-)]
119 !<app-emulation/emul-linux-x86-medialibs-20140508-r6
120 !app-emulation/emul-linux-x86-opengl[-abi_x86_32(-)]
121 !<app-emulation/emul-linux-x86-opengl-20140508-r1
122 !app-emulation/emul-linux-x86-sdl[-abi_x86_32(-)]
123 !<app-emulation/emul-linux-x86-sdl-20140508-r1
124 !app-emulation/emul-linux-x86-soundlibs[-abi_x86_32(-)]
125 !<app-emulation/emul-linux-x86-soundlibs-20140508
126 !app-emulation/emul-linux-x86-xlibs[-abi_x86_32(-)]
127 !<app-emulation/emul-linux-x86-xlibs-20140508
128 )"
129
130 RDEPEND="${COMMON_DEPEND}
131 dos? ( games-emulation/dosbox )
132 perl? ( dev-lang/perl dev-perl/XML-Simple )
133 samba? ( >=net-fs/samba-3.0.25 )
134 selinux? ( sec-policy/selinux-wine )
135 udisks? ( sys-fs/udisks:2 )
136 pulseaudio? ( realtime? ( sys-auth/rtkit ) )"
137
138 # tools/make_requests requires perl
139 DEPEND="${COMMON_DEPEND}
140 staging? ( dev-lang/perl dev-perl/XML-Simple )
141 X? (
142 x11-proto/inputproto
143 x11-proto/xextproto
144 x11-proto/xf86vidmodeproto
145 )
146 xinerama? ( x11-proto/xineramaproto )
147 prelink? ( sys-devel/prelink )
148 >=sys-kernel/linux-headers-2.6
149 virtual/pkgconfig
150 virtual/yacc
151 sys-devel/flex"
152
153 # These use a non-standard "Wine" category, which is provided by
154 # /etc/xdg/applications-merged/wine.menu
155 QA_DESKTOP_FILE="usr/share/applications/wine-browsedrive.desktop
156 usr/share/applications/wine-notepad.desktop
157 usr/share/applications/wine-uninstaller.desktop
158 usr/share/applications/wine-winecfg.desktop"
159
160 wine_build_environment_check() {
161 [[ ${MERGE_TYPE} = "binary" ]] && return 0
162
163 # bug #549768
164 if [[ $(gcc-major-version) = 5 ]]; then
165 eerror "You need gcc-4.x to build wine; see https://bugs.gentoo.org/549768"
166 eerror
167 return 1
168 fi
169
170 if use abi_x86_64 && [[ $(( $(gcc-major-version) * 100 + $(gcc-minor-version) )) -lt 404 ]]; then
171 eerror "You need gcc-4.4+ to build 64-bit wine"
172 eerror
173 return 1
174 fi
175
176 if use abi_x86_32 && use opencl && [[ x$(eselect opencl show 2> /dev/null) = "xintel" ]]; then
177 eerror "You cannot build wine with USE=opencl because intel-ocl-sdk is 64-bit only."
178 eerror "See https://bugs.gentoo.org/487864 for more details."
179 eerror
180 return 1
181 fi
182 }
183
184 pkg_pretend() {
185 wine_build_environment_check || die
186 }
187
188 pkg_setup() {
189 wine_build_environment_check || die
190 }
191
192 src_unpack() {
193 if [[ ${PV} == "9999" ]] ; then
194 git-r3_src_unpack
195 if use staging; then
196 EGIT_REPO_URI=${STAGING_EGIT_REPO_URI}
197 unset ${PN}_LIVE_REPO;
198 EGIT_CHECKOUT_DIR=${STAGING_DIR} git-r3_src_unpack
199 fi
200 else
201 unpack ${MY_P}.tar.bz2
202 use staging && unpack "${STAGING_P}.tar.gz"
203 fi
204
205 use pulseaudio && unpack "${PULSE_PATCHES}.tar.bz2"
206 if use staging; then
207 # we use a separate pulseaudio patchset
208 rm -r "${STAGING_DIR}/patches/06-winepulse" || die
209 # ... and need special tools for binary patches
210 mv "${STAGING_DIR}/patches/10-Missing_Fonts" "${T}" || die
211 if ! use pipelight; then
212 rm -r "${STAGING_DIR}/patches/97-Pipelight" || die
213 fi
214 fi
215 unpack "${WINE_GENTOO}.tar.bz2"
216
217 l10n_find_plocales_changes "${S}/po" "" ".po"
218 }
219
220 src_prepare() {
221 local md5="$(md5sum server/protocol.def)"
222 local f
223 local PATCHES=(
224 "${FILESDIR}"/${PN}-1.5.26-winegcc.patch #260726
225 "${FILESDIR}"/${PN}-1.4_rc2-multilib-portage.patch #395615
226 "${FILESDIR}"/${PN}-1.7.12-osmesa-check.patch #429386
227 "${FILESDIR}"/${PN}-1.6-memset-O3.patch #480508
228 )
229 use pulseaudio && PATCHES+=(
230 "../${PULSE_PATCHES}"/*.patch #421365
231 )
232 if use gstreamer; then
233 # See http://bugs.winehq.org/show_bug.cgi?id=30557
234 ewarn "Applying experimental patch to fix GStreamer support. Note that"
235 ewarn "this patch has been reported to cause crashes in certain games."
236
237 PATCHES+=( "../${PULSE_PATCHES}"/gstreamer/*.patch )
238 fi
239 if use staging; then
240 ewarn "Applying the unofficial Wine-Staging patchset which is unsupported"
241 ewarn "by Wine developers. Please don't report bugs to Wine bugzilla"
242 ewarn "unless you can reproduce them with USE=-staging"
243
244 PATCHES+=(
245 "${FILESDIR}/wine-1.7.19-makefile-race-cond.patch"
246 "${STAGING_DIR}/patches"/*/*.patch #507950
247 "${STAGING_DIR}/patches/patch-list.patch"
248 )
249 # epatch doesn't support binary patches
250 ebegin "Applying Staging font patches"
251 for f in "${T}/10-Missing_Fonts"/*.patch; do
252 "${STAGING_DIR}/debian/tools/gitapply.sh" < "${f}" || die "Failed to apply Compholio font patches"
253 done
254 eend
255 fi
256 autotools-utils_src_prepare
257
258 # Modification of the server protocol requires regenerating the server requests
259 if [[ "$(md5sum server/protocol.def)" != "${md5}" ]]; then
260 einfo "server/protocol.def was patched; running tools/make_requests"
261 tools/make_requests || die #432348
262 fi
263 sed -i '/^UPDATE_DESKTOP_DATABASE/s:=.*:=true:' tools/Makefile.in || die
264 if ! use run-exes; then
265 sed -i '/^MimeType/d' tools/wine.desktop || die #117785
266 fi
267
268 # hi-res default icon, #472990, http://bugs.winehq.org/show_bug.cgi?id=24652
269 cp "${WORKDIR}"/${WINE_GENTOO}/icons/oic_winlogo.ico dlls/user32/resources/ || die
270
271 l10n_get_locales > po/LINGUAS # otherwise wine doesn't respect LINGUAS
272 }
273
274 src_configure() {
275 export LDCONFIG=/bin/true
276 use custom-cflags || strip-flags
277
278 multilib-minimal_src_configure
279 }
280
281 multilib_src_configure() {
282 local myconf=(
283 --sysconfdir=/etc/wine
284 $(use_with alsa)
285 $(use_with capi)
286 $(use_with lcms cms)
287 $(use_with cups)
288 $(use_with ncurses curses)
289 $(use_with udisks dbus)
290 $(use_with fontconfig)
291 $(use_with ssl gnutls)
292 $(use_enable gecko mshtml)
293 $(use_with gphoto2 gphoto)
294 $(use_with gsm)
295 $(use_with gstreamer)
296 --without-hal
297 $(use_with jpeg)
298 $(use_with ldap)
299 $(use_enable mono mscoree)
300 $(use_with mp3 mpg123)
301 $(use_with netapi)
302 $(use_with nls gettext)
303 $(use_with openal)
304 $(use_with opencl)
305 $(use_with opengl)
306 $(use_with osmesa)
307 $(use_with oss)
308 $(use_with png)
309 $(use_with threads pthread)
310 $(use_with scanner sane)
311 $(use_enable test tests)
312 $(use_with truetype freetype)
313 $(use_with v4l)
314 $(use_with X x)
315 $(use_with xcomposite)
316 $(use_with xinerama)
317 $(use_with xml)
318 $(use_with xml xslt)
319 )
320
321 use pulseaudio && myconf+=( --with-pulse )
322 use staging && myconf+=( --with-xattr )
323
324 local PKG_CONFIG AR RANLIB
325 # Avoid crossdev's i686-pc-linux-gnu-pkg-config if building wine32 on amd64; #472038
326 # set AR and RANLIB to make QA scripts happy; #483342
327 tc-export PKG_CONFIG AR RANLIB
328
329 if use amd64; then
330 if [[ ${ABI} == amd64 ]]; then
331 myconf+=( --enable-win64 )
332 else
333 myconf+=( --disable-win64 )
334 fi
335
336 # Note: using --with-wine64 results in problems with multilib.eclass
337 # CC/LD hackery. We're using separate tools instead.
338 fi
339
340 ECONF_SOURCE=${S} \
341 econf "${myconf[@]}"
342 emake depend
343 }
344
345 multilib_src_test() {
346 # FIXME: win32-only; wine64 tests fail with "could not find the Wine loader"
347 if [[ ${ABI} == x86 ]]; then
348 if [[ $(id -u) == 0 ]]; then
349 ewarn "Skipping tests since they cannot be run under the root user."
350 ewarn "To run the test ${PN} suite, add userpriv to FEATURES in make.conf"
351 return
352 fi
353
354 WINEPREFIX="${T}/.wine-${ABI}" \
355 Xemake test
356 fi
357 }
358
359 multilib_src_install_all() {
360 local DOCS=( ANNOUNCE AUTHORS README )
361 local l
362 add_locale_docs() {
363 local locale_doc="documentation/README.$1"
364 [[ ! -e ${locale_doc} ]] || DOCS+=( ${locale_doc} )
365 }
366 l10n_for_each_locale_do add_locale_docs
367
368 einstalldocs
369 prune_libtool_files --all
370
371 emake -C "../${WINE_GENTOO}" install DESTDIR="${D}" EPREFIX="${EPREFIX}"
372 if use gecko ; then
373 insinto /usr/share/wine/gecko
374 use abi_x86_32 && doins "${DISTDIR}"/wine_gecko-${GV}-x86.msi
375 use abi_x86_64 && doins "${DISTDIR}"/wine_gecko-${GV}-x86_64.msi
376 fi
377 if use mono ; then
378 insinto /usr/share/wine/mono
379 doins "${DISTDIR}"/wine-mono-${MV}.msi
380 fi
381 if ! use perl ; then # winedump calls function_grep.pl, and winemaker is a perl script
382 rm "${D}"usr/bin/{wine{dump,maker},function_grep.pl} "${D}"usr/share/man/man1/wine{dump,maker}.1 || die
383 fi
384
385 use abi_x86_32 && pax-mark psmr "${D}"usr/bin/wine{,-preloader} #255055
386 use abi_x86_64 && pax-mark psmr "${D}"usr/bin/wine64{,-preloader}
387
388 if use abi_x86_64 && ! use abi_x86_32; then
389 dosym /usr/bin/wine{64,} # 404331
390 dosym /usr/bin/wine{64,}-preloader
391 fi
392
393 # respect LINGUAS when installing man pages, #469418
394 for l in de fr pl; do
395 use linguas_${l} || rm -r "${D}"usr/share/man/${l}*
396 done
397 }
398
399 pkg_preinst() {
400 gnome2_icon_savelist
401 }
402
403 pkg_postinst() {
404 gnome2_icon_cache_update
405 fdo-mime_desktop_database_update
406
407 if ! use gecko; then
408 ewarn "Without Wine Gecko, wine prefixes will not have a default"
409 ewarn "implementation of iexplore. Many older windows applications"
410 ewarn "rely upon the existence of an iexplore implementation, so"
411 ewarn "you will likely need to install an external one, like via winetricks"
412 fi
413 if ! use mono; then
414 ewarn "Without Wine Mono, wine prefixes will not have a default"
415 ewarn "implementation of .NET. Many windows applications rely upon"
416 ewarn "the existence of a .NET implementation, so you will likely need"
417 ewarn "to install an external one, like via winetricks"
418 fi
419 }
420
421 pkg_postrm() {
422 gnome2_icon_cache_update
423 fdo-mime_desktop_database_update
424 }

  ViewVC Help
Powered by ViewVC 1.1.20