/[gentoo-x86]/dev-lang/qu-prolog/qu-prolog-9.1.ebuild
Gentoo

Contents of /dev-lang/qu-prolog/qu-prolog-9.1.ebuild

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.8 - (show annotations) (download)
Sat Mar 21 15:29:49 2015 UTC (3 months, 1 week ago) by jlec
Branch: MAIN
CVS Tags: HEAD
Changes since 1.7: +17 -16 lines
Drop old; fix correct installation and dependencies

(Portage version: 2.2.18/cvs/Linux x86_64, signed Manifest commit with key B9D4F231BD1558AB!)

1 # Copyright 1999-2015 Gentoo Foundation
2 # Distributed under the terms of the GNU General Public License v2
3 # $Header: /var/cvsroot/gentoo-x86/dev-lang/qu-prolog/qu-prolog-9.1.ebuild,v 1.7 2013/04/12 22:44:57 ulm Exp $
4
5 EAPI=2
6
7 inherit eutils multilib qmake-utils
8
9 MY_P=qp${PV}
10
11 DESCRIPTION="Extended Prolog supporting quantifiers, object-variables and substitutions"
12 HOMEPAGE="http://www.itee.uq.edu.au/~pjr/HomePages/QuPrologHome.html"
13 SRC_URI="http://www.itee.uq.edu.au/~pjr/HomePages/QPFiles/${MY_P}.tar.gz"
14
15 LICENSE="Qu-Prolog GPL-2+"
16 SLOT="0"
17 KEYWORDS="amd64 ppc x86"
18 IUSE="debug doc examples pedro qt4 readline threads"
19
20 RDEPEND="
21 !dev-util/mpatch
22 !dev-util/rej
23 qt4? ( dev-qt/qtgui:4 )
24 pedro? ( net-misc/pedro )
25 readline? ( app-misc/rlwrap )"
26
27 DEPEND="${RDEPEND}
28 dev-lang/perl"
29
30 S="${WORKDIR}"/${MY_P}
31
32 src_prepare() {
33 epatch \
34 "${FILESDIR}"/${P}-portage.patch \
35 "${FILESDIR}"/${P}-cflags.patch \
36 "${FILESDIR}"/${P}-cerr-ptr.patch \
37 "${FILESDIR}"/${P}-gcc.patch
38 }
39
40 src_configure() {
41 econf \
42 --libdir=/usr/$(get_libdir) \
43 $(use_enable debug) \
44 $(use_enable threads multiple-threads)
45
46 if use qt4; then
47 cd "${S}"/src/xqp || die
48 eqmake4 xqp.pro
49 fi
50 }
51
52 src_compile() {
53 emake || die "emake failed"
54
55 if use qt4; then
56 cd "${S}"/src/xqp || die
57 emake || die "emake xqp failed"
58 fi
59 }
60
61 src_install() {
62 sed -i -e "s|${S}|/usr/$(get_libdir)/qu-prolog|g" \
63 bin/qc bin/qc1.qup bin/qecat bin/qg bin/qp || die
64
65 dobin bin/qa bin/qdeal bin/qem bin/ql || die
66 dobin bin/qc bin/qc1.qup bin/qecat bin/qg bin/qp bin/qppp || die
67 dobin bin/kq || die
68
69 if use qt4; then
70 dobin src/xqp/xqp || die
71 fi
72
73 insinto /usr/$(get_libdir)/${PN}/bin
74 doins bin/rl_commands
75 doins bin/qc1.qup.qx \
76 bin/qecat.qx \
77 bin/qg.qx \
78 bin/qp.qx || die
79
80 insinto /usr/$(get_libdir)/${PN}/library
81 doins prolog/library/*.qo || die
82
83 insinto /usr/$(get_libdir)/${PN}/compiler
84 doins prolog/compiler/*.qo || die
85
86 doman doc/man/man1/*.1 || die
87
88 dodoc README || die
89
90 if use doc ; then
91 docinto reference-manual
92 dodoc doc/manual/*.html || die
93 docinto user-guide
94 dodoc doc/user/main.pdf || die
95 fi
96
97 if use examples ; then
98 insinto /usr/share/doc/${PF}/examples
99 doins examples/*.ql || die
100 docinto examples
101 dodoc examples/README || die
102 fi
103 }

  ViewVC Help
Powered by ViewVC 1.1.20