/[gentoo-x86]/app-misc/geoclue/geoclue-0.12.99.ebuild
Gentoo

Contents of /app-misc/geoclue/geoclue-0.12.99.ebuild

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.14 - (show annotations) (download)
Sun May 25 14:17:55 2014 UTC (5 years, 8 months ago) by pacho
Branch: MAIN
CVS Tags: HEAD
Changes since 1.13: +1 -2 lines
gtk-doc is not needed (#444564 by Laszlo Szalma)

(Portage version: 2.2.10/cvs/Linux x86_64, signed Manifest commit with key A188FBD4)

1 # Copyright 1999-2014 Gentoo Foundation
2 # Distributed under the terms of the GNU General Public License v2
3 # $Header: /var/cvsroot/gentoo-x86/app-misc/geoclue/geoclue-0.12.99.ebuild,v 1.13 2014/01/14 12:12:43 blueness Exp $
4
5 EAPI=4
6 inherit autotools eutils
7
8 DESCRIPTION="A geoinformation D-Bus service"
9 HOMEPAGE="http://freedesktop.org/wiki/Software/GeoClue"
10 SRC_URI="http://freedesktop.org/~hadess/${P}.tar.gz"
11
12 LICENSE="LGPL-2"
13 SLOT="0"
14 KEYWORDS="alpha amd64 arm ia64 ~mips ppc ppc64 sparc x86 ~amd64-fbsd"
15 IUSE="connman geonames gps gsmloc gtk hostip manual networkmanager nominatim plazes skyhook static-libs yahoo-geo"
16
17 REQUIRED_USE="skyhook? ( networkmanager )"
18
19 RDEPEND=">=dev-libs/dbus-glib-0.100
20 >=dev-libs/glib-2
21 dev-libs/libxml2
22 sys-apps/dbus
23 gps? ( sci-geosciences/gpsd )
24 gtk? ( x11-libs/gtk+:2 )
25 networkmanager? ( net-misc/networkmanager )
26 skyhook? ( net-libs/libsoup )"
27 DEPEND="${RDEPEND}
28 dev-util/gtk-doc-am
29 virtual/pkgconfig"
30
31 src_prepare() {
32 epatch \
33 "${FILESDIR}"/${PN}-0.12.0_p20110307-use-flag.patch \
34 "${FILESDIR}"/${PN}-0.12.0_p20110307-use-fallback-mac.patch \
35 "${FILESDIR}"/${P}-gpsd.patch
36
37 sed -i -e '/CFLAGS/s:-g ::' configure.ac || die #399177
38 sed -e "s/AM_CONFIG_HEADER/AC_CONFIG_HEADERS/" -i configure.ac || die
39 eautoreconf
40 }
41
42 src_configure() {
43 # Conic is only for Maemo. Don't enable.
44 # Gypsy has multiple vulnerabilities:
45 # https://bugs.freedesktop.org/show_bug.cgi?id=33431
46 econf \
47 --disable-silent-rules \
48 $(use_enable static-libs static) \
49 --disable-schemas-compile \
50 $(use_enable gtk tests) \
51 $(use_enable gtk) \
52 --disable-conic \
53 $(use_enable connman) \
54 $(use_enable networkmanager) \
55 --disable-gypsy \
56 $(use_enable gps gpsd) \
57 $(use_enable skyhook) \
58 $(use_enable geonames) \
59 $(use_enable gsmloc) \
60 $(use_enable hostip) \
61 $(use_enable manual) \
62 $(use_enable nominatim) \
63 $(use_enable plazes) \
64 $(use_enable yahoo-geo yahoo) \
65 --with-html-dir=/usr/share/doc/${PF}/html
66 }
67
68 src_install() {
69 emake DESTDIR="${D}" install
70 use gtk && dobin test/.libs/geoclue-test-gui
71 prune_libtool_files
72 }

  ViewVC Help
Powered by ViewVC 1.1.20