/[gentoo-x86]/dev-lang/v8/v8-2.4.9.6.ebuild
Gentoo

Contents of /dev-lang/v8/v8-2.4.9.6.ebuild

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.2 - (show annotations) (download)
Fri Nov 19 09:49:19 2010 UTC (4 years, 7 months ago) by phajdan.jr
Branch: MAIN
CVS Tags: HEAD
Changes since 1.1: +1 -1 lines
FILE REMOVED
Version bump. Remove old.
(Portage version: 2.1.8.3/cvs/Linux i686)

1 # Copyright 1999-2010 Gentoo Foundation
2 # Distributed under the terms of the GNU General Public License v2
3 # $Header: /var/cvsroot/gentoo-x86/dev-lang/v8/v8-2.4.9.6.ebuild,v 1.1 2010/10/29 08:34:53 phajdan.jr Exp $
4
5 EAPI="2"
6
7 inherit eutils flag-o-matic multilib subversion toolchain-funcs
8
9 ESVN_REPO_URI="http://v8.googlecode.com/svn/tags/${PV}"
10
11 DESCRIPTION="Google's open source JavaScript engine"
12 HOMEPAGE="http://code.google.com/p/v8"
13 LICENSE="BSD"
14
15 SLOT="0"
16 KEYWORDS="~amd64 ~x86"
17 IUSE="readline"
18
19 RDEPEND="readline? ( >=sys-libs/readline-6.1 )"
20 DEPEND="${RDEPEND}
21 >=dev-util/scons-1.3.0"
22
23 v8_scons_opts() {
24 echo "$(echo ${MAKEOPTS} | sed -r 's/.*(-j\s*|--jobs=)([0-9]+).*/-j\2/')"
25 }
26
27 pkg_setup() {
28 tc-export AR CC CXX RANLIB
29 }
30
31 src_prepare() {
32 # Stop -Werror from breaking the build.
33 epatch "${FILESDIR}"/${PN}-no-werror-r0.patch
34
35 # Respect the user's CFLAGS, including the optimization level.
36 epatch "${FILESDIR}"/${PN}-no-O3-r0.patch
37
38 # Locally fix http://code.google.com/p/v8/issues/detail?id=773.
39 epatch "${FILESDIR}"/${PN}-upstream-bug-773-r0.patch
40
41 # Remove a test that is known to fail:
42 # http://groups.google.com/group/v8-users/browse_thread/thread/b8a3f42b5aa18d06
43 rm test/mjsunit/debug-script.js || die
44 }
45
46 src_configure() {
47 # GCC issues multiple warnings about strict-aliasing issues in v8 code.
48 append-flags -fno-strict-aliasing
49 }
50
51 src_compile() {
52 local myconf=""
53
54 # Use target arch detection logic from bug #296917.
55 local myarch="$ABI"
56 [[ $myarch = "" ]] && myarch="$ARCH"
57
58 if [[ $myarch = amd64 ]] ; then
59 myconf+=" arch=x64"
60 elif [[ $myarch = x86 ]] ; then
61 myconf+=" arch=ia32"
62 else
63 die "Failed to determine target arch, got '$myarch'."
64 fi
65
66 if use readline; then
67 myconf="${myconf} console=readline"
68 else
69 myconf="${myconf} console=dumb"
70 fi
71
72 scons library=shared soname=on $(v8_scons_opts) ${myconf} . || die
73 }
74
75 src_install() {
76 insinto /usr
77 doins -r include || die
78
79 dobin d8 || die
80
81 dolib libv8-${PV}.so || die
82 dosym libv8-${PV}.so /usr/$(get_libdir)/libv8.so || die
83
84 dodoc AUTHORS ChangeLog || die
85 }
86
87 src_test() {
88 tools/test.py --no-build -p dots --shell d8 || die
89 }

  ViewVC Help
Powered by ViewVC 1.1.20