/[gentoo-x86]/dev-cpp/commoncpp2/commoncpp2-1.8.1-r1.ebuild
Gentoo

Contents of /dev-cpp/commoncpp2/commoncpp2-1.8.1-r1.ebuild

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.7 - (show annotations) (download)
Tue Apr 21 19:10:59 2015 UTC (4 years, 9 months ago) by pacho
Branch: MAIN
CVS Tags: HEAD
Changes since 1.6: +2 -2 lines
ppc stable wrt bug #491974

(Portage version: 2.2.18/cvs/Linux x86_64, RepoMan options: --include-arches="ppc", signed Manifest commit with key A188FBD4)

1 # Copyright 1999-2015 Gentoo Foundation
2 # Distributed under the terms of the GNU General Public License v2
3 # $Header: /var/cvsroot/gentoo-x86/dev-cpp/commoncpp2/commoncpp2-1.8.1-r1.ebuild,v 1.6 2015/04/18 12:47:48 pacho Exp $
4
5 EAPI="5"
6
7 inherit eutils autotools
8
9 DESCRIPTION="C++ framework offering portable support for threading, sockets, file access, daemons, persistence, serial I/O, XML parsing, and system services"
10 SRC_URI="mirror://gnu/commoncpp/${P}.tar.gz"
11 HOMEPAGE="http://www.gnu.org/software/commoncpp/"
12 LICENSE="GPL-2"
13 SLOT="0"
14 KEYWORDS="amd64 ppc ppc64 x86"
15 IUSE="debug doc examples ipv6 gnutls ssl static-libs"
16 REQUIRED_USE="gnutls? ( ssl )"
17
18 RDEPEND="ssl? ( gnutls? ( dev-libs/libgcrypt:0
19 net-libs/gnutls )
20 !gnutls? ( dev-libs/openssl ) )
21 sys-libs/zlib"
22 DEPEND="doc? ( >=app-doc/doxygen-1.3.6 )
23 ${RDEPEND}"
24
25 src_prepare() {
26 epatch \
27 "${FILESDIR}/1.8.1-configure_detect_netfilter.patch" \
28 "${FILESDIR}/1.8.0-glibc212.patch" \
29 "${FILESDIR}/1.8.1-autoconf-update.patch" \
30 "${FILESDIR}/1.8.1-fix-buffer-overflow.patch" \
31 "${FILESDIR}/1.8.1-parallel-build.patch"
32 eautoreconf
33 }
34
35 src_configure() {
36 use doc || \
37 sed -i "s/^DOXYGEN=.*/DOXYGEN=no/" configure || die "sed failed"
38
39 local myconf
40
41 if use gnutls; then
42 myconf="--with-gnutls"
43 else
44 use ssl && myconf="--with-openssl"
45 fi
46
47 econf \
48 $(use_enable debug) \
49 $(use_with ipv6) \
50 $(use_enable static-libs static) \
51 ${myconf}
52 }
53
54 src_install () {
55 default
56 prune_libtool_files
57
58 dodoc COPYING.addendum
59
60 # Only install html docs
61 # man and latex available, but seems a little wasteful
62 use doc && dohtml doc/html/*
63
64 if use examples ; then
65 insinto /usr/share/doc/${PF}/examples
66 cd demo
67 doins *.cpp *.h *.xml README
68 fi
69 }
70
71 # Some of the tests hang forever
72 #src_test() {
73 # cd "${S}/tests"
74 # emake || die "emake tests failed"
75 # ./test.sh || die "tests failed"
76 #}

  ViewVC Help
Powered by ViewVC 1.1.20